
Preface






About Alloy

Alloy is a formal modeling language proposed by Daniel Jackson at MIT in the late 90s. Initially is was mainly tailored at describing software structures, but the latest Alloy 6 version also natively supports behavioral design. Alloy 6 is the version of Alloy used in this book.


Installing Alloy

Alloy models can be automatically analyzed with a tool called Alloy Analyzer that can be downloaded here. The Analyzer is implemented in Java and for most platforms the downloaded jar can be directly executed with the java -jar command. For macOS, a dmg installer is also available.

You can also try Alloy online in the Alloy4Fun web application. This online version allows the easy sharing of models with permalinks, and can also be used to share specification challenges in educational concepts. But it has some limitations when compared to the standalone Analyzer, namely in the validation of behavioral specifications. To learn more about how to use Alloy4Fun in education, read Experiences on teaching alloy with an automated assessment platform [SCP21].



Installing unbounded model-checkers

Alloy 6 already comes with embedded solvers and is therefore self-contained. However, it can optionally leverage so-called unbounded, or complete, model-checking to increase the breadth of verification (more on that in the Behavioral modeling chapter). Currently, Alloy 6 supports NuSMV (free/open-source) and nuXmv (proprietary, free for non-commercial or academic purpose): these tools must be installed in addition to Alloy (check their respective web pages for installation instructions). Provided they appear in the path of executable programs (PATH environment variable), they will be available as electrod.nusmv or electrod.nuxmv in the list of solvers available in the Options ‣ Solver menu.



Alloy versions

The main novel feature in Alloy 6, when compared to previous versions of Alloy, is native support for behavioral design, namely the possibility to declare mutable structures and reason over these. The reader may wonder if the previous Alloy 5 version, where all structures were immutable, was useful in any way. In fact, in many software systems the main design problem concerns just structural aspects. This book starts precisely by explaining how Alloy can be used for structural design (in the Structural modeling chapter).

With Alloy 5, it was still possible to reason about behavior, by explicitly specifying the notion of time and of execution traces. However, this was often a rather time-consuming and error-prone task. The Electrum extension [FSE16] [ASE18] was proposed precisely to address this shortcoming. Electrum added an implicit notion of time, allowed the declaration of mutable structures, and the specification of properties with temporal logic. With Alloy 6, these extensions became a standard part of Alloy.

For an overview of Alloy 5, check Alloy: A Language and Tool for Exploring Software Designs [CACM19] by Daniel Jackson, or his book Software Abstractions: Logic, Language, and Analysis [MIT12].



Alloy extensions

Many extensions of Alloy were proposed in the past, that are not part of Alloy 6. To try them out, you should download the respective versions of the Analyzer. Note that most of these extensions were derived from Alloy 5, so they do not support the behavioral specification constructs of Alloy 6. Here is a non-exhaustive list of extensions:


	Alloy*, an extension that supports the specification and analysis of higher-order constraints, and that can be used, for example, to implement program synthesis [FMSD19].


	AlloyMax, an extension that supports the specification and analysis of problems with optimal solutions [FSE21].


	DynAlloy, an extension for the specification of behavioral models using an idiom inspired by dynamic logic [FSE17].


	QAlloy, an extension for the specification and analysis of quantitative requirements [FSE22].










About this book


How to read this book

This book is organized in two parts, the first introducing the basics of modeling with Alloy, and the second exploring its application in the formal design of different kinds of software systems.

The part about the basics is divided in two chapters, one about Structural modeling and the other about Behavioral modeling, each illustrated with a simple case study. If you want to get a quick introduction to Alloy you can just read these two chapters. If you want to know a bit more, then you can read the advanced topics that complement them. Each of these advanced topics builds on the case study of the respective main chapter, and each can be read separately in any order at your own pace. You can also interleave the reading of the main chapters and the advanced topics, as each section of the main chapters wraps up by pointing to related advanced topics.

The part about formal design applications will have a chapter for each application domain. For example, we currently already have a chapter about Protocol design, where we present idioms and tips to help you model and analyze distributed software, such as suggestions on how to model message passing. In the future we intend to add more chapters covering different application domains, such as a chapter about how to use Alloy to design apps using Daniel Jackson’s concepts [JAC21]. Since these are more advanced chapters, we assume the reader already read before both chapters in the basics part, as well as some of the advanced topics.



How to leave feedback

The book has a comment system that allows you to leave comments or suggestions for each chapter and each advanced topic. This comment system requires you to have a GitHub account and they will appear as issues in the public book repository.



Where to find the examples

All the examples in this book are available in a public GitHub repository. This repository has a directory for each chapter (or advanced topic) in the book containing the example models at that chapter. Each chapter also includes direct links to the respective directory in this repository, as well as the themes that were used to customize the visualization of instances. Since running a command may result in different instances depending on the configuration, we also provide in this repository the exact command that generates all instances shown throughout the book. These can be accessed by clicking on the instance figures along the book.



About the authors

The authors are researchers in formal methods, focusing on making these methods more accessible to software engineers. They are the designers of Alloy 6, which introduced native behavioral modeling and verification capabilities to Alloy and its Analyzer. They have extensive experience teaching Alloy to master’s students, researchers at summer schools and conferences, and industry practitioners. Alcino and Nuno also developed the Alloy4Fun platform for learning Alloy.

Alcino Cunha is an Associate Professor with Habilitation at the University of Minho and also member of the High-Assurance Software Laboratory of INESC TEC.

Nuno Macedo is an Assistant Professor at the Faculty of Engineering of the University of Porto and a member of the High-Assurance Software Laboratory of INESC TEC.

Julien Brunel is a Senior Researcher at ONERA, the French aerospace research center, and also a member of University of Toulouse. He is also adjunct faculty at ISAE-SUPAERO, INP-ENSEEIHT and IMT-Mines Alès.

The Basics

 




Structural modeling

This chapter explains how Alloy can be used for structural modeling. As running example we will explore the design of a file system. The main goal of the chapter is to introduce the key concepts of Alloy, so our model will be purposely simple, a very high-level abstraction of a real file system. We will focus only on the structural aspects of the design, namely on describing how files and directories are organized. Behavioral modeling will be the focus of the next chapter. Given the high level of abstraction, our specification will resemble a domain model, formally describing the key file system entities and their relationships. Another goal of this design exploration is to elicit the set of constraints that characterize a well-formed file system. Our final goal will be to verify that this set of constraints entails other relevant properties of a file system. In particular we are interested in verifying the property that no partitions occur in the file system, meaning that all files and directories are accessible from the root directory.


Signature declaration

In Alloy entities can be declared with signatures. A signature is just a set that groups together some elements of the domain of discourse. In this case we will declare signatures to capture the two key entities in a file system: directories and files. Since both files and directories share some common properties, namely they can both appear inside a directory, it is convenient to declare them as subsets of a more abstract signature containing all file system objects. To declare a signature we use the keyword sig followed by the signature name and a list of field declarations between braces. Such fields will later be used to represent associations or relationships between signatures. For the moment we will not declare them, so a signature containing all file system objects without any field can be declared simply as follows.




sig Object {}






To declare a subset signature, the keyword in should be used after the signature name, followed by the name of the including (or parent) signature. For example, the two subset signatures of Object containing the directories and files can be declared as follows.




sig Dir in Object {}

sig File in Object {}






In Alloy we typically start validating a design very early in the modeling process, when the specification is still quite incomplete. The goal is to find design problems or specification errors as early as possible, and not let them amass to a point where debugging becomes very difficult. This can be achieved by executing analysis commands.

A distinguishing feature of Alloy is that commands can be included together with the declarations and constraints in a model. This is very convenient because later all stakeholders can easily see which analysis were used to validate and verify a design. There are two kinds of commands, both accepting an optional name and a formula enclosed in braces: run commands instruct the Analyzer to check the satisfiability of the given formula, yielding a satisfying instance if that is the case; check commands instruct the Analyzer to check the validity of the given formula, yielding a counter-example instance if that is not the case. An instance is just a valuation to all declared signatures and fields. In the case of signatures, this valuation defines which elements of the domain are contained in each signature. The elements of the domain are known in Alloy as atoms, because they have no intrinsic semantics, apart from the connections they establish with other atoms through relations.

The usual way to start validating a specification is to define an empty run command. An empty formula is equivalent to true, and for the moment such a command basically asks for any instance that conforms to the signature declarations. Later, as our model evolves, the instances returned by such an empty command will also be required to satisfy all the specified assumptions. If no instance is returned then the assumptions are inconsistent and most likely our specification of the system is buggy and needs to be corrected (for example by weakening some of the assumptions).




run example {}






To execute the first command in a specification, or to re-execute the last command, just press cmd-e or the Execute button in the toolbar of the Analyzer window. If you have multiple commands, to choose which one to execute go to the Execute menu and select the desired command. If the commands are named you will see the names there, otherwise you will see an automatically generated name composed by the type of command (run or check) followed by a $ and a sequential numeric identifier.

After executing a command, you’ll see some logging information in the pane to the right of the model editor. If a run command finds an instance, the Analyzer will report a message Instance found that can be clicked to open tha instance in the visualizer (likewise for check commands and counter-examples). Alternatively, you can press the Show button in the toolbar of the Analyzer window or select menu option Execute ‣ Show Latest Instance (shortcut cmd-l) to view the last generated instance. After executing the example command in our model we get the following message.

[image: ../../_images/log12.png] 

After clicking Instance, the following instance is opened in the visualizer.

[image: Get the code to generate this instance.]

Another distinguishing feature of Alloy is that the instances returned by the analysis commands are, by default, depicted graphically as graph-like structures in a pop-up window, just as the one above: atoms belonging to the different signatures are nodes (depicted as boxes by default) and associations between atoms are edges (depicted as arrows). In this instance we have two objects, one of them is a directory and the other a file. We can ask the Analyzer to generate a different instance, by pressing New in the visualizer toolbar, or selecting menu option Instance ‣ Show New Solution (shortcut cmd-n). As mentioned before, atoms have no intrinsic semantics. In particular, the names the Analyzer generates for them are meaningless: Object0 isn’t the name of a particular file existing in a real-world file system, but just a name to help us distinguish it from other elements in the domain. As such, two instances that only differ in the names of the atoms are in fact the same instance (they are isomorphic up to atom renaming), and showing both to the user would just encumber the understanding of the specification. To avoid this, and also to speed up analysis, the Analyzer implements a powerful symmetry breaking mechanism that excludes from the analysis most isomorphic (i.e., symmetric) instances. This feature is also very convenient for validation, as we can quickly see many truly different instances of our model. For example, after pressing New we could get the following instance. Re-enforcing the fact that name are meaningless, if there is a single atom in a signature it is not numbered in the visualization by default.

[image: Get the code to generate this instance.]

If you try to run these commands in the Analyzer it is possible that you get different instances. The Analyzer relies on lower-level SAT solvers to perform the analysis. Depending on the Analyzer version and the solver you have selected to perform the analysis, you might get instances in a different order than this. You can choose the underlying solver in the Options menu. However, irrespective of the selected solver, if you keep pressing New you will obtain all the possible (non-symmetric) instances of a specification, so you are guaranteed to eventually obtain these.

In the above instance we have a single object that is, simultaneously, a directory and a file. Obviously this is not something we wanted, but it is allowed by this model since both File and Dir are arbitrary subsets of Object. It is very common to require that some subset signatures are disjoint. Alloy has a special syntax to declare those: instead of in, the keyword extends should be used in the signature declaration. An advantage of using extends is that in the instance visualizer atoms will be named according to the most specific extension signature they belong to (instead of using labels), which simplifies the understanding of instances. To introduce File and Dir as two disjoint subsets of Object we should declare them as follows.




sig File extends Object {}

sig Dir extends Object {}






File and Dir are extension signatures, while Object is a top-level signature, because it does not extend or is included in another signature. If we re-execute the example command, and iterate through the possible instances using New we will no longer see objects that are simultaneously files and directories, but we will eventually get an instance such as the following, where we have the problem of having an object (named Object) that is neither a file nor a directory.

[image: Get the code to generate this instance.]

A frequent requirement for extension signatures is that they actually form a partition of the parent signature, meaning that the parent signature must not contain atoms besides those contained in its extensions. In this case, the parent signature should be declared as abstract, by preceding its declaration with the keyword abstract. In our example we want File and Dir to partition signature Object, so we should have the following declarations.




abstract sig Object {}

sig Dir extends Object {}

sig File extends Object {}






We would now like to denote one of the directories as the root of the file system. In Alloy it is not possible to directly declare constants, but we can declare an extension signature that is inhabited by exactly one atom, and thus behaves like a constant. Signature declarations can be preceded by a multiplicity constraint that restricts the cardinality of that signature. There are three multiplicities that can be used in a signature declaration: some forces the signature to always have some atoms; lone restricts the signature to have at most one atom; and one restricts the signature to have exactly one atom. To denote the root directory, we can declare a signature Root extending Dir with multiplicity one.




one sig Root extends Dir {}






Root is a singleton set that contains the atom that is the root directory of the file system. Since it is declared with extends, that atom will also be named Root in the instance visualizer. A possible instance returned by the example command is the following, where we have three directories, one of them being (necessarily, due to multiplicity one) the root directory.

[image: Get the code to generate this instance.]

Objects inside directories have an associated name, so we will need a signature to represent the latter. In our file system model we will also allow files to be (hard) linked, meaning that the same file can have different names in different directories (or even inside the same directory). As such, we will also introduce a signature Entry that will later be used as a (kind of) record to pack together an object inside a directory and the respective name.




sig Entry {}

sig Name {}






With these new signature declarations, a possible instance of our specification is the following, with two different names, two entries, one file, and two directories, one of which is the root.

[image: Get the code to generate this instance.]

To enable automatic analysis, Alloy imposes a bound on the size of all signatures. This bound is defined by a scope on commands. By default the scope is 3 for all top-level signatures, meaning that instances will only be built using at most 3 atoms for each top-level signature. In our command this means that instances will have at most 3 names, 3 entries, and 3 objects. With this scope, instances with, for example, 3 files, will not be possible, because the root always exists and consumes 1 of the 3 atoms that can inhabit Object. To change the default global scope for a certain command the keyword for followed by the desired scope can be used. We can also set a different scope for each top-level or extension signature (but not for the subset signatures declared with in), by using the keyword but followed by a comma separated list with different scopes for each signature. You can also set an exact scope for a signature with the keyword exactly, forcing that signature to always be inhabited by the exact number of specified atoms. For example, to execute the example command with a default scope of 4 for top-level signatures, but up to 2 entries, and exactly 3 names, the scope should be set as follows.




run example {} for 4 but 2 Entry, exactly 3 Name






Note that in this case, the only top-level signature that will be subject to the default scope of 4 is Object, since specific scopes are given for the other two top-level signatures. Multiplicities on signature declarations also affect the scope: for example, a signature with multiplicity one will always have a scope of exactly 1, and an error will be thrown if you try to set a different scope.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/blob/2024-02-28/structural-modeling/signature-declaration/

Further reading

Subset signatures

A signature can be declared as a subset of a union of signatures. Learn how this allows us to simulate multiple inheritance.

Subset signatures

Further reading

Enumeration signatures

Learn how to declare enumeration signatures with one sig extensions or with the keyword enum.

Enumeration signatures

Further reading

Commands in detail

Learn more about Alloy’s analysis commands and associated scopes.

Commands in detail



Field declaration

Having declared our signatures we now proceed with the declaration of fields. Fields can be used to model associations or relationships between different entities in the domain. Fields are declared inside the braces of a signature declaration, and are essentially mathematical relations (sets of tuples) that connect atoms of the enclosing signature to other atoms (of the same or other signatures).

A field we will need in our example is one that connects each directory with the respective set of entries. This binary relation, which will be named entries, is a set of ordered pairs, where the first atom of each pair is a directory and the second atom is an entry. Since it relates atoms of signature Dir to atoms of signature Entry, it must be declared as a field in the former signature. To do so, we change the declaration of Dir as follows.




sig Dir extends Object {

  entries : set Entry

}






As we can see, a field declaration consists of its name followed by a colon and the target signature, optionally preceded be a multiplicity declaration. In this case the target is signature Entry and the multiplicity is set, meaning that one atom of signature Dir can be related by entries to an arbitrary number of atoms of signature Entry. The other options for the multiplicity are the same that can be used in signature declarations: one, lone, or some. If no multiplicity is given, the default is one. In this book we will avoid this implicit multiplicity in field declarations, and always explicitly state the multiplicity of a field, even if it is one.

Recall the already declared empty command example.




run example {}






By executing it, we could now get the following instance.

[image: Get the code to generate this instance.]

Binary relations are depicted by the Analyzer using labelled arrows: each arrow is a pair contained in the relation, whose first atom is the source of the arrow and whose second atom is the target. In this instance, relation entries is a set that contains three pairs: (Dir,Entry0), (Dir,Entry1), and (Root,Entry2), meaning that we have a directory Dir with two entries and the Root with one entry. Given the set multiplicity we could also have directories without any entries.

The arity of a relation is the size of the tuples contained in it. For example, entries is a (binary) relation of arity 2. Actually, in Alloy everything is a relation. In particular, signatures are also relations, namely (unary) relations of arity 1. This means they are sets of tuples of size 1. For example, in the previous instance, signature Dir contains the following unary tuples: (Dir) and (Root). Do not confuse the name of the atom Dir with the signature name Dir: the former is just an automatically-generated name for one of the two inhabitants of the latter! When we start using relational logic operators to write constraints, it will be more clear why the fact that everything denotes a relation considerably simplifies the syntax and semantics of the language.

Besides entries we will declare two more fields in our specification: name, that relates each entry in a directory with the respective name; and object, that relates each entry in a directory with the respective file system object (either a file or a directory). Both these fields will be declared inside signature Entry and both will have multiplicity one, since exactly one target atom is associated with each entry. With these two fields, an entry acts like a record that packs together an object inside a directory and the respective name.




sig Entry {

  object : one Object,

  name : one Name

}






Let’s change the default scope of our run command.




run example {} for 4






After executing this command we could get the following instance.

[image: Get the code to generate this instance.]

In this instance some problems with our specification are evident, for example entries shared between directories or files not belonging to any directory. As our specification grows, instances become increasingly difficult to understand. The Analyzer allows the visualization to be customized be defining a theme, which can make instances easier to understand. For our file system model, we will use different colours and shapes for entries and file system objects, and show entry names as attributes rather than edges. After the customization, the instance will be depicted as follows.

[image: Get the code to generate this instance.]

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-modeling/field-declaration

Further reading

Visualization customization

Learn in detail how to customize themes and how to get the above visualization.

Visualization customization

Further reading

Higher-arity relations

Instead of declaring entries, the association between directories, their contents, and the respective names could alternatively be modelled by a ternary relation.

Higher-arity relations

Further reading

The instance evaluator

The Alloy Analyzer has an evaluator that can be very useful for debugging.

The instance evaluator



Specifying constraints

By inspecting the above instance we can easily detect several problems in our specification of a file system, namely it currently allows:


	Shared entries between directories (entry Entry3 belongs both to Dir and Root).


	Different entries in the same directory with the same name (all entries inside Dir have the same name Name).


	The same directory to appear in more than one entry (Dir is the object of all entries).


	Dangling files that do not belong to any entry (File).




To prevent these issues, we must add constraints to our model. In Alloy, constraints that are assumptions of the model (that is, necessarily valid) should be added inside a fact. A fact is declared with keyword fact followed by an optional name and a set of constraints inside braces.

To specify constraints Alloy has a dual syntax for the usual Boolean operators: they can be both written with the typical programming language style operators, but also using the respective English words. We have ! or not for negation, && or and for conjunction, || or or for disjunction, => or implies for implication, and <=> or iff for equivalence. Alloy syntax was designed to be very clean and readable. The use of the English version of the operators further increases the readability of the specifications, and will be the preferred style in this book. The universal and existential quantifiers of first-logic logic can also be used, and are written with keywords all and some. Quantified variables can range over arbitrary sets, and a single quantifier can introduce multiple variables at once, separated by commas. To separate the quantified variables from the (open) formula that they should satisfy the separator | should be used (or brackets for a block of constraints).

Actually, in Alloy properties can be specified with an extension of first-order logic called relational logic. Relational logic extends first-order logic with so called relational operators, that can be used to combine (or compose) relations (which in first-order logic are known as predicates) to obtain more complex relations. Among these operators we have the classic set operators such as intersection (&), union (+), and difference (-). Notice that every relation (of any arity) is a set of tuples, so these can be applied to any relation, including fields and signatures. A typical atomic formula in relational logic is a cardinality check: keyword no checks if a relation is empty; some checks if it is non-empty; lone checks if it has at most one tuple; and one checks if it has exactly one tuple. We can check that a relation is a subset or equal to another relation with keyword in. To check the negation of this we can directly use the operator not in. Finally, equality can be checked with = and inequality with !=. For example, the following fact restrict_object states that all objects are either directories or files, by specifying that signature Object is a subset of the union of Dir and File.




fact restrict_object {

  Object in Dir + File

}






Using plain first-order logic, this fact would have to be written with a more verbose style using quantifiers and Boolean operators.




fact restrict_object {

  all x : Object | x in Dir or x in File

}






Of course, this fact is redundant, since it is a consequence of signature Object being abstract and extended by Dir and File. However, it illustrates an important point about Alloy’s motto that “everything is a relation”. In Alloy, the operator in is the standard subset or equal operator of set theory and not the membership test. A formula like x in Dir is allowed, because in Alloy every expression denotes a relation (a set of tuples). In particular, quantified variables are also relations, namely singleton sets with a unary tuple containing a single atom drawn from the range of the quantifier. When x is such a singleton set, an inclusion check like x in Dir actually performs a membership check. This is an example of how the above motto enables the simplification of the syntax and semantics of the language, since there is no need for a different operator for membership check.

The essential operator in relational logic is composition, the binary operator written as . (also known as dot-join). This operator allows us to navigate through fields to obtain related atoms. Understanding how this operator works is key to be proficient in Alloy. Here, we will explain its informal semantics by means of several examples. In particular we will focus on the simplest, and most frequent, use of this operator, namely when applied to a set and a binary relation. For example, suppose e is a singleton set containing an Entry and d a singleton set containing a Dir. These could be, for example, quantified variables. To obtain the name of entry e you can compose it with relation name: relational expression e.name denotes the name of e. Since name is a field with multiplicity one, the result of this composition is necessarily a singleton set containing a Name. Similarly, e.object is the singleton set with the file system object that is contained in entry e. The notation is, on purpose, similar to that of accessing an attribute of an object in an object-oriented programming language, as the effect is essentially the same when dealing with singleton sets. However, we can also apply it to relations with multiplicity different than one and arbitrary sets. For example, d.entries retrieves the set of all entries in directory d. This set can be empty or contain an arbitrary number of entries, since relation entries has multiplicity set. Another interesting usage is when composing a non-singleton set with a relation. For example, Entry.name is the set of all names of all entries and Dir.entries is the set of all entries that belong to some directory. Also, you are not forced to compose a set followed by a relation: the other way around also works. Relations can be navigated forwards, from the source signature to the target signature, but also backwards from the target signature to the source one. For example, entries.e denotes the set of directories that contain entry e: this set can be empty, if e is not contained in any directory, or even have more than one directory, since when declaring a field there are no multiplicity restrictions imposed on the source signature. We can also compose with an arbitrary set on the right-hand side: for example, entries.Entry is the set of all directories that contain some entry. Compositions can also be chained to obtain atoms that are somehow indirectly related. For example, d.entries.object denotes the set of all file system objects that are contained in some entry of directory d. And again, it is possible to navigate backwards through a chain of compositions. For example, entries.object.d denotes the set of all directories that have some entry that points to directory d.

Using . we can now declare a fact that prevents the first issue identified in the beginning of this section. We can almost directly transliterate the natural language requirement that “entries cannot be shared between directories” to relational logic. Given any two different directories x and y, the property that there should be no common entries between both can be specified as no (x.entries & y.entries). In this formula we first determine the intersection of the two sets of entries of both directories, and then we check that this set is empty using the keyword no. To finish the specification of our first assumption we just need to universally quantify over all different directories x and y.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all x, y : Dir | x != y implies no (x.entries & y.entries)

}






The need to quantify over two or more different variables is very common, so Alloy provides the modifier disj, that can be added between a quantifier and the variables, precisely to restrict those variables to be different. This modifier simplifies the formulas, since we no longer need an implication to indirectly restrict the range of the quantification. Using this modifier, our property can be restated as follows.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all disj x, y : Dir | no (x.entries & y.entries)

}






As expected, there are many different ways to specify the same property. In the case of this property, a simpler formula can be obtained by navigating backwards the entries relation, and specifying instead that for every entry e there should be at most one directory in the set entries.e, the set of all directories that contain e as an entry. This alternative formulation would look as follows. Recall that lone can be used to check if a relation (or set) contains at most one tuple.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all e : Entry | lone entries.e

}






To fix the second identified issue, we must enforce that different entries in the same directory have different names. This can be achieved with the following fact.




fact unique_names {

  // Different entries in the same directory must have different names

  all d : Dir, disj x, y : d.entries | x.name != y.name

}






Here you can see another nice feature of Alloy’s syntax: it is possible to quantify over any expression and not only over signatures. In this case, x and y will be instantiated with all the (distinct) atoms belonging to d.entries, the set of entries of each directory d quantified in the outer formula. An alternative formulation of this property is the following.




fact unique_names {

  // Different entries in the same directory must have different names

  all d : Dir, n : Name | lone (d.entries & name.n)

}






Expression d.entries & name.n denotes the set of entries in directory d that also have name n. This set must contain at most one entry for every directory d and name n.

To prevent the third issue we can enforce that each directory is contained in at most one entry as follows.




fact no_shared_dirs {

  // A directory cannot be contained in more than one entry

  all d : Dir | lone object.d

}






The last issue is an example of a broader problem: there is nothing in our specification that forces all objects except the root to belong to an entry. To specify such a constraint, we can begin by determining the set of all objects that are contained in any entry using expression Entry.object, and then enforce that this set is equal the set of all objects minus the root.




fact no_dangling_objects {

  // Every object except the root is contained in some entry

  Entry.object = Object - Root

}






After adding these four facts, if we re-execute the example command and iterate with New, we’ll notice that the problems identified above seem to be gone. However, we will still get instances such as the following.

[image: Get the code to generate this instance.]

This instance makes clear two additional issues in our model (the second was actually already present in the previous problematic instance):


	Entries not belonging to any directory.


	Directories contained in themselves.




To address the first issue we could replace the fact no_shared_entries introduced above with a stronger version to demand that every entry belongs to one and exactly one directory (rather than at most one).




fact one_directory_per_entry {

  // Entries must belong to exactly one a directory

  all e : Entry | one entries.e

}






Concerning the second issue, to forbid directories from containing themselves as entries, we can use the previously described expression d.entries.object to determine the objects contained in a directory d. Then we just need to forbid d itself from being a member of this set.




fact no_self_containment {

  // Directories cannot contain themselves

  all d : Dir | d not in d.entries.object

}






Re-executing again command example and iterating a couple of times with New reveals no more issues. Obviously, it is impossible to manually inspect all possible instances, so we will proceed with the verification of our desired assertion, namely that the file system contains no partitions.

A question of style

Relational logic, the formalism behind the Alloy language, is very expressive and flexible. This means that the same constraint can be encoded in several different styles, depending on the user’s preference.

Let us get back to the fact no_shared_entries, forcing that entries cannot be shared between directories. The last version presented above was the following.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all e : Entry | lone entries.e

}






This navigational style is the most common in Alloy. We usually have a few quantifiers (many times just a single quantified variable) and use composition to navigate back and forwards from variables to get related sets of atoms, over which some constraints are imposed. In this case we first determine the set entries.e containing the directories where entry e is contained, and then force this set to contain at most one directory with a cardinality check.

Of course, we could also express the same property using a plain first-order style, where we only check if a tuple of variables belongs to a relation (known as a predicate in first-order logic parlance) or if a pair of variables are equal. This requires having more quantified variables and results in a verbose style that is also known as pointwise.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all x, y : Dir, e : Entry | x->e in entries and y->e in entries implies x = y

}






The -> operator is the Cartesian product, here being applied to two singleton sets (two variables) to form a singleton binary relation (with a single tuple). Checking that this singleton binary relation is a subset of entries is just checking the membership of the respective tuple.

Going full first-order style usually results in very verbose constraints. So even when going for a pointwise style, it is still common to rely on the set operators of relational logic to obtain a more succinct formula. That was the case of the first version of the no_shared_entries fact we presented above.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all x, y : Dir | x != y implies no (x.entries & y.entries)

}






In Alloy, sometimes we can also go in the opposite direction and use a very succinct, purely relational style, where no quantifiers are used. This style is sometimes known as pointfree due to the lack of variables. The above restriction could be specified in this style as follows.




fact no_shared_entries {

  // Entries cannot be shared between directories

  entries.~entries in iden

}






The iden predefined binary identity relation contains all possible tuples of identical atoms. The unary operator ~ reverses a binary relation, so ~entries is a relation from entries to the directories containing it. The expression entries.~entries is thus a binary relation that associates a directory with all directories that contain at least a shared entry. By restricting this derived relation to be a subset of iden we are indirectly forbidding shared entries between directories. It is a nice intellectual challenge to write specifications in this pointfree style, but sometimes we end up with formulas such as this one that are very difficult to understand, when compared to the equivalent formula specified in the typical navigational style of Alloy. Also, be aware that it is not possible to convert all formulas of relational logic to this style in Alloy.

Verifying assertions

In Alloy, check commands are used to verify properties that are expected to be a consequence of the specified facts. Although such commands can be declared to verify any arbitrary formula (must like the body of run commands), assertions that are expected to hold are better declared inside a named assert block to improve code maintainability. To specify the expected assertion in our example, namely that there are no partitions in a file system, we need to determine the set of all objects that are reachable from the root. We have already seen how to determine the set of objects that are directly contained in a directory. Namely, Root.entries.object is the set of objects directly contained in the Root directory. The set of objects reachable from Root contains not only these, but also the objects that they contain, which can be determined as




Root.entries.object.entries.object






Of course, we also need to include the objects contained in these, and so on, and so on. Essentially, we would like to determine the following set:




Root.entries.object +

Root.entries.object.entries.object +

Root.entries.object.entries.object.entries.object +

…






The problem is how to fill in the … in this expression: ultimately the number of times we need to compose entries.object depends on the size of our file system, and we would like our specification to be independent of this value. Fortunately, relational logic includes the so-called transitive closure operator (^) that when applied to a binary relation determines the binary relation that results from taking the union of all its possible compositions. Essentially, given a relation r, ^r is the same as r + r.r + r.r.r + …. Seeing our instances as labelled graphs, the expression x.^r will determine the set of all atoms that can be reached from atom x by navigating in one or more steps via arrows labelled with r. Transitive closure is the reason why relational logic is strictly more expressive than first-order logic: our desired assertion could not be expressed in first-order logic alone.

By using transitive closure applied to relation entries.object we can determine the set of all objects reachable from root, its descendants. Alloy allows the declaration of functions, reusable (parametrized) expressions. To declare a function the keyword fun should be used, followed by the function name, an optional list of parameters, a colon followed by the type of the returned relation, and the expression used to compute it enclosed between braces. This expression can be specified using any of the relational operators presented so far. For example, we could declare a function descendants that returns the set of all objects reachable from a given object as follows.




fun descendants [o : Object] : set Object {

  o.^(entries.object)

}






In this definition we could also use a let expression to name the derived relation entries.object. Let expressions are particularly useful if the named expression is used more than once in the following expression, thus avoiding repetition, but here we could use it just to make the definition more clear.




fun descendants [o : Object] : set Object {

  let children = entries.object | o.^children

}






Besides functions Alloy also allows the declaration of predicates, reusable formulas that are only required to hold when invoked (for example in a fact). To declare a predicate the keyword pred should be used, followed by the predicate name, an optional list of parameters, and a formula enclosed between braces. For example, we could declare a predicate reachable that checks if an object is reachable from the root as follows




pred reachable [o : Object] {

  o in Root + descendants[Root]

}






A reachable object is either the root itself or one of its descendants. To compute the latter we use function descendants defined above.

To ensure that there are no partitions, all objects of the file system should be reachable from the root. Using the above predicate, this desired assertion can be specified as follows.




assert no_partitions {

  // Every object is reachable from the root

  all o : Object | reachable[o]

}






To verify that this assertion is a consequence of all the facts that have been imposed before, we can use a check command.




check no_partitions






Unfortunately, executing this command reveals a counter-example.

[image: Get the code to generate this instance.]

The problem is that we have two directories that contain each other. Fortunately, this counter-example is not an issue in real file systems, but exposes a problem in our specification. One of the facts specified above, no_self_containment, imposed that no directory can contain itself, but of course this alone is not sufficient: a directory cannot be one of its own descendants. To fix that fact, we can again use function descendants.




fact no_indirect_containment {

   // Directories cannot descend from themselves

   all d : Dir | d not in descendants[d]

}






Re-executing the check command no longer yields counter-examples, reporting a message such as the following.

[image: ../../_images/log22.png] 

Note that the Analyzer only reports that no counter-example was found, so the assertion may be valid, since with the bounded analysis performed by the Analyzer we can never be entirely sure that an assertion is valid. Nonetheless, we can always set a higher scope in the command to increase our confidence that that is indeed the case.




check no_partitions for 6






You should always be wary of the results of checking your assertions, in particular when they yield no counter-examples. Recall that a check command verifies that an assertion is implied by the conjunction of all declared facts. If your facts are inconsistent, in the sense that their conjunction is false, or admit only very trivial instances (for example empty ones), your assertion can be trivially true. For example, in this example we changed one of the facts before our final check that yielded no counter-examples. We should have checked that this change did not accidentally make our specification inconsistent. To do so we could execute a run command after the final check, and iterate a bit through the returned instances to make sure the specification is still consistent and admits non-trivial file systems.

Structural modelling advanced topics

This chapter presents some advanced topics relevant for structural modelling. These topics build on the file system example model of the Structural modeling chapter.

Subset signatures

Sets (unary relations) can be introduced in a model through subset signatures. As we’ve already seen, unlike sub-signatures defined by extension, these are not guaranteed to be disjoint among themselves. In chapter Structural modeling we’ve seen the basic use of subset signatures, but since we actually expected those subset signatures to be disjoint, they were better modelled as extension signatures. That is not always the case, and in fact subset signatures can be used to encode powerful patterns, including something that resembles multiple inheritance.


Mixing subset and extension signatures

Suppose we wanted to add the ability to tag objects in a file system, for example as supported by operating systems like macOS. The concept of tagged object is transversal to the signature Object, since both regular files and directories can be tagged. On the other hand, not all objects are necessarily tagged. So this feature is best encoded as a subset signature as follows.




sig Tagged in Object {}






If we now ask the Analyzer for instances of this model there may exist objects that are both in File and Tagged and Dir and Tagged. The following is one such possible instance for the empty command example. The fact that an atom belongs to the Tagged subset signature is depicted with an attribute label below its name (the name of the atom itself is based on the most specific extension signature to which it belongs).

[image: Get the code to generate this instance.]

Even more interesting, subset signatures can have their own fields declared within. For instance, let’s introduce a signature Tag to represent abstract tags, and then extend signature Tagged to also register the non-empty set of tags assigned to each object, as follows.




sig Tag {}



sig Tagged in Object {

  tags : some Tag

}






Now, for instance, any tagged directory will both be related through relations entries (inherited from Dir) and tags (inherited from Tagged). Below is one such example for the same command, where the root has both entries and tags (in the theme, we’ve hidden Tag atoms, and set field tags to be shown as an attribute).

[image: Get the code to generate this instance.]

Simulating multiple inheritance

Suppose now we wanted to discriminate different kinds of tags, so that these can either be shapes (with a color) or labels (with a text message). This tag hierarchy could be declared as follows.




sig Color, Text {}



abstract sig Tag {}



sig Shape extends Tag {

  color : one Color

}



sig Label extends Tag {

  text : one Text

}






Suppose now we also wanted to add alerts that are tags that are both shapes and labels. In Alloy we don’t have multiple inheritance, so we cannot declare a signature Alert that both extends Shape and Label. Using subset signatures we could simulate multiple inheritance. The key idea would be to declare all three signatures as subsets of the Tag signature, and then use a fact to encode the type hierarchy constraints, namely the fact that Tag is abstract and that Alert is the set of tags that are both shapes and labels. We could do so as follows. Note that alerts would inherit both the color and text fields.




sig Tag {}



sig Color, Text {}



sig Shape in Tag {

  color : one Color

}



sig Label in Tag {

  text : one Text

}



sig Alert in Tag {}






One of the problems of this approach is that since the different kinds of tags are not proper extensions, their atom names will all begin with Tag, so to distinguish the different kinds of tags we would need to use the subset signature labels. Of course, we could also customize the theme to help us distinguish which tags fall in each category. In the following instance, we’ve set the abstract top-level Tag signature to be white and have the default rectangle shape. Then, shapes are instead colored yellow, while labels are shaped as ellipses. As a consequence, alerts are yellow colored ellipses.

[image: Get the code to generate this instance.]

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/subset-signatures/simulating-multiple-inheritance

Further reading

Visualization customization

In this topic we’ve have used advanced theme customizations to ease the visualization of instances. Learn more about the Alloy Analyzer’s theme customization feature.

Visualization customization



Cross-signature subsets

Another interesting feature of subset signatures is that they can be defined to be a subset of a union of multiple signatures using the + operator, rather than just one as we’ve seen thus far. Let us extend our example again, and consider that our file system also supports symbolic links as a distinct type of object.




sig Symlink extends Object {}






If we do not want symbolic links to be tagged, we could enforce this through an additional fact that restricted the value of Tagged, but this can be directly achieved at the signature level by adapting its declaration as follows.




sig Tagged in Dir + File {

  tags : some Tag

}






Now subset signature Tagged is restricted to only Dir and File atoms, excluding other kinds of objects. In this example Dir and File share the same top-level signature Object, but signatures can be defined as the subset of the union of completely unrelated signatures. To properly visualize instances, you will have to customize the theme again at this point. This is because in the previous version, subset signature Tagged and field tags were defined for the full signature Object in the theme; now, they are no longer defined for all objects, but only for signatures File and Dir. At the theme customization pane, this will originate two duplicates of Tagged and tags, one for each of these two signatures, which both have to be customized again.

One last, and less common, way to define subset signatures is through equality rather than inclusion using the operator =. For instance, let’s say that we wish to assign user permissions to all directories and files, but not to symbolic links. This could be done as follows.




sig Permission {}



sig NonSymlink = Dir + File {

  permission : one Permission

}






An instance for the empty command for this version of the model is the following.

[image: Get the code to generate this instance.]

Obviously, this example is a bit contrived since a simpler solution would be to extend Object with an abstract signature NonSymlink and then have Dir and File extend that signature. However, we could also declare a subset that is equal to the union of unrelated signatures, and that could not be declared in such a manner.

On a last note, due to all the flexibility of subset signatures, particularly the fact that they may contain atoms from unrelated signatures, they cannot be extended, only contain other subset signatures.

Enumeration signatures

Models often require enumerated types that are expected to contain certain specific elements. For example, let’s build on the file system example from the Structural modeling chapter, and extend it with Unix-like file permissions, where the file’s owner, file’s group and every other user are assigned either read, write or execute permission.


Declaring enumeration signatures

In Alloy it is very common to use extension signatures of multiplicity one to specialize signatures that are supposed to represent enumerated data types. The following specification declares a Permission signature that contains exactly three permissions: Read, Write, and Execute.




abstract sig Permission {}

one sig Read, Write, Execute extends Permission {}






Here we see another feature of the Alloy language: if two or more signatures share the same features (multiplicity, parent signature, fields, etc.) they can all be defined together in the same declaration with names separated by commas. This also applies to fields and variable declarations.

This pattern for declaring signatures that represent enumerated data types is so common that Alloy has a keyword enum for that purpose. Using this keyword, the Permission signature could be declared as follows.




enum Permission { Read, Write, Execute }

Using enumeration signatures

Enumeration signatures can be used as any other regular signature. In our example, we want each object in the file system to have a permission assigned to each group, so signature Object could be extended as follows.




abstract sig Object {

  user_permission : set Permission,

  group_permission : set Permission,

  others_permission : set Permission

}






Here, each of the 3 fields determines the permissions assigned to a scope. Running an empty example command yields instances such as the following, after some theme customization (including hiding the enumeration and setting the permission fields to be shown as attributes).

[image: Get the code to generate this instance.]

An alternative encoding

While this models the desirable information, it is perhaps not the easiest encoding to maintain. An alternative is to also encode the different classes as an enumeration signature, and then create a new signature that acts as a “record” that combines classes and permissions. This could be encoded as follows.




enum Class { User, Group, Other }



sig PermissionAssignment {

  permission : set Permission,

  class : one Class

}



abstract sig Object {

  mode : set PermissionAssignment

}






However, this no longer guarantees that for each object, there is exactly one permission assigned to each group. This requires the following additional fact.




fact all_classes_assigned {

  // There is one permission assigned to each group

  all o : Object, c : Class | one o.mode & class.c

}






Unfortunately, this encoding also has a limitation: the number of distinct assignments of permissions to classes is determined by the scope on signature PermissionAssignment. Since there are 3 different classes, this already uses up the complete default scope for PermissionAssignment, and commands like the following yield no instance.




run distinct_permissions {

  some disj o1, o2 : Object | o1.mode != o2.mode

}






If we increase, for instance, the overall scope to 4, the command will be able generate instances such as the following (again, after some similar theme customizations).

[image: Get the code to generate this instance.]

Yet another alternative encoding that would address both the maintainability and scope issues could be to define the permissions using a ternary relation. The declaration and use of such higher arity relations are addressed in another advanced topic.

There is just a subtle difference between declaring enumeration signatures with keyword enum and declaring them with singleton extensions as we did initially: the former additionally imposes a total order between the respective atoms, corresponding to the order in which they are declared inside the braces. Total orders in Alloy are also explored in a separate advanced topic.

Commands in detail

Commands are an essential feature of an Alloy model, since they are what triggers the automatic analyses of our model by the Analyzer. There are two types of commands in Alloy: run commands search for instances that satisfy certain constraints, while check commands search for counter-examples that violate assertions. Commands also include the scope of the analyses, which determines the maximum size of the signatures and of the universe of discourse. In the Structural modeling chapter we have already seen the fundamentals of command declaration. This chapter explores commands in more detail.


Alternative command syntaxes

Both run and check commands can take two different syntaxes. In the first commands have an optional label and a constraint to be enforced/checked between braces. Between the braces any arbitrary constraint can be written. In the Structural modeling chapter we have defined run commands of this shape, but this could also be done for check commands. For instance, below is a check command equivalent to the one defined in the Structural modeling chapter to check that the file system has no partitions, given as a contraint in the command rather than defined in an assertion.




check no_partitions {

  all o : Object | reachable[o]

} for 6






In the second alternative syntax, a command cannot be labelled and just calls a re-usable formula defined elsewhere. For check commands we’ve already seen in the Structural modeling chapter how that can be done through the definition of assertions; the check command will then search for counter-examples that violate that assertion. For run commands, they can be instructed to generate instances for which a certain predicate holds. An advantage of these versions is that they ease the definition of multiple commands for the same property with different scopes. For instance, let’s say that we want to explore instances that have a file hierarchy of at least depth 2 but with different scopes for File. We could do something like the following.




pred depth2 {

  some Root.entries.object.entries.object

}



run depth2 for 4 but 0 File

run depth2 for 4 but 1 File

run depth2 for 4 but 2 File






An interesting feature of this kind of commands is that, if you run a predicate with parameters, they will be automatically quantified and show an instance for which there is some atom that makes the predicate true. For instance, let us define a predicate that tests whether a directory is empty, and then ask for instances where there is some empty directory.




pred empty_dir [d : Dir] {

  no d.entries

}



run empty_dir for 3






This will result in instances such as the one below. Notice that there is now a subset $empty_dir_d in the instances, identifying the quantified variable that made predicate empty_dir true. This is because the Analyzer performs a process called Skolemization whenever outermost existential quantifications occur in run commands (or universal quantifications for check commands), creating additional free relations to represent the quantified variables. This improves the efficiency of the analysis procedures, and as a side-effect such relations are now also part of the generated instance and can be depicted.

[image: Get the code to generate this instance.]

Although less common, run commands can also call a function rather than a predicate. In that case Alloy will search for input variables for which the function is well defined (i.e., it returns a value within its return type).

Note that once you specify a constraint in the command, you are no longer calling an assertion or predicate and just labelling the command. Since commands can have the same label as a predicate name, this can sometime lead to confusions. For instance, the command below is not really checking assertion no_partitions, but instead the empty constraint within brackets (which is equivalent to true) and obviously never finds any counter-example, possibly leading the distracted user to a false sense of confidence.




check no_partitions {}

Controlling scopes

When the Analyzer is launched, a non-negative scope must be assigned to every signature of the model that determines the maximum number of atoms for that signature. These scopes are declared in the analysis commands.

The overall scope of a command is specified with the keyword for which is applied to all top-level signatures. If omitted, a default overall scope of 3 is used. Since overall scopes apply only to top-level signatures, they may have some unintended results when the signature hierarchy becomes more complex, in particular when singleton signatures are introduced and consume part of the scope of a top-level signature. For instance, in our running example, a command with a overall scope of 3 like the one below will never generate instances with 3 files. This is because the scope for Object is 3, but one of those atoms is the Root, so only 2 atoms are free to become files or non-root directories.




run scope_3 {} for 3






After the overall scope, we can assign additional scopes to specific top-level and extension sub-signatures that override the overall scope (you cannot assign scopes to subset signatures). These additional scopes are declared after the overall scope with a keyword but and separated by commas. For instance, the following command overrides the overall scope for signature Name.




run names_2 {} for 3 but 2 Name






If you declare a scope for a specific signature that conflicts with its multiplicity constraint, you’ll get an error. Namely, one signatures must have scope 1, lone signatures scope less than or equal to 1, and some signatures greater than 0. Also, you can never declare a scope for an enumeration signature.

In general, assigning a specific scope to a signature does not affect the scope of its parent nor its siblings. There are however exceptions, namely when specific scopes are assigned to the extensions of a signature. If the extensions have exact scopes (if they are singleton signatures or, as will be explained later, have an exact scope defined in a command) than the scope of the parent signature is automatically increased so be at least the sum of the scopes of the extensions. If the parent signature is abstract and does not have a specified scope then the overall scope will also be automatically overrided to be the sum of the specified scopes of the extensions (even if these scopes are not exact). For example, in the following command, the scope of Object is actually increased from the overall specified scope of 3 up to 6.




run files_3_dirs_3 {} for 3 but 3 Dir, 3 File






Note that this second case only happens if all extensions signatures are assigned a specific scope. Moreover, there is another corner case implemented in calculating the scope of abstract signatures: if all extension signatures are assigned a specific scope except one, then that one gets the scope remaining from the abstract parent signature, which is not increased. This may have unexpected consequences. For instance, the following command yields no instance, because there is a single extension signature of Object without a specific scope assigned, namely File, so it gets what remains of the scope on Object minus the scope on Dir, which is 0.




run dirs_3 { some File } for 3 but 3 Dir






The actual scopes being used by the Analyzer can be consulted in the information reported by the Analyzer. For instance, for the two commands above, the following information would be reported.

[image: ../../../../_images/log13.png] 

More information about how these scopes were calculated is provided if the logging verbosity is increased through menu option Options ‣ Verbosity.

If you assign a specific scope for every top-level signature of the model, you can actually omit the overall scope; otherwise, an error is thrown. For instance, the following command is valid in our running example.




run no_overall {} for 3 Object, 2 Name, 2 Entry






All scopes considered until now impose an upper-bound on the number of atoms. Specific signature scopes can also be marked with keyword exactly, which forces them to contain exactly that amount of atoms. For instance, the following command guarantees that there exist exactly 2 files in every instance.




run files_exact2 {} for 3 but exactly 2 File

Documenting expected outcomes

A complex model often contains several run and check commands. Sometimes we want to encode negative run commands to show that a certain class of instances is disallowed, or invalid check commands to register some known issues. We could use comments to annotate which is the case, but Alloy allows the user to register what is the expected outcome of a command using a keyword expect after the scope declaration. The expectation is that the command is either satisfiable (1) or unsatisfiable (0). A command is satisfiable when it is able to generate an instance. So a run command that yields instances is satisfiable, and a valid check command that finds no counter-examples is unsatisfiable. When executing such commands, the Analyzer will inform the user whether the result was the expected.

Let us recall the file system example developed in the Structural modeling chapter. Let us say that, for demonstration purposes we want to be able execute the invalid version of the no_partitions assertion that we encountered when the incorrect fact no_self_containment was enforced rather than the stronger, fixed no_indirect_containment. This would require those constraints to no longer be enforced as a fact (which would apply to all commands), but as a predicate that is only enforced in the appropriate command. Likewise, we won’t be able to use a single assert since we now have two distinct properties to check. A possibility is to encode them as follows.




pred no_self_containment {

   // Directories cannot contain themselves

   all d : Dir | d not in d.entries.object

}



pred no_indirect_containment {

  // Directories cannot contain themselves directly or indirectly

  all d : Dir | d not in descendants[d]

}



pred no_partitions {

  // Every object is reachable from the root

  all o : Object | reachable[o]

}






Then we can call the appropriate restriction as a premise to checking no_partitions. This would be done as follows.




check bad_containment {

  no_self_containment implies no_partitions

} for 6 expect 1



check good_containment {

  no_indirect_containment implies no_partitions

} for 6 expect 0






The first command is expected to generate a counter-example, but not the second one, as stated by the expected outcome. After execution, the Analyzer would report the results as follows.

[image: ../../../../_images/log23.png] 

Recall, however, that once no_self_containment becomes a predicate, it is no longer enforced in any command. For instance, to generate valid file systems without any additional constraint, one would have to adapt the example run command as follows.




run example { no_self_containment }






Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/commands/documenting-expected-outcomes

Further reading

Encoding test instances

run commands can be used to encode unit tests for our specification. Learn how to write commands of that kind.

Encoding test instances

Further reading

Working with integers

Scopes for the built-in type Int work differently. Learn how to properly handle them.

Working with integers

Further reading

Model finding

The Analyzer uses a technique called model finding to execute the commands. Learn how this works.

Model finding

 





Visualization customization

The visualizer provided by the Analyzer is one of the most popular features of Alloy, since it allows the inspection and navigation of scenarios or counter-examples. However, as models become more complex, the interpretation of instances becomes more challenging. To ease this process, the visualizer allows the graphical visualization of instances to be customized through themes.


Theme customization

Let us get back to our file system example from the Structural modeling chapter and focus on an instance generated by command example. With the default visualization of the instances, it looks as follows.

[image: Get the code to generate this instance.]

To customize it, we can open the theme customization menu, by pressing the button Theme in the toolbar of the instance visualizer pop-up window. The first customization we will apply is to show the names of directory entries as attributes in the respective atoms, instead of using arrows pointing to the name. This will unclutter substantially the depiction and is a very common customization for fields of multiplicity one, in particular for fields that somehow act as identifiers, as is the case of name. To do so, first select the field name, and then tick the Show as attribute option in the top pane. This option will show the name of an entry as an attribute but still keep the respective arrows. To remove them, tick twice Show as arcs to choose the Off option. Your theme options for relation name should look as follows.

[image: ../../../../_images/theme1.png] 

By pressing Apply in the toolbar and then Close the instance will now be depicted as follows.

[image: Get the code to generate this instance.]

We now have some unconnected Name atoms. Since names were only used in directory entries, where they are now shown as attribute, we can remove them from the graph. To do so, select Theme again (actually when changing many options it is better to keep the theme customization menu open and just keep pressing Apply without closing it to see the effect), select the Name signature, and then tick the Show option twice to choose the Off option. After pressing Apply the Name atom will disappear.

[image: ../../../../_images/theme2.png] 

Another common customization is to give different colors (or different shapes and borders) to atoms belonging to different signatures. First, we will select a different color palette, with more subdued colors. To do so, select the general graph settings, and then select the Martha palette both for node and edge colors. After pressing Apply we will get some nice faded colors.

[image: ../../../../_images/theme3.png] 

Notice that since version 6.2 of Alloy, the visualizer features a colorblind-friendly palette called Tol, inspired by (but not completely equivalent to) one of Paul Tol’s color schemes.

Since entries are auxiliary structures in defining the (supposedly) tree-like structure of the file system, we will paint them gray. To do so select signature Entry, then the color Gray in the drop-down menu in the top left-hand corner, and finally Apply.

[image: ../../../../_images/theme4.png] 

For file system objects we will choose a more eye-catching red color. We don’t have to set this color separately for signatures Dir, Root and File. By default most theme options of extension signatures are set as Inherited from their parent signature. As such, it suffices to set the color red for the Object signature, and both their children will inherit this setting. You also have the option to set the color to Magic, which will assign a different color to each extension signature, instead of the default yellow. That is actually the default setting for the color of edges, as you can see by the colors of entries and object. Finally we will choose different shapes for different file system objects. Let’s keep files as rectangles, but choose the shape Trapezoid for directories and a House for the root. The shape can be chosen in the drop-down menu in the top right-hand corner. The combo-box to the left of that one allows changing the style of the border. After pressing Apply we have the following visualization.

[image: ../../../../_images/theme5.png] 

One last customization that is often useful is to change the label of an element in the graph, be it a signature, a subset or relation (for instance, to make it shorter, or to remove the namespace prepended to elements from imported modules). This can be changed in the text box in the top left-hand corner after selecting an element.

Managing themes

For the moment these are all the customizations we will use, and so we can close the theme customization menu. Notice that you can always reset your theme settings by going to the menu option Theme ‣ Reset theme. You can also save your theme for later use in the option Theme ‣ Save theme. Occasionally it is also useful to have multiple themes for the same model, highlighting different facets of the instances.

Instead of customizing manually your theme, you can also try out the Magic Layout button in the toolbar of the instance visualizer. This will “magically” choose options for visualizing the different elements of your specification based on the signature and field declarations. Sometimes the results are good enough and it will save you some work. The result of magic layout for our instance is the following.

[image: Get the code to generate this instance.]

More information about how the magic layout actually works can be found in [LED07]. In this case we prefer our handmade customization and so we will load back our previously saved theme by selecting Theme ‣ Load theme in the menu.

[image: Get the code to generate this instance.]



Improving visualizations with derived relations

Alloy supports the definition of derived relations through the declaration of functions, whose return type can be any relational expression with arbitrary arity. Parameterless functions are processed by the visualizer and presented alongside the signatures and fields of the instance, even if not used in the specification at all. This section shows how to explore this feature for further tweaking instance visualization.

Let’s say that we want to highlight in our visualization the directories that are empty. A possibility would be to introduce a new subset signature and restrict its value to always be the set of empty directories. However, due to the nature of the Alloy analysis procedures, such a signature would have to be solved by the Analyzer, possible impacting its performance. If we introduce a function that calculates this set, the Analyzer will calculate its value after the instance is generated and present it in the visualizer. Since they are introduced by the visualizer after the solving process, they can be used without undermining the performance of the analysis. Such a function that retrieves all empty directories would be defined as follows.




fun empty_dirs : set Dir {

  Dir - entries.Entry

}






For instance, using the same instance as above, the visualization would now be as follows.

[image: Get the code to generate this instance.]

Notice how the empty directory at the bottom has an additional label $empty_dirs. All visualization elements introduced in the visualizer that are not part of the model are prefixed with a $. Since function empty_dirs returns a set, it is interpreted as a subset of Dir which by default are shown as labels in the theme. As expected, their depiction can be customised as any other signature. For instance, to highlight empty directories in the depiction, open the theme customisation menu, and set the border of $empty_dirs subset of Dir to be Dotted and the displayed name to just empty. The resulting depiction is below. You could also hide the label of this subset altogether by just setting to Show as labels to Off for $empty_dirs.

[image: ../../../../_images/theme6.png] 

Parameterless derived functions are introduced in the visualization regardless of their arity, resulting in additional edges for relations of arity higher than 1. For instance, let’s say we wanted to directly depict the relation between directories and their content, hiding the entry intermediary atoms. We could define the binary relation below in the specification.




fun contents : Dir -> Object {

  entries.object

}






Running the command again results in the depiction below, with $contents edges directly between directories and objects.

[image: Get the code to generate this instance.]

Once we start introducing derived relations, it is often useful to hide others elements in order to unclutter the visualizer. In this case, we simply set Show to Off for the Entry signature, resulting in the compact depiction below where the content of directories is evident.

[image: Get the code to generate this instance.]

A consequence of short-circuiting entries in the visualizer is that we can no longer see the name of the objects inside a directory. Relations with arity higher than 2 are depicted in the visualizer as edges with labels. Thus, a ternary relation between signatures Dir, Name and Object could be used to directly show the content of a directory but also show its name in a label. Defining such relations is often not trivial, and usually requires defining relations by comprehension. In this case this ternary relation could be defined as follows.




fun named_contents : Dir -> Name -> Object {

  { d : Dir, n : Name, o : Object |

    some e : Entry | e in d.entries and e.name = n and e.object = o }

}






Here, we are collecting all triples d->n->o such that there is an entry in d that has name n and object o. The resulting depiction is shown below, where the names of the objects inside directories can be seen as a label of the $named_contents edges.

[image: Get the code to generate this instance.]

Alternative visualizations

As a last note, it is worth mentioning that the Analyzer also supports alternative visualizations other than the graph one we’ve explored in this chapter. In the visualizer toolbar, buttons Viz, Txt, Table, and Tree control the representation of the instance. Option Viz is the default graph representation, while the other 3 are textual representations of the relations in plain text, tabular format, and in hierarchical structure, respectively. For illustration purposes, below is the representation of the same instance in tabular format, where each table denotes a signature and the associated fields. Despite the usefulness of the graph visualization, when instances become too complex these simpler representations can prove helpful.

[image: ../../../../_images/table1.png] 

Higher-arity relations

In the main chapter we’ve seen how to introduce unary relations (as signatures) and binary relations (as fields), and how to compose them in relational expressions. However, Alloy actually supports relations of arity higher than 2: they are simply seen as a set of tuples of a certain arity. We call a relation with arity n > 0 an n-ary relation, and it must be uniform (i.e., all tuples in it must have arity n). Sets and binary relations are 1-ary and 2-ary relations, respectively. Most of Alloy’s relational operators actually apply to relations of arbitrary arity (except for a few that only apply to binary relations). This chapter explores relations with arity higher than 2, which we denote as higher-arity relations to distinguish from sets and binary relations.


Declaring higher-arity fields

Let us get back to the file system example from the Structural modeling chapter, where the content of a directory is specified by a set of entries that assign a name to each of its objects. Using only binary fields, the solution we implemented used a signature Entry to register exactly one name and one object; then a field entries assigned a set of Entry atoms to each directory. These entries are not really an essential part of the design of the file system and are not the target of any of the expected properties, but were required to group names and objects in a single entity.

An alternative to this approach would be to store the objects and names contained in a directory directly, without creating the auxiliary Entry signature. In practice, this entails removing the Entry signature and the entries field, and instead create a ternary field relating directories, names, and objects. In Alloy, such a field could be simply declared as follows:




sig Dir extends Object {

  contents : Name -> Object

}






The range type expression in the declaration of contents is now the Cartesian product of Name and Object, meaning each directory is assigned an arbitrary set of pairs each with a name and object inside that directory. Field contents itself is a ternary relation that is a subset of the Cartesian product Dir -> Name -> Object. A ternary field is simply a set of flatted triples, and likewise binary relations can be navigated in both directions.

In theory, we can declare fields of an arbitrary arity in an Alloy model. In practice, relations with a large arity become impossible to processed by the Analyzer. This limit depends on the size of the universe of discourse. For instance, a 5-ary field can only be represented in universes with less than 74 atoms. However, in our experience, relations with arity higher than 3 are very rarely useful, as manipulating them in constraints becomes very cumbersome. It should also be noted that higher-arity relations can sometimes help reduce of the size of the universe. In our example, by avoiding the creation of auxiliary signature Entry we removed all those atoms from the universe.

Visualizing higher-arity fields

Let us for now ignore all additional facts that we had defined for the file system model (which we will need to adapt to the new ternary field), and just run the empty example command. We need to remove any scope assigned to Entry since that signature no longer exists. We will get instances such as the following.

[image: Get the code to generate this instance.]

Notice how ternary relations are still represented as edges in the Analyzer’s visualizer, namely edges between the first and the last in each tuple; the middle atom is shown as a label in the edge. So, in this instance, Root contains File0 with name Name0 and Dir with Name1. For fields of arity higher than 3, additional atoms would added to the labels of the edges separated by commas.

Specifying constraints

The instance above exhibits many of the issues that we addressed in the main chapter. Let us adapt the facts to the new version of the model with a ternary field. Most relational operators work for higher-arity relations as they do for binary ones. Set operators such as intersection (&), union (+), and difference (-) can be applied between two relations of the same arbitrary arity. Composition also applies to higher arity relations. If you have a directory d, d.contents is a binary relation within Name -> Object containing all pairs of names and objects assigned to d by contents. Likewise, for an object o, contents.o is a binary relation pairing directories with the names that object o has inside them.

The first fact in the model, unique_names, forced different entries of a directory to have distinct names. The original version of this fact calculated all entries of each directory with a given name, and forced the resulting set to have at most one value. In the new version, we can follow a similar strategy, as follows.




fact unique_names {

  // Different entries in the same directory must have different names

  all d : Dir, n : Name | lone n.(d.contents)

}






If d.contents is a binary relation containing alls pair of names and objects assigned to d, n.(d.contents) is a unary relation with the objects assigned name n in directory d. Since we want at most one object with each name in a directory, we restrict this set to have cardinality lone. Parenthesis are needed here because composition associates to the left and n.d is not a valid expression (it would have arity 0).

Interestingly, once we encode the content of a directory as a ternary relation, we can actually enforce this constraint directly when declaring the field. Higher-arity fields can also be restricted by multiplicity constraints in their declaration. In this case, we want to enforce that for any directory, and for any name, there is at most one object related by contents. This could be enforced as follows, as an alternative to fact unique_names.




sig Dir extends Object {

  contents : Name -> lone Object

}






The second fact, no_shared_dirs, forced every directory to appear at most in one entry. This one can be trivially adapted to the ternary field as follows. Relation contents.d is a binary relation that pairs all directories that contain d with the respective names. Since a directory can only be contained in a single directory we should restrict the cardinality of his expression with lone.




fact no_shared_dirs {

  // A directory cannot be contained in more than one entry

  all d : Dir | lone contents.d

}






Fact no_dangling_objects forced all objects, except the root, to be contained in some entry. In the previous version, expression Entry.object denoted every object referred by any entry. In the ternary version, we must retrieve all objects related to any object by any name, which is represented by expression Name.(Object.contents). Given this expression, the fact could be trivially adapted as follows.




fact no_dangling_objects {

  // Every object except the root is contained somewhere

  Name.(Object.contents) = Object - Root

}






Fact one_directory_per_entry is no longer needed in this version of the model because we no longer have entries.

Defining relations by comprehension

All the facts we have adapted thus far were as complex to specify with the ternary field as they were with the auxiliary signature Entry and the binary entries field. Unfortunately, that is not always the case, and the last remaining fact, no_indirect_containment, is a bit tricky to encode with the ternary contents field. That fact, through function descendants, relied on the transitive closure of the binary relation entries.object to collect all objects indirectly contained in a directory. However, when two ternary relations are composed, the result is actually a quaternary relation. For instance, with the ternary contents, contents.contents is a quaternary relation contained in Dir -> Name -> Name -> Object. So the transitive closure operations are not well-defined for non-binary relations, and are forbidden in Alloy.

By inspecting function descendants, it is obvious that the name of the objects inside a directory is irrelevant to calculate this relation, so what we need is to convert ternary field contents in Dir -> Name -> Object to a binary version in Dir -> Object that relates directories with their content disregarding the name. Unfortunately, there is no straightforward way to achieve this using only relational operators, and we need to rely on defining this relation by comprehension.

Relations can be defined by comprehension by quantifying over a sequence of variables, and keeping only the tuples that satisfy a formula defined over those variables. All relational operators (except closures) can be rewritten using a relation by comprehension. For instance, expression Object - Root above could be rewritten as { o : Object | o not in Root }, and Dir + File as { o : Object | o in Dir or o in File }.

For our example, we want to take all directories and objects such that they are related by some name in contents. This can be specified as a binary relation defined by comprehension that “selects all directories d and objects o such that d is related to o through some atom”. Let us define a new auxiliary function objects that provides this derived relation.




fun objects : Dir -> Object {

  { d : Dir, o : Object | some d.contents.o }

}






Equipped with this relation, it is now trivial to adapt function descendants (and consequently, fact no_indirect_containment) to the ternary field as follows.




fun descendants [o : Object] : set Object {

  o.^objects

}






Manipulating ternary relations can become cumbersome, so the Analyzer actually provides a utility module util/ternary that defines functions to project and flip ternary relations. The one we just defined, that retrieves the first and last columns of a ternary relation, is provided by function select13.

If we now run the empty example command once again, we will get instances such as the following, where the issues seem to have been fixed.

[image: Get the code to generate this instance.]

You’ll notice that there is now a new element in the visualization, the value of function objects prefixed by a $. Alloy introduces all functions without parameters in the visualization, and in one of the advanced topics we show how these can be used to improve the visualization of instances. For now we can just hide it as any other relation by choosing Off in the Show as arcs theme option for objects. This will result in the following cleaner instance.

[image: Get the code to generate this instance.]

To finish we should of course check the no_partitions assertion. Given that no_partitions was defined by calling function descendants (through predicate reachable), nothing needs to be adapted in this assertion. After executing the command, the Analyzer will report no counter-examples, as expected.

As a last note, it’s not always evident when higher-arity relations should be used in a model. There is a sweet spot where employing a few higher-arity relations (almost always, ternary relations) improves the readability and maintainability of our specifications, while also improving the performance of the Analyzer by reducing the number of signatures and fields in a model (and thus the number of atoms and free relations to be solved). If too many higher arity relations are used (or relations of too high arity), models can become unmanageable and they can also have a negative impact on performance (since expressions can become considerably more complex).

The instance evaluator

The Alloy instance visualizer has an evaluator that can be used to compute the value of any relational expression or formula over the instance being inspected in the visualizer. For more complex instances and counter-examples, this feature is helpful to support their interpretation.


Evaluating expressions

To access this evaluator just press the Evaluator button in the toolbar of the instance visualizer window. To close the evaluator and return to the normal instance visualizer just press the Close Evaluator button in the toolbar.

To illustrate this feature, we will use an instance that could have been returned as the result of the empty run command example from Structural modeling chapter. While this is clearly a simple instance that could perhaps be easily understood through the visualization, as models and instances become more complex, so does the evaluator become more relevant.

[image: Get the code to generate this instance.]

To ask for the value of an expression just type it in the evaluator and press Enter. Every relational expression denotes a relation of a certain arity. By default, the visualizer depicts the values of the signatures and fields of an instance as labelled graphs. The visualizer can also be set to depict the value of a relation (of any arity) as a table where each line is one of the tuples contained in it. The evaluator uses this latter representation to show the values of relational expressions.

A basic use of the evaluator is to just ask for the values of the signatures and fields of the model, such as Dir or entries. However, we can actually evaluate the value of any relational expression. For instance, we can ask for the value of entries.objects to get the relation between directories and the objects they contain, or Root.^(entries.object) to get all objects indirectly contained inside the root using the transitive closure. We can also refer any auxiliary function defined in the model, so we can also just call function descendants to get the descendants of the root. The result is shown below. Note that you can navigate through the evaluator log with ↑ and ↓.

[image: Get the code to generate this instance.]

Evaluating formulas

The evaluator can also be used to ask for the values of arbitrary formulas, which makes it very useful and convenient to debug constraints. For example, when inspecting a counter-example, we can use the evaluator to find out which sub-formulas of a constraint have been broken in that particular case. Below is an example where we evaluate certain formulas over this instance, such as testing whether there are any directories besides the root, or whether the root is indirectly contained in itself. As expected, you can also call any auxiliary functions and predicates defined in the model to ease this process. So we test whether the root is in its own descendants using function descendants, or even using the reachable predicate directly.

[image: Get the code to generate this instance.]

Referring to atoms

Another feature of the evaluator that is sometimes helpful is that, when inspecting an instance, unlike when writing a specification, we can refer to concrete atoms in expressions. This is possible because the universe of atoms for a specific instance is known during evaluation. To refer to a concrete atom in the evaluator, you should use the label of its most specific extension signature as the prefix and its numerical identifier as a suffix, separated by a $ mark (except for special atoms such as those from Int). Note that subset signatures do not affect the name of an atom (since each atom may belong to multiple subsets). Back to the example, you can for instance query the object of entry Entry$2 with Entry$2.object, or find out all objects that have name Name$1 with (name.Name$1).object. Or you can call descendants on Dir$0 to find out the indirect contents of that directory.

[image: Get the code to generate this instance.]

You might have noticed that in this instance, the atoms of Dir and File do not appear numbered in the visualization. This is because, by default, the visualizer does not number the atoms of signatures that directly contain just one atom to improve readability (in this case signature Dir actually has 2 atoms, but one of them is in a more specific extension, Root). To refer to those atoms, you can use index 0, namely Dir$0 and File$0 (note that a call to Dir refers to the signature and will actually return Dir$0 and Root$0).

This mismatch between the names of the atoms in the evaluator, and the pretty-printed version in the graphical visualizer can be a source of confusion. For instance, if you try to call Entry2 you’ll get an error as that atom does not exist (and it could actually refer to another signature since signature names are alpha-numerical). In fact, we can even change the name of the atoms in the graphical visualization through theme customizations, but these do not apply to the evaluator, and the new name of atoms in the graph will not be recognized by the evaluator. If this gets confusing, you can always temporarily tick the option Use original atom names in the theme customizer, and all atoms in the visualization will be shown with their original name as in the evaluator. Below is the result after changing this option in the theme.

[image: Get the code to generate this instance.]

Visualization customization

We’ve mentioned that the visualizer can be customized. Learn in more detail how this can simplify the understanding of instances.

Arrow multiplicity constraints

When declaring fields in an Alloy model, one can only restrict the multiplicity of the target signature. Multiplicities on the source signature can be enforced in facts using regular relational logic, as we’ve seen in the Structural modeling chapter. However, Alloy also provides a special formula syntax to directly constrain the multiplicities of both end points of a relation.




Enforcing multiplicities with arrows

Consider a relation r between atoms of signature A and atoms of signature B. Let’s say we want to state that r relates every atom of source signature A to at most one atom of target signature B, and every atom of B to at least one atom of A, we could write the formula r in A some -> lone B. This kind of atomic formula can use the same multiplicities as the declaration of signatures and fields (set, some, lone, and one). Not stating a multiplicity next to an end point is the same as having multiplicity set.

Recall fact no_shared_entries from the Structural modeling chapter, repeated below.




fact no_shared_entries {

  // Entries cannot be shared between directories

  all e : Entry | lone entries.e

}






With this special syntax, we could rewrite it simply as follows.




fact no_shared_entries {

  // Entries cannot be shared between directories

  entries in Dir lone -> Entry

}






The constraint entries in Dir lone -> Entry forces relation entries to be injective, a relation where no two atoms of the source signature point to the same target atoms. This is one of the four basic properties of relations we can obtain by varying the multiplicities of the source and target signatures. If we had entries in Dir some -> Entry we would have a surjective relation, one where every atom of the target is related to some source atom. If entries in Dir -> lone Entry relation entries would be simple (or a partial-function), a relation where every source atom is related to at most one target. And if entries in Dir -> some Entry relation entries would be entire (or total), since every source atom is related to at least one target.

As another example, recall the fact one_directory_per_entry.




fact one_directory_per_entry {

  // Entries must belong to exactly one a directory

  all e : Entry | one entries.e

}






This could also be rewritten as the following fact, stating that entries is both injective and surjective (note that multiplicity one is the combination of multiplicities lone and some).




fact one_directory_per_entry {

  // Entries must belong to exactly one a directory

  entries in Dir one -> Entry

}

A bestiary of binary relations

By combining these four properties we get additional well-known kinds of relations. A relation that is both entire and simple is a function: every atom of the source is related to exactly one target. A representation is a relation that is both entire and injective, and dually, an abstraction is a relation that is both simple and surjective. An injection is a function that is also a representation, and a surjection is a function that is also an abstraction. Finally, by combining all four basic properties we get a bijection: a one-to-one mapping between the source and the target signatures. The following table summarizes these properties, and presents the full “bestiary” of binary relations that can be obtained by imposing multiplicity constraints on the source and target signatures.





	injective

	entire

	simple

	surjective




	A lone -> B

	A -> some B

	A -> lone B

	A some -> B




	representation

	function

	abstraction




	A lone -> some B

	A -> one B

	A some -> lone B




	injection

	surjection




	A lone -> one B

	A some -> one B




	bijection




	A one -> one B

Beyond restricting fields

Multiplicity arrows are more expressive than setting the multiplicity of a field between signatures, and can actually set the multiplicity of an arbitrary relation between arbitrary domains and ranges. Recall fact no_shared_dirs from the main chapter.




fact no_shared_dirs {

  // A directory cannot be contained in more than one entry

  all d : Dir | lone object.d

}






This pattern looks like the one for injectivity, but it is only restricting the portion of field object that relates to directories (object is a relation from Entry to Object). Using the Alloy range restriction operator :>, we can obtain the portion of object related to directories (object:>Dir), and then restrict it to be injective with a multiplicity arrow. This would result in following equivalent version of no_shared_dirs.




fact no_shared_dirs {

  // A directory cannot be contained in more than one entry

  object:>Dir in Entry lone -> Dir

}






For yet another example, recall fact no_dangling_objects.




fact no_dangling_objects {

  // Every object except the root is contained somewhere

  Entry.object = Object - Root

}






Expression Entry.object retrieves all objects related to an entry. By equalling it to Object - Root, we’re saying that every object, except the root, must be related to some entry by object. So we’re essentially stating that object is surjective on a restricted range. So the following is an equivalent version of no_dangling_objects using multiplicity arrows.




fact no_dangling_objects {

  // Every object except the root is contained somewhere

  object in Entry some -> (Object - Root)

}

Further reading

Higher-arity relations

These multiplicity arrows can also be applied to higher-arity fields. Learn how to use higher-arity relations.

Higher-arity relations

Further reading

A relational logic primer

If you’re not familiar with operators like :>, you can learn about the full syntax and semantics of Alloy’s relational logic.

Type system

The Alloy language is notably flexible, and so is its type system. Alloy’s type system was designed to detect three types of errors that can occur in relational expressions:


	arity errors, when an operator is applied to relations of incorrect or mismatching arities;


	irrelevance warnings, when an expression always yields an empty set regardless of the instance and thus is irrelevant;


	ambiguity errors, when the type system cannot disambiguate between various overloaded relations.







Arity errors

In Alloy, all relations must have a uniform arity greater than 0 (i.e., all its tuples must have the same positive arity). A first consequence of this, is that relational operations union +, intersection &, difference - and override ++, are only well-typed if applied two to relations of the same arity. For instance, the following throws an arity error, since File is unary and entries binary.




no File + entries






[image: ../../../../_images/log16.png] 

To ensure the positive arity, you also cannot compose two relations of arity 1 (recall that the composition of an n-ary and an m-ary relation results in a relation of arity n+m-2). So formulas such as the following are invalid in Alloy.




all o : Object | o.Dir






Finally, some operators can only be applied to relations with a specific arity. Namely, the transpose ~, transitive closure ^ and reflexive transitive closure * can only be applied to binary relations, while the domain restriction <: and range restriction :> require a unary relation on the left-hand and right-hand side, respectively.

Irrelevance warnings

Alloy allows relations between different signatures to be combined, as long as they have the same arity. For instance, even though field entries is only defined for directories, we’ve actually applied it to arbitrary objects in the fact no_indirect_containment, by calculating the closure of entries.object: it just happens that entries will return an empty set for files. Likewise, expressions such as Object.entries are also perfectly acceptable. You can also put together atoms of signatures that are completely unrelated. The union Object + Name is a valid expression even though objects and names belong to distinct top-level signatures. And (Object + Name).entries is also acceptable, although it is not particularly useful since only the Dir atoms of Object will contribute to the final result.

Concerning “mismatching” types, Alloy type system only reports warning to the user when an expression will necessarily result in the empty set, and in which case it is considered irrelevant. For instance, suppose we add the following fact to our model.




fact irrelevance_warning {

  no Dir.name

}






If we now execute any command we would get a warning: the Analyzer refuses to execute the command and tells us that the . operator will always yield an empty set.

[image: ../../../../_images/log24.png] 

You’ll get similar warning if you write an expression such as Dir & File, since the two relations being intersected are always disjoint. This warning issued by Alloy’s type system is one of the advantages of using extends to declare disjoint subset signatures, instead of relying on in and additional facts.

Note however that this is merely a warning to the user, and that the Analyzer can actually still execute the requested command. By default that option is disabled, but you can enable it through menu option Options ‣ Allow warnings. This will also allow models with other kinds of warnings to be executed (such as unused variable warnings). But in general irrelevance warnings are most likely specification errors made by the user and should be fixed. For instance, Dir.name could be a mistake easily introduced by a distracted user. If the user effectively wants to write an expression that always denotes an empty set, then the special constant none should be used instead, making that intention explicit.

To detect irrelevant expressions, Alloy type system calculates an expression bounding type, an upper-bound on the value of that expression. If that bounding type is empty, the expression is irrelevant and a warning is thrown. Bounding type inference is guided by the abstract syntax and is bottom-up. What is interesting is that the type inference uses the same operators as the expressions for which the type is being inferred, but rather than manipulating tuple sets of atoms, it manipulates tuple sets of types.

The type of an expression is a tuple set of atomic types. There is an atomic type A for every extension signature A that is not extended further. For a non-abstract signature A that has some extension, an atomic type is also created to denote the atoms that do not belong to any of its extensions. This remainder atomic type is denoted by $A. For our example, the atomic types corresponding to declared signatures are Root, File, Name and Entry, while $Dir represents the remainder directories (i.e., directories other than the root).

The bounding type of each signature and field is then specified by a tuple set of atomic types. The bottom-level signatures simply have its own type. For instance, File has type {(File)} and Name type {(Name)}. Other signatures have a type that is the union of its sub-signatures. So for our example, Dir has type {(Root),($Dir)} and Object type {(Root),($Dir),(File)}. The bounding type of fields is defined in a similar way considering the type of the related signatures. For instance, name simply has type {(Entry,Name)}, while entries has type {(Root,Entry),($Dir,Entry)}. The bounding type of an expression is calculated by directly applying the operation at the bounding type level. Below is the process for expression (Object + Name).entries. For each sub-expression, the application of the operator at the type level is shown to depict how the bounding type is calculated.










	Object

{(Root),($Dir),(File)}

	Name

{(Name)}

	



	Object + Name

{(Root),($Dir),(File)} + {(Name)}

{(Root),($Dir),(File),(Name)}

	entries

{(Root,Entry),($Dir,Entry)}




	(Object + Name).entries

{(Root),($Dir),(File),(Name)}.{(Root,Entry),($Dir,Entry)}

{(Entry)}








In the end, an expression (other than none) is considered irrelevant, if its bounding type an empty tuple set. For instance, below is the bounding type calculation for irrelevant expression Dir.name.









	Dir

{(Root),($Dir)}

	name

{(Entry,Name)}




	Dir.name

{(Root),($Dir)}.{(Entry,Name)}

{}

Ambiguity errors

Alloy models can contain overloaded fields as long as the type system is able to disambiguate which version is being called in each expression. Let us consider an alternative version of our file system model, where both field entries of directories and field object of entries happened to have the same name contents.




sig Dir extends Object {

  contents : set Entry

}



sig Entry {

  contents : one Object,

  name : one Name

}






Commands such as the following are perfectly acceptable, because the Analyzer is able to infer that the relevant contents field in that case is the one for directories.




run not_ambiguous {

  some Root.contents

}






In fact, Alloy is able to disambiguate all occurrences of entries and object in the definitions of the system model after they are both renamed to contents. However, if you call field contents in a context that does not allow for disambiguation, you will get an ambiguity error due to multiple matches, such as in the command below.




run ambiguous {

  some contents

}






[image: ../../../../_images/log3.png] 

To perform this disambiguation, Alloy builds on the inference of the bounding types presented above to calculate the relevance type of an expression. After the bounding type of an expression is calculated, a top-down phase determines which expressions contributed to that bound. The relevance type of the outermost expression is its bounding type, and the relevance type of a sub-expression is the subset of its bounding type that contributed to the parent expression relevance type. Unlike the bounding type, the relevance type of an expression depends on the context it occurs, so the same expression can have different relevance types in different contexts. As an example, below is the calculus of the relevance types for expression (Object + Name).entries. For each expression, the bounding type is shown, and also the subset of that that corresponds to its relevance type.










	(Object + Name).entries

{(Entry)}

{(Entry)}




	Object + Name

{(Root),($Dir),(File),(Name)}

{(Root),($Dir)}

	entries

{(Root,Entry),($Dir,Entry)}

{(Root,Entry),($Dir,Entry)}




	Object

{(Root),($Dir),(File)}

{(Root),($Dir)}

	Name

{(Name)}

{}

	







So Name does not contribute to the final expression, nor does the File portion of Object.

To disambiguate between overloaded fields, the call to an overloaded field is replaced by the union of all fields with the same name. Then, when calculating the relevance type of the expression, if only one of those fields contributed to the final value, the overloading is disambiguated. Otherwise an ambiguity error is thrown. Below is the process for expression Root.contents.










	Root.(contents + contents)

{(Entry)}

{(Entry)}




	Root

{(Root)}

{(Root)}

	contents + contents

{(Root,Entry),($Dir,Entry),(Entry,Root),(Entry,$Dir),(Entry,File)}

{(Root,Entry)}




	
	contents

{(Root,Entry),($Dir,Entry)}

{(Root,Entry)}

	contents

{(Entry,Root),(Entry,$Dir),(Entry,File)}

{}








So the Analyzer infers that the contents of Object is the only one that contributes to the expression, so there is no ambiguity.

More information about Alloy’s type system can be found in [FSE04].

A note on predefined types

This chapter focused mostly on how Alloy’s type system deals with user defined signatures. But the reader may wonder if Alloy has any predefined types, such as integers or strings. And if that is the case, why haven’t we used, for instance, strings to represent names of objects in our file system example, instead of declaring a new signature Name?

Alloy does indeed have a couple of predefined types, namely signatures Int for (bounded) integers and String for strings. However, these types should be avoided as much as possible, because their semantics is substantially more tricky than that of regular signatures, and analysis can be confusing and somehow crippled when using them (in particular with strings).

The fact is that in many cases, the semantics of such signatures is just too rich for the intended use: for example, strings can be concatenated and there is the notion of one string being a substring of another, but for the file system specification none of this is of interest when specifying the abstract concept of a name. The only thing we will need in this case is to check for name equality, and normal signatures and atoms already provide us that basic semantics.

People also tend to use integers when they actually need something much simpler, semantics-wise. For example, we sometimes need to specify a signature where there is some total order imposed over its atoms and, at first sight, integers are very convenient for that. However, integers have a richer semantics than just being a total order, and we can easily axiomatise a total order on a regular signature with some simple facts and thus avoid the analysis drawbacks that come with using integers.

So, when should you use String or Int? The former has very little use, and actually, even if recognized by the Analyzer, is not even part of standard Alloy. The latter is sometimes useful, for example when you effectively need to perform arithmetic operations in the specification, such as additions or subtractions. The Int type is discussed in detail in a dedicated advanced topic.

Further reading

A relational logic primer

Learn about all operators provided by Alloy’s relational logic and their arity restrictions.

Some models effectively require integers. Learn what are their limitations and how to properly use them in Alloy.

Working with integers

Further reading

The predefined ordering module

Learn how to impose a total order on a signature and avoid using integers unless absolutely necessary.

The predefined ordering module

 





Module system

Alloy provides a simple module system to promote the modularisation and reusability of models. In other chapters we’ve already seen how to use some of the utility modules that come packaged with the Analyzer. This chapter explores how to create new ones.


Declaring simple modules

To create a new module in Alloy you just need to create a new .als file and add it to the same directory as the main model, possibly inside other sub-directories. You can declare the module name using the module keyword, but note that only the file name is used to search for modules to be included. To include a module in another model, we must to use an open instruction with the path to the corresponding file (without the .als extension). The module and open instructions must appear at the top of the model, before any other declaration. After a module is opened all its definitions are included in the main module, and you can refer to them by their identifier directly, or use its full qualified name using a / separator. In particular, if the Analyzer is not able to disambiguate an identifier, you may use the qualified name to disambiguate. If this becomes cumbersome, you can open a module with an alias using the keyword as.

Let us get back to the file system example from the Structural modeling chapter. The constrains we have imposed on the file system mean that it is actually a directed acyclic graph (DAG) where nodes are objects. Additionally, it is a rooted graph, since there is a single node without a parent (Root). This shape is enforced by the combination of facts no_indirect_containment and no_dangling_objects in the original file system model, but since these are common constraints on graph-like structures, it makes sense to provide them in a separate module to promote reusability.

Let us create a new Alloy model file and name it graph.als. A binary relation over a set of nodes defines a DAG if it is acyclic. So we can just declare the following predicate, that checks this property for a given set of nodes and a binary adjacency relation over them.




pred dag [node : set univ, r : node -> node] {

  all n : node | n not in n.^r

}






On the other hand, a graph has a root if all other nodes are reachable from that node, a constraint that can be encoded as follows.




pred rootedAt [node : set univ, r : node -> node, root : node] {

  node in root.*r

}






Getting back to our file system model, the adjacency relation of the file system DAG is the relation between directories and the objects they contain, abstracting away the intermediate entry atoms, that is, the composed relation entries.object. So, after including the new auxiliary model with open graph, we could just enforce the following fact in the main module, replacing no_indirect_containment and no_dangling_objects.




fact rooted_dag {

  dag[Object, entries.object]

  rootedAt[Object, entries.object, Root]

}






Alternatively, we could have used the qualified names of the predicates as graph/dag and graph/rootedAt.

Parametrized modules

You may have noticed that all predicates declared above required as input the set of nodes on which the graph if formed. This can get a bit cumbersome, and can be avoided by using module parameters. Alloy modules can be declared with signature parameters, that are specified by the including modules. These are declared after its name in the module declaration between square brackets. These module parameters can be used as regular signatures in the model, including as the type of fields and predicates. The parameter declaration can also be marked with keyword exactly, which enforces an exact scope on that signature.

For our example, we would declare the graph utilities module as graph[node] so that the set of nodes comprising the graph get specified when the module is first opened. Then, the predicates within would be rewritten assuming that the set of graph nodes is now provided as a parameter of the module.




module graph[node]



pred dag [r : node -> node] {

  all n : node | n not in n.^r

}



pred rootedAt [r : node -> node, root : node] {

  node in root.*r

}






Note that you can still define commands in parametrized modules in order to validate them. In that case module parameter signatures will be treated as any arbitrary signature. For instance, we could write the following run command in our graph module.




run dag_example {

  some r : node -> node | dag[r]

} for exactly 4 node






This is an example of a higher-order quantification, possible in certain contexts due to Skolemization. A possible resulting instance is shown below.

[image: Get the code to generate this instance.]

Getting back to our file system example, we want to force a rooted DAG over file system objects. So we include the graph module as open graph[Object], and then rewrite the fact rooted_dag as follows.




fact rooted_dag {

  dag[entries.object]

  rootedAt[entries.object, Root]

}






What we just defined is actually part of the utility module util/graph, which builds on the util/relation utility module. These come packaged with the Analyzer, and contain many more common properties that can be tested over relations and graphs. They can be inspected through menu option File ‣ Open Sample Models….

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/modules/parametrized-modules

Further reading

Model finding

We’ve used a higher-order quantification solved through Skolemization. Learn in detail how this works.

Model finding



Adding fields to module parameters

Sometimes it is useful for auxiliary modules to declare additional structures to be used in the main importing module. New signatures, possibly with fields, can be introduced in the auxiliary module. However, we cannot declare new fields for the parameter signatures that are passed by the main module. However, there are some workarounds to this limitation.

For the sake of example, let us try to encode a simple auxiliary module that introduces timestamps in over a given signature. We’ll call this module timestamp, and it takes as a parameter the signature A to which the timestamps will be assigned, and the signature T representing the actual timestamps.




module timestamp[A, T]






Our timestamp module will be very simple for the sake of example: we want timestamps to be comparable, to be assigned to every A atom, and to be exhaustively used (i.e., no free dangling timestamps). To allow the comparison of timestamps, we can impose a total ordering over T with the utility module util/ordering.




open util/ordering[T]






Next, we want to define a new binary relation that assigns timestamps from T to elements of A. We cannot introduce new fields in A directly, but we can introduce a new auxiliary singleton signature with a ternary field between A and T, and then just project it when needed.




one sig TimeAux {

  aux_time : A -> T

}






For instance, to impose the desired multiplicity of the timestamp field, we can enforce the following fact. Note that since TimeAux is a singleton signature, TimeAux.aux_time simply returns a binary relation between A and T.




fact time_mult {

  TimeAux.aux_time in A some -> one T

}






Now, let us get back to our file system model and include this module. We define a new signature representing the timestamps, and then open the auxiliary module timestamp over the objects of the file system.




open timestamp[Object, Timestamp]



sig Timestamp {}






Field aux_time is now accessible from the main module, and we can impose additional restrictions on timestamps. For instance, we can force the timestamps of the contents of a directory to be after the timestamp of the directory itself as follows. Relation next is provided by util/ordering over the timestamps.




fact time {

  all d : Dir | d.entries.object.(TimeAux.aux_time) in d.(TimeAux.aux_time).*next

}






The new elements will also show up in the visualizer, as follows. Notice how atoms introduced by other modules appear with the qualified name by default. This label can be changed by customizing the theme.

[image: Get the code to generate this instance.]

While this strategy of defining a singleton auxiliary signature is perfectly functional, it is not ideal in terms of maintainability, since we have to keep projecting aux_time. Moreover, it appears as a ternary relation in the visualizer.

For this latter issue, the visualizer actually provides a functionality that can improve the visualization of these instances. On the toolbar, there is a Projection menu where you can select a signature to be projected in the visualization. For selected signatures, the visualization will show its contents projected by each atom, with a new combobox at the bottom of the visualizer allowing the selection of the highlighted atom. In this particular case, TimeAux is a singleton signature, so we are only projecting over a single atom, making the ternary aux_time a binary relation in the visualization. Below is the result after projection.

[image: Get the code to generate this instance.]

Further reading

The predefined ordering module

We’ve used the ordering module to impose a total ordering on timestamps, learn more about how it works.

The predefined ordering module

Further reading

Higher-arity relations

The aux_time is a ternary field. Learn how to use such higher-arity relations.

Higher-arity relations

Further reading

Arrow multiplicity constraints

Learn how to use arrow multiplicity constraints, like the one used in fact time_mult.

Arrow multiplicity constraints



Private declarations

To avoid using the projected ternary relation, we can derive a binary relation from the auxiliary aux_time by declaring an auxiliary function that projects away TimeAux, as follows.




fun time : A -> T {

  TimeAux.aux_time

}






We want to provide this derived relation to including modules, and hide the fact that it uses an auxiliary signature. Alloy allows any declaration in a module to be marked as private. This makes the element inaccessible from any module that includes the auxiliary module. In our example, we can make TimeAux (and the field within) private as follows.




private one sig TimeAux {

  aux_time : A -> T

}






Now TimeAux is no longer visible in the file system module, but only the derived relation time. So the fact shown above would be rewritten as follows.




fact time {

  all d : Dir | d.entries.object.time in d.time.*next

}






If you now generate an instance you’ll see the binary time connecting objects to timestamps (labeled $time since it is a derived relation).

[image: Get the code to generate this instance.]

Of course you can always customize the theme to hide timestamp atoms and show time as an attribute.

[image: Get the code to generate this instance.]

You may notice that, although private signatures are omitted, the corresponding atoms still belong to the universe (there is no notion of private atom). So, for instance, if you evaluate univ in the evaluator atoms from private signatures will appear. In our file system example, you’ll see in the universe an atom timestamp/TimeAux$0 representing the singleton auxiliary signature TimeAux. Perhaps surprisingly, you’ll also see an atom timestamp/ordering/Ord$0. This because the approach just presented is precisely the one followed in util/ordering to introduce a total ordering over a given parameter signature with a derived relation next, and that atom corresponds to the singleton auxiliary signature introduced.

As a last note, you can include the same module multiple times with different signature parameters. For instance, here we could additional declare open timestamp[Entry, Timestamp] and an additional time relation would assign timestamps to entries. Alloy will try to disambiguate calls to time using its type system. For instance, the fact above would still be valid since from the type of d it identifies the time relation defined for objects. Nonetheless, it may help to open those modules with an alias using as.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/modules/private-declarations

Full models for this topic

Download and explore the files relevant for the model at this point of the book.

Further reading

The instance evaluator

We’ve used the evaluator to validate our model, learn in more detail how it works.

The instance evaluator

Further reading

Type system

We’ve mentioned the Alloy type system and the disambiguation of overloaded identifiers. Learn more about it.

Type system

 





The predefined ordering module

Alloy has some predefined modules in a special util namespace. One of them is util/ordering, a parametrized module that can be used to impose a total order in a signature. In particular, this module defines a next relation that given an atom returns the next atom in the total order, and two derived singleton signatures first and last with the first and last atoms of the order, respectively. Note that last is the only atom without a next atom in the order. Module util/ordering also defines several derived predicates and functions to compare and compute the maximum or minimum of sets of elements (for example, gt is a predicate that can be used to compare if one atom is greater than another, and max is a function that computes the maximum of a given set of atoms).


Declaring totally ordered signatures

For example, let’s suppose we wanted to enrich our file system model with the creation timestamp of each entry. Since we will want to compare timestamps, we could first declare a totally ordered signature Time as follows.




open util/ordering[Time]

sig Time {}






The definition of signature Entry could now be changed to include the creation timestamp attribute.




sig Entry {

  object : one Object,

  name : one Name,

  time : one Time

}






Of course, we should impose a new constraint stating that the creation timestamp of an entry should precede that of its children.




fact children_timestamp {

  // The timestamp of an entry precedes that of its children

  all e : Entry, t : e.object.entries.time | lt[e.time, t]

}






Note the use of a chain of compositions to get all timestamps of all entries contained in the object of an entry. If the object is a file this set will be obviously empty and the constraint holds trivially. If it is a directory, then the timestamp of the respective entry must be less than those of all its children.

If we run the example command with a scope of 3, and customize the theme to show timestamps as attributes, we could get the following example filesystem.

[image: Get the code to generate this instance.]

You can see in the visualization relations first, last, and next introduced by module util/ordering. If we are not interested in seeing these relations in the visualization, we can omit them. In principle, this would make it very difficult to understand how the timestamps are ordered, and check if instances are valid. However, the module util/ordering is handled in special way be the Alloy Analyzer, which will attempt to name the inhabitants of the ordered signature sequentially according to the order defined by next. So you can see in our instance that Time0 is the first, which is followed by Time1, and then by Time3, which is the last. If we really want to confirm the value of the next relation we could go to the evaluator and ask for its value. However, we will get an ambiguity error since next is also defined in the util/integer module that is imported by default. To disambiguate we could type the qualified name ordering/next instead.

[image: Get the code to generate this instance.]

To see what other functions and derived relations are declared in util/ordering you can open it in the menu File ‣ Open Sample Models….

The above fact, imposing that the creation timestamp of an entry should precede that of its children, actually makes fact no_indirect_containment redundant, since it is no longer possible for directories to contain themselves directly or indirectly. We can confirm this by changing that fact to an assertion and using the Analyzer to verify it.




assert no_indirect_containment {

   // Directories cannot contain themselves directly or indirectly

   all d : Dir | d not in descendants[d]

}

check no_indirect_containment for 6






Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/ordering/declaring-totally-ordered-signatures

Further reading

Module system

Learn how to define your own modules in Alloy, and the strategy used in ordering.

Module system

Further reading

The instance evaluator

Learn how to use the evaluator, so that you can check the value of the next relation.

The instance evaluator



Analysis scopes

Besides naming the atoms according to the total order, module util/ordering has another peculiarity concerning the analysis. The scope of the signature that is passed as parameter to util/ordering is always exact even if not declared with exactly. The reason for this is to make analysis faster, but one should always be aware of this detail when running commands, as it can sometimes introduce inconsistencies, making run commands trivially unsatisfiable or check commands trivially valid.

As an example, consider the following (rather arbitrary) model of a finite sequence of natural numbers, distinguishing between even and odd numbers, and requiring the first in the sequence to be even and the last to be odd.




open util/ordering[Nat]



abstract sig Nat {}

sig Even, Odd extends Nat {}



fact {

  all n : Even | n.next in Odd

  all n : Odd | n.next in Even

  first in Even

  last in Odd

}



run example {}






If we execute the command example we get no instance! This is due to the fact that the default scope for Nat is 3, and since this signature is being totally ordered with util/ordering this scope is required to be exact. Unfortunately, with exactly 3 atoms in Nat it is impossible to satisfy the given constraints. If we change the scope of example to 4 then we will obtain one instance.

[image: Get the code to generate this instance.]

This is also an example where the naming of the atoms does not help in understanding what is the total order, since the ordered signature Nat is abstract and extended by Even and Odd. If you omit the util/ordering relations from the visualization, you can always use the evaluator to consult the atom order.

[image: Get the code to generate this instance.]

As a last note on scopes, for efficiency reasons the util/ordering module also requires the parameter signature to be non-empty (it forces first and last to always contain exactly one atom), meaning that setting its scope to 0 will also result in an inconsistent specification.

Download and explore the files relevant for the model at this point of the book.

Further reading

Commands in detail

Learn the full details about analysis commands and their scopes.

Commands in detail

  





A relational logic primer

In Alloy, constraints are specified in relational logic, an extension of first-order logic with a few operators to compose relations. In this chapter we will present this logic in detail, namely detail the semantics of each of the operators, illustrated with several usage examples.

Recall the file system model from the Structural modeling chapter, and consider the following instance of this specification, that will be used to illustrate the result of relational operators throughout the chapter.

[image: Get the code to generate this instance.]


Everything is a relation

Structures are described in Alloy using only (mathematical) relations. A relation is a set of tuples of objects drawn from the universe of discourse. Every tuple in a relation must have the same size, which is known as the arity of the relation.

For example, field name is a relation of arity 2 (a binary relation) relating entries with their names. For the above instance, it has four pairs, namely:




name = {(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}






In classical logic a relation is also known as a predicate, and the fact that predicate name holds for tuple (x,y) is usually denoted as name(x,y). As explained later, in Alloy this fact can be denoted by x->y in name.

A set can also be represented by a relation of arity 1. In Alloy, signatures are encoded in this way. For example, in the above instance, signature Dir has the value:




Dir = {(Root),(Dir0),(Dir1)}






Moreover, in Alloy even the constants and (quantified) variables are represented by relations, namely singleton relations of arity 1. A singleton is a relation with a single tuple. For example, signature Root, declared with multiplicity one, has the following value.




Root = {(Root)}






Do not confuse the two occurrences of the word Root in the above definition. On the left-hand side, we have the signature Root that was declared in our specification to denote the root of the file system. On the right-hand side, we have the atom Root, whose name was automatically generated by the Analyzer to populate signature Root. The name of this atom is actually irrelevant, but the Analyzer names atoms using the signature name as prefix and a sequential number as suffix. Actually, according to this naming convention, the name of this atom is Root0, and that is the name that will be depicted in the evaluator if you ask for the value of signature Root. However, in the visualizer, if there is only a single atom with a given name prefix, the numeric suffix is omitted by default. Here we will use the names chosen by the visualizer.

Since atom names are arbitrary, when specifying constraints in Alloy it is impossible to refer to them directly. If we need to distinguish a particular atom of the universe, we need to declare a singleton signature that will contain that atom and refer to that signature name instead. That was precisely what we did to distinguish the root of a file system.

An instance of an Alloy specification without mutable declarations is a complete valuation for all declared signatures and fields, mapping each of them to a relation of the appropriate arity. The value of all signatures and fields in our example instance is the following.




Object = {(Root),(Dir0),(Dir1),(File)}

Dir = {(Root),(Dir0),(Dir1)}

Root = {(Root)}

File = {(File)}

Entry = {(Entry0),(Entry1),(Entry2),(Entry3)}

Name = {(Name0),(Name1),(Name2)}



entries = {(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}

object = {(Entry0,File),(Entry1,File),(Entry2,Dir0),(Entry3,Dir1)}

name = {(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}






An instance also includes the values of the three predefined relations: none (the empty set), univ (the universe of all atoms), and iden (the identity relation on the universe). In our example instance their value is the following.




none = {}

univ = {(Root),(Dir0),(Dir1),(File),(Entry0),(Entry1),(Entry2),(Entry3),(Name0),(Name1),(Name2)}

iden = {(Root,Root),(Dir0,Dir0),(Dir1,Dir1),(File,File),(Entry0,Entry0),(Entry1,Entry1),(Entry2,Entry2),(Entry3,Entry3),(Name0,Name0),(Name1,Name1),(Name2,Name2)}

Download and explore the files relevant for the model at this point of the book.

Further reading

The instance evaluator

Learn how to use the evaluator to ask for the values of relational expressions.

The instance evaluator



First-order logic in a nutshell

Relational logic is an extension of first-order logic, which in turn is an extension of propositional logic. In propositional logic the simplest (atomic) formula is a proposition that checks if a Boolean variable is true. Compound formulas can be built by connecting atomic formulas using the standard logic connectives (or operators): negation, conjunction, disjunction, implication, and equivalence. These connectives are also available in Alloy’s relational logic, and their syntax is the following.





	Operator

	Name




	!, not

	Negation




	&&, and

	Conjunction




	||, or

	Disjunction




	=>, implies

	Implication




	<=>, iff

	Equivalence








As you can see, Alloy has a dual syntax for these operators, one with programming language style symbols and the other with English words. In this book we tend to use the latter, as the resulting formulas are more readable. The implies operator can also have an optional else to state what should be true when the condition on the left-hand side is false. Given arbitrary formulas P, Q, T, P implies Q else T is the same as (P and Q) or (not P and T).

In first-order logic we have a domain of discourse (or universe), and propositions are generalized by predicates that relate elements of this domain. Formulas can also be built using variables quantified over this domain. There are two standard quantifiers: the universal quantifier ∀x⋅\forall x \cdot P checks if a formula P (possibly referring to variable x) is true for all x in the domain; and the existential quantifier ∃x⋅∃ x \cdot P checks if a formula P (possibly referring to variable x) is true for some x in the domain. In Alloy all quantifications are bounded by a set, and English words are used instead of the standard mathematical notation. The following table presents all quantifiers that are available in Alloy: A is denotes an arbitrary set (a unary relation) and P an arbitrary formula. The first two are the standard universal and existential quantifiers.





	Quantifier

	Informal meaning




	all x : A | P

	P is true for all x in set A




	some x : A | P

	P is true for some x in set A




	no x : A | P

	P is false for all x in set A




	lone x : A | P

	P is true for at most one x in set A




	one x : A | P

	P is true for exactly one x in set A








It is well known that the existential quantifier can be specified with the universal one, and vice-versa, and the same is true for all other Alloy quantifiers. For example, some x : A | P is the same as not (all x : A | not P) and no x : A | P is the same as all x : A | not P.

Alloy’s rule that everything is a relation also applies to quantified variables: the quantified x that can be referred in P is a unary relation containing a single tuple with an atom of the universe.

It is also possible to quantify more than one variable at once, as in all x, y : A | P or all x : A, y : B | P. In the latter, the expression B can also refer to the first quantified variable x. It is also possible to add keyword disj to quantify over all different values of the bound variables. For example, writing all disj x, y : A | P abbreviates all x, y : A | x != y implies P. Note that the disj keyword only applies to groups of variables quantified over the same set. This means that in formula all disj x, y : A , w, z : B | P, w and z may take the same value (but not x and y). Also, be aware that although these multi-variable quantifications are equivalent to their expansion for all and some, that is not the case for one, lone and no. For example, consider formulas one x, y : A | x->y in r and one x : A | one y : A | x in r, and let r = {(A0,A0),(A0,A1),(A1,A0)}. The former formula is false because there are three tuples in r. However, the latter is true because there is exactly one x (A1) for which there is exactly one y (A0) in r.

Besides predicates, first-order logic also allows functions as non-logical symbols. Given some parameters a function returns an element of the domain. Since in Alloy the atoms of the universe are mostly uninterpreted there are very few predefined functions. The exception is when using integers, for which we have the standard arithmetic operations. If we do not consider functions, atomic formulas in first-order logic just check for equality of (quantified) variables or if a tuple of (quantified) variables satisfies (or is a member of) a predicate. In Alloy’s relational logic we have a few more atomic formulas, that are described in the following table, where R and S are arbitrary relations of the same arity, including sets.





	Atomic formula

	Informal meaning




	R in S

	R is a subset or equal to S




	R = S

	R is equal to S




	some R

	R contains at least one tuple




	lone R

	R contains at most one tuple




	one R

	R contains exactly one tuple




	no R

	R is empty








The negation of the subset or equality atomic formulas can also be written by placing the negation operator next to the comparison operator. For example, instead of not (R in S) it is possible to write R not in S or R !in S.

Since quantified variables are also (singleton) relations, although in stands for the ‘subset or equal’ operator (⊆\subseteq) it can also be used to check set membership (∈\in). As we will see below, given variables x1,…,xax_1, \ldots, x_a, it is possible to define expression x₁->…->xₐ that denotes a relation with a single tuple with those variables. Formula x₁->…->xₐ in R can then be used to check that this tuple belongs to a relation R with arity aa, something that in the standard mathematical notation of first-order logic is written as R(x₁,…,xₐ)(x_₁,\ldots,x_ₐ). Recall that, besides equality checks between variables, such membership checks are the only atomic formulas in first-order logic. Although Alloy also allows all the above ones, they all can be written using just these basic checks, so technically they do not add expressive power to first-order logic, but just a more succinct way to write formulas. The following table provides such formal definitions, assuming R and S have arity aa.





	Atomic formula

	Formal meaning




	R in S

	all x₁,…,xₐ : univ | x₁->…->xₐ in R implies x₁->…->xₐ in S




	R = S

	R in S and S in R




	some R

	some x₁,…,xₐ : univ | x₁->…->xₐ in R




	lone R

	all x₁,…,xₐ,y₁,…,yₐ : univ | x₁->…->xₐ in R and y₁->…->yₐ in R implies x₁=y₁ and … and xₐ=yₐ




	one R

	some R and lone R




	no R

	not (some R)








As we can see, the reduction in formula size can be substantial. For example, to formalize the requirement that “every file is an object”, in plain first-order logic we would have to write ∀x⋅\forall x \cdot File(x)→(x) \rightarrow Object(x)(x) or, in Alloy’s notation, all x : univ | x in File implies x in Object. However, with Alloy’s relational logic we can just write File in Object.

It is important to always recall that in denotes the subset operator and not the membership test. Of course, if we are certain that the expression on the left-hand side is a singleton (a set with a single tuple), in behaves like membership. For example, to test that Root is a Dir we can write Root in Dir. However, if the expression on the left-hand side does not necessarily denote a singleton, this check may not work as expected. For example, if Root was declared with multiplicity lone instead of one, the check Root in Dir will also be true if Root is empty. In this case, to be certain to test for membership you also need to check that the left-hand expression is non-empty, as follows.




some Root and Root in Dir

Further reading

Working with integers

Read about integers in Alloy, namely learn which arithmetic operators are available.

Working with integers



Relational operators

Likewise the alternative atomic checks, most of the relational operators in Alloy do not technically add expressive power to first-order logic, but just a more succinct alternative to write formulas. The full list of operators is presented below.





	Operator

	Name




	+

	Union




	&

	Intersection




	-

	Difference




	.

	Composition, Dot join




	[]

	Box join




	->

	(Cartesian) Product




	<:

	Domain restriction




	:>

	Range restriction




	++

	Override




	~

	Transpose, Converse




	^

	Transitive closure




	*

	Reflexive transitive closure








These operators act like combinators, that can be used to put together relations (predicates) to obtain expressions denoting more complex relations. The most basic operators are the standard set operators of union, intersection, and difference. For example, given predicates File and Dir we can compose them with union to obtain the derived predicate File + Dir that can be used to directly check if an element is either a file or a directory. This simplifies the writing of requirements such as (the redundant) “every object is either a file or a directory”. In plain first-order logic we would write (using Alloy’s syntax):




all x : Object | x in File or x in Dir






By using the union operator we can simplify this to:




all x : Object | x in File + Dir






And finally by using the subset operator we can write just:




Object in File + Dir






Below we present the formal semantics of all relational operators in terms of plain first-order logic. The formula in the right column formally specifies when a tuple belongs to an expression that uses each operator. To abbreviate, in this formula all variables are implicitly universally quantified over the universe. Notice that some of these operators (namely the transpose and the closure operators) are only defined for binary relations.





	Operator

	Formal meaning




	+

	x₁->…->xₐ in R + S iff x₁->…->xₐ in R or x₁->…->xₐ in S




	&

	x₁->…->xₐ in R & S iff x₁->…->xₐ in R and x₁->…->xₐ in S




	-

	x₁->…->xₐ in R - S iff x₁->…->xₐ in R and x₁->…->xₐ !in S




	.

	x₁->…->xₐ₋₁->y₂->…->yₑ in R.S iff x₁->…->xₐ in R and y₁->…->yₑ in S and xₐ = y₁




	[]

	x₁->…->xₐ in R[S] iff x₁->…->xₐ in S.R




	->

	x₁->…->xₐ->y₁->…->yₑ in R->S iff x₁->…->xₐ in R and y₁->…->yₑ in S




	<:

	x₁->…->xₐ in A <: R iff x₁ in A and x₁->…->xₐ in R




	:>

	x₁->…->xₐ in R :> A iff x₁->…->xₐ in R and xₐ in A




	++

	x₁->…->xₐ in R ++ S iff x₁->…->xₐ in S or (x₁->…->xₐ in R and x₁->y₂->…->yₐ !in S)




	~

	x₁->x₂ in ~R iff x₂->x₁ in R




	^

	x₁->x₂ in ^R iff x₁->x₂ in R + R.R + R.R.R + …




	*

	x₁->x₂ in *R iff x₁->x₂ in ^R + iden








Below we illustrate each operator with examples based on the file system specification presented above.


Composition


	The entries inside the root




Root.entries

= {(Root)}.{(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}

= {(Entry0),(Entry1),(Entry2)}







	The names of the entries inside the root




Root.entries.name

= {(Entry0),(Entry1),(Entry2)}.name

= {(Entry0),(Entry1),(Entry2)}.{(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}

= {(Name0),(Name2),(Name1)}







	The binary relation between directories and the contained objects




entries.object

= {(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}.{(Entry0,File),(Entry1,File),(Entry2,Dir0),(Entry3,Dir1)}

= {(Root,File),(Root,Dir0),(Dir0,Dir1)}







	Non-empty directories




entries.Entry

= {(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}.{(Entry0),(Entry1),(Entry2),(Entry3)}

= {(Root),(Dir0)}











Set operators


	All directories except the root




Dir - Root

= {(Root),(Dir0),(Dir1)} - {(Root)}

= {(Dir0),(Dir1)}







	The directories inside the root




Root.entries.object & Dir

= Root.{(Root,File),(Root,Dir0),(Dir0,Dir1)} & Dir

= {(File),(Dir0)} & {(Root),(Dir0),(Dir1)}

= {(Dir0)}











Cartesian product


	All possible associations between files and names




File->Name

= {(File)} -> {(Name0),(Name1),(Name3)}

= {(File,Name0),(File,Name1),(File,Name3)}











Domain and range restriction


	The identity relation on objects




Object <: iden

= {(Root),(Dir0),(Dir1),(File)} <: {(Root,Root),(Dir0,Dir0),(Dir1,Dir1),(File,File),(Entry0,Entry0),(Entry1,Entry1),(Entry2,Entry2),(Entry3,Entry3),(Name0,Name0),(Name1,Name1),(Name2,Name2)}

= {(Root,Root),(Dir0,Dir0),(Dir1,Dir1),(File,File)}











Override


	A modified entries relation where all files are removed from the root directory




entries ++ (Root -> (Root.entries & object.Dir))

= entries ++ (Root -> ({(Root)}.{(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)} & object.Dir))

= entries ++ (Root -> ({(Entry0),(Entry1),(Entry2)} & object.Dir))

= entries ++ (Root -> ({(Entry0),(Entry1),(Entry2)} & {(Entry0,File),(Entry1,File),(Entry2,Dir0),(Entry3,Dir1)}.{(Root),(Dir0),(Dir1)}))

= entries ++ (Root -> ({(Entry0),(Entry1),(Entry2)} & {(Entry2),(Entry3)}))

= entries ++ (Root -> {(Entry2)})

= entries ++ ({(Root)} -> {(Entry2)})

= entries ++ ({(Root,Entry2)})

= {(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)} ++ ({(Root,Entry2)})

= {(Root,Entry2),(Dir0,Entry3)}











Transpose


	The binary relation between objects (contained in directories) and their name




~object.name

= ~{(Entry0,File),(Entry1,File),(Entry2,Dir0),(Entry3,Dir1)}.{(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}

= {(File,Entry0),(File,Entry1),(Dir0,Entry2),(Dir1,Entry3)}.{(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}

= {(File,Name0),(File,Name2),(Dir0,Name1),(Dir1,Name1)}







	The binary relation between entries in the same directory




~entries.entries

= ~{(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}.{(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}

= {(Entry0,Root),(Entry1,Root),(Entry2,Root),(Entry3,Dir0)}.{(Root,Entry0),(Root,Entry1),(Root,Entry2),(Dir0,Entry3)}

= {(Entry0,Entry0),(Entry0,Entry1),(Entry0,Entry2),(Entry1,Entry0),(Entry1,Entry1),(Entry1,Entry2),(Entry2,Entry0),(Entry2,Entry1),(Entry2,Entry2),(Entry3,Entry3)}







	The binary relation between entries sharing names




name.~name

= {(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}.~{(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}

= {(Entry0,Name0),(Entry1,Name2),(Entry2,Name1),(Entry3,Name1)}.{(Name0,Entry0),(Name2,Entry1),(Name1,Entry2),(Name1,Entry3)}

= {(Entry0,Entry0),(Entry1,Entry1),(Entry2,Entry2),(Entry2,Entry3),(Entry3,Entry2),(Entry3,Entry3)}











Closures


	The binary relation between a directory and the objects contained in that directory or any sub-directory




^(entries.object)

= ^{(Root,File),(Root,Dir0),(Dir0,Dir1)}

= {(Root,File),(Root,Dir0),(Root,Dir1),(Dir0,Dir1)}







	All objects in the file system




Root.*(entries.object)

= Root.(^(entries.object) + iden)

= Root.({(Root,File),(Root,Dir0),(Root,Dir1),(Dir0,Dir1)} + iden)

= {(Root)}.{(Root,File),(Root,Dir0),(Root,Dir1),(Dir0,Dir1),(Root,Root),(Dir0,Dir0),(Dir1,Dir1),(File,File),(Entry0,Entry0),(Entry1,Entry1),(Entry2,Entry2),(Entry3,Entry3),(Name0,Name0),(Name1,Name1),(Name2,Name2)}

= {(Root),(Dir0),(Dir1),(File)}











Set comprehension


	The binary relation between directories and the contained objects




{ d : Dir, o : Object | some d.entries & object.o }

= {(Root,File),(Root,Dir0),(Dir0,Dir1)}









Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/structural-topics/relational-logic/the-pre-defined-relations

Further reading

Higher-arity relations

Most of these operators can also be applied to higher-arity relations. Learn how to use these in Alloy models.

The predefined relations

There are three predefined relations in Alloy:


	none, that denotes the empty set.


	univ, the set of all atoms in all signatures.


	iden, the binary relation that associates each atom in univ to itself.




It is important to know that iden relates every element of univ to itself. This means that, for example, to check that a binary relation R (defined on a signature A) is reflexive it is not correct to write iden in R, as iden will not only contain elements in A but also elements in other declared top-level signatures. To obtain the identity relation on signature A we could, for example, intersect it with the binary relation containing all pairs of elements drawn from A, computed with the Cartesian product operator ->, as follows: iden & (A->A). We could also use the domain restriction operator for the same effect: A <: iden filters relation iden to obtain only the pairs whose first element belongs to A. Dually, we could have restricted the range: iden :> A filters relation iden to obtain only the pairs whose last element belongs to A. Thus, to check that the relation R is reflexive we could write, for example, (A <: iden) in R.

Another thing to recall is that none denotes the empty set and is a unary relation. So, if we write R = none, to check if R is empty, we will get a type error since the relations have different arities (none is unary and R is binary). The empty binary relation is denoted by the Cartesian product none->none: this expression denotes the empty set like none, but for the type system it is a binary relation, so writing R = (none->none) does not raise a type error. Of course, a simpler way to check that R is empty is to write no R, since the cardinality check keywords like no can be used with relational expressions of arbitrary arity.

Alloy vs. classical logic nomenclature

Although Alloy is a formal language based on first-order logic, there are some nuances in the nomenclature that differ from that of traditional logic.

When reasoning about semantics in logic, an instance (or interpretation) of a formula is usually known as a model: a model of a formula defines a domain (or universe) of discourse and a valuation of its non-logical symbols that makes the formula true. In contrast, in Alloy the term model is frequently used to denote the specification of a system, and the term instance is used to denote a satisfying universe and valuation. In particular, the Analyzer processes models (and the commands defined within) and generates instances (when the problem is satisfiable). This use of the term model in Alloy parlance is consistent with other techniques and languages for software design, namely the Unified Modeling Language, where a software model is precisely the kind of artefact we have been denoting by a specification.

Another concept that has a different meaning in the Alloy language than in classical logic is that of predicate and function. In first-order logic (also known as predicate logic), predicates and functions are non-logical symbols of arbitrary arity for which an interpretation must be provided when evaluating a formula. Their counter-part in Alloy are the free relations of a model that arise from the signature and field declarations. In contrast, predicates (pred) and functions (fun) in Alloy models are merely re-usable parametrisable formulas and expressions, respectively, and do not introduce any new free variables.

Model finding

The Alloy Analyzer relies on a procedure called model finding to execute the analysis commands. This procedure, in turn, relies on off-the-shelf solvers for Boolean satisfiability problems (SAT). This topic provides an overview of this process, pointing out to other references for more detailed presentations.


Relational model finding

The Analyzer relies on an intermediate tool to perform relational model finding named Kodkod [FSE04]. Kodkod is also based on first-order relational logic, but is stripped of all the structure and syntactic sugar supported by the Alloy language: a Kodkod problem is simply a set of relations bounded by tuple sets and a single formula that will be tested for satifiability. Relations have both a lower-bound declaring which tuples it must contain, and an upper-bound declaring which tuples it may contain. These bounds allow the user to express some partial-knowledge about the possible solutions to the problem. If a Kodkod problem is satisfiable, an instance is returned that assigns a tuple set to each declared relation, ensuring each tuple set is within the specified bounds. The problem’s relations are derived from the signatures and fields declared in the Alloy model, and their bounds from the scope of the command under analysis. The problem’s formula contains the model facts and constraints defined in the command, as well as additional restrictions to encode the signature hierarchy and multiplicity constraints. For check commands, the expected property is negated so that Kodkod will search for counter-examples, i.e., instances that obey all the model’s constraints but break the expected property. Kodkod is also responsible for performing Skolemization (see below), and detecting and enforcing symmetry breaking.

Let us get back to our file system example from the Structural modeling chapter, and consider the following simple command with a small scope, asking for instances where all entries point to directories.




run all_entries_dir {

  Entry.object in Dir

} for 2






Given this scope, a universe with 6 atoms is created, with 2 atoms for each top-level signature. Then the following relations, and the respective lower- and upper-bounds, are declared in the Kodkod problem .




Root = {(Root0)} {(Root0)}

Dir$ = {} {(Object0)}

File = {} {(Object0)}

Entry = {} {(Entry0),(Entry1)}

Name = {} {(Name0),(Name1)}



entries = {} {(Root0,Entry0),(Root0,Entry1),(Object0,Entry0),(Object0,Entry1)}

object = {} {(Entry0,Root0),(Entry1,Root0),(Entry0,Object0),(Entry1,Object0)}

name = {} {(Entry0,Name0),(Entry1,Name1),(Entry0,Name1),(Entry0,Name1)}






Note that there isn’t a relation created for signatures that are extended by others. Instead, whenever called, they are replaced by the union of all its children signatures. If the signature is not abstract, then a new relation is declared to encode the atoms that do not belong to any of its children (we denote this set with a $ suffix). For instance, any call to Dir in an expression is replaced by Root + Dir$ in Kodkod, and calls to Object by File + Root + Dir$ (since Object is abstract, there are no objects that are not files or directories). Note also that, since Root has multiplicity one, its lower-bound is the same as its upper-bound, making its bounds exact; all other relations in this model have an empty lower-bound.

Then, besides the constraints imposed by the model’s facts and the run command, a few other constraints are introduced from the signature declarations. The first, shown below, forces the set of directories and files to be disjoint.




no (Root + Dir$) & File






The others enforce the type and multiplicity of the binary relations. Below are the constraints corresponding to the object relation. The first constraint enforces the multiplicity one for all entries and the appropriate range type, Object. The second constraint enforces the type of the domain, Entry. These constraints may seem a bit spurious when looking at the upper-bound of object, since it only contains pairs relating entries and objects. However, recall that at this point it is still unknown which atoms will effectively exist in the instance. For instance, Entry can even be empty, and object must be restricted accordingly during solving.




all e : Entry | one e.object and e.object in Root + Dir$ + File

object.univ in Entry






You can actually inspect the generated Kodkod problem by setting menu option Options ‣ Record the Kodkod input/output to Yes. When turned on, words Assertion or Predicate in the Analyzer log, for check and run commands respectively, will open a pop-window with this information. Below is how it looks for the command above.

[image: ../../../../_images/log14.png] 

You can inspect the full formula that was extracted from an Alloy model after all the structure was flattened (it will probably be a bit more verbose than the simplified snippets shown above). You’ll also find the corresponding Java code that allows the generation of that problem, since Kodkod does not support a concrete syntax for defining problems.

From relational logic to SAT

Kodkod relies on off-the-shelf SAT solvers to solve model finding problems. SAT solvers process only propositional formulas in conjunctive normal form (CNF), and generating these from complex Kodkod problems is not trivial [FSE04]. Roughly, if the universe has u atoms, each n-ary relation is seen as an n-dimensional Boolean matrix with size u, where each entry in the matrix denotes whether an n-ary tuple belongs to the relation. Using the bounds declared for the relation, some of these entries will be necessarily true, and some necessarily false; for those whose value is not pre-defined in the bounds, Boolean variables are created whose value will be determined by the solver. Then, relational operations are converted into corresponding matrix operators. For instance, the union + is encoded as entrywise matrix disjunction, while composition . is encoded as matrix multiplication. Atomic formulas are converted accordingly. For instance, inclusion in is encoded as the conjunction of entrywise implications. Finally, first-order operators are translated into propositional logic, which is possible because at this point the finite universe of atoms is known. So universal quantifications all are flattened into conjunctions and existential some into disjunctions.

Let us get back to our example. It has 6 atoms, so unary relations are represented by 6 x 1 matrices (a vector). Below are the matrices corresponding to the unary relations. Notice how tuples that necessarily belong to a relation due to its lower-bound are set to true (here only Root), and those outside the upper-bound are set to false. Those between the lower- and upper-bound are assigned a new Boolean variable.





	Root

	
	
	Dir$

	
	
	File

	
	
	Entry

	
	
	Name

	



	Root0

	⊤\top

	
	Root0

	⊥\bot

	
	Root0

	⊥\bot

	
	Root0

	⊥\bot

	
	Root0

	⊥\bot




	Object0

	⊥\bot

	
	Object0

	v1v_1

	
	Object0

	v2v_2

	
	Object0

	⊥\bot

	
	Object0

	⊥\bot




	Entry0

	⊥\bot

	
	Entry0

	⊥\bot

	
	Entry0

	⊥\bot

	
	Entry0

	v3v_3

	
	Entry0

	⊥\bot




	Entry1

	⊥\bot

	
	Entry1

	⊥\bot

	
	Entry1

	⊥\bot

	
	Entry1

	v4v_4

	
	Entry1

	⊥\bot




	Name0

	⊥\bot

	
	Name0

	⊥\bot

	
	Name0

	⊥\bot

	
	Name0

	⊥\bot

	
	Name0

	v5v_5




	Name1

	⊥\bot

	
	Name1

	⊥\bot

	
	Name1

	⊥\bot

	
	Name1

	⊥\bot

	
	Name1

	v6v_6








Getting back to command all_entries_dir, relation Root + Dir$ (i.e., relation Dir) is calculated by the entrywise disjunction of the corresponding matrices, resulting in the matrix below.





	Root + Dir$

	



	Root0

	⊤\top




	Object0

	v1v_1




	Entry0

	⊥\bot




	Entry1

	⊥\bot




	Name0

	⊥\bot




	Name1

	⊥\bot








The binary relations are represented by 6 x 6 matrices. Below is the matrix for object (matrices for entries and name are omitted but look similar).





	object

	Root0

	Object0

	Entry0

	Entry1

	Name0

	Name1




	Root0

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot




	Object0

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot




	Entry0

	v7v_{7}

	v8v_{8}

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot




	Entry1

	v9v_{9}

	v10v_{10}

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot




	Name0

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot




	Name1

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot

	⊥\bot








Continuing with command all_entries_dir, we must calculate composition Entry.object, which is encoded as matrix multiplication. The result is the following vector. Intuitively, this states that, for instance, atom Object0 is present in Entry.object if Entry0 exists in Entry (v3v_3) and object relates those two atoms (v9v_9), or Entry1 exists in Entry (v4v_4) and is related with Object0 through object (v10v_{10}).





	Entry.object

	



	Root

	(v3∧v7)∨(v4∧v8)(v_3 \wedge v_7) \vee (v_4 \wedge v_8)




	Object

	(v3∧v9)∨(v4∧v10)(v_3 \wedge v_9) \vee (v_4 \wedge v_{10})




	Entry0

	⊥\bot




	Entry1

	⊥\bot




	Name0

	⊥\bot




	Name1

	⊥\bot








Now, it only remains to encode the inclusion Entry.object in Dir through entrywise implication of the two corresponding matrices. The result is the following propositional formula.



(((v3∧v7)∨(v4∧v8))→⊤)∧(((v3∧v9)∨(v4∧v10))→v1)≡((v3∧v9)∨(v4∧v10))→v1\begin{split}&(((v_3 \wedge v_7) \vee (v_4 \wedge v_8)) \rightarrow \top) \wedge (((v_3 \wedge v_9) \vee (v_4 \wedge v_{10})) \rightarrow v_1) \\
&\equiv \\
&((v_3 \wedge v_9) \vee (v_4 \wedge v_{10})) \rightarrow v_1\end{split}




This reads as: if atom Object0 belongs to Entry.object, then it must belong to Dir$ (v1v_1). The first conjunct was trivially true since it related to Root0, which is necessarily in Dir through Root. Although we avoided it for simplicity, in practice, the resulting formula will be in CNF.

When the Analyzer reports the result of a command, you can actually get a bit of an insight of the complexity of the SAT problem deployed underneath. The primary vars reported are precisely those that correspond to tuples of the problem’s relations. The execution of command all_entries_dir shown above reported 18 primary variables (the 10 shown above plus another 8 for the omitted entries and name relations). The vars and clauses result from the translation of the problem’s formula into CNF.

Since this procedure generates SAT problems, we can then use many different solvers to check satisfiability, and the Analyzer comes packaged with many state-of-the-art SAT solvers. The SAT solver used by Kodkod can be set through the menu option Options ‣ Solver of the Analyzer. By default, this solver is set to SAT4J, a Java SAT solver that is guaranteed to run in every operating system that the Analyzer also runs. While it’s impossible to predict which SAT solver will perform best for each particular model, SAT4J is rarely the fastest, and the user can explore other solvers that come pre-packaged with the Analyzer depending on the operating system, such as Glucose or MiniSAT. Note that instance iteration requires the usage of an incremental SAT solver to be feasible. So if you select a SAT solver that is not incremental (such as Lingeling), you’ll get an error message when trying to iterate instances in the visualizer. Note also that the order on which the instances are generated my change depending on the selected solver (although eventually they will all generate the same set of instances).

Skolemization

Before deploying the solver, Kodkod performs a process called Skolemization whenever outermost existential quantifications occur in run commands (or universal quantifications for check commands). Instead of flattening the existential quantifier to a disjunction, skolemization transforms the problem to an equisatisfiable one, by creating a new free singleton set (a unary relation) for the existentially quantified variable, and then removing the quantifier and leaving just the quantified formula. The solver will then try to search for a value for the new free variable that satisfies the formula. This largely improves the efficiency of the analysis procedures, and as a side-effect such singleton sets are now also part of the generated instance. Moreover, Skolemization allows the analysis of some commands with higher-order quantifications, which is forbidden in Alloy in general. In particular an existential quantified higher-order variable in a run command will be Skolomized to a new relation with the appropriate arity. Such Skolemized variables can be treated as any other relation in the theme customization. You can control how deep the Analyzer will search for quantifications to Skolemize through menu option Options ‣ Skolem depth, but you cannot actually turn it off altogether.

Let us consider an example, for our file system model. For instance, the following command asks for instances where some entry points to a directory.




run some_entries_dir {

  some d : Dir | d in Entry.object

} for 2






The resulting instance is the following, where variable d was Skolemized and is treated as a regular subset of Dir. Its name is prefixed with the command name, and with a $ to distinguish it from the model’s relations. So it appears in the visualization, can be customized in the theme, or called in the evaluator. Here, we just set its border to be Bold. If you look at the log, you’ll notice that the Analyzer now reported 20 primary variables rather than the expected 18: that’s because d was encoded as a relation of the Kodkod problem.

[image: Get the code to generate this instance.]

As an example of a higher-order quantification, let’s suppose we wanted to check the obviously false property that all subsets of entries in a file system have the same name. The check command to do so is the following.




check all_entries_same_name {

  all s : set Entry | lone s.name

}






When translated to Kodkod the formula in this command will be negated and originate an existential higher-order quantification that searches for any subset of entries with at least two different names, which would be a counter-example to this property. The Skolomized variable will be part of the counter-example instance, as can be seen in the instance below, where $all_entries_same_name_s contains entries with two different names.

[image: Get the code to generate this instance.]

It is worth noting that Skolomization of higher-order quantifications does not add any expressiveness to the language: you could achieve the same result by introducing a new subset signature of Entry and enforcing the same constraints over it (although this would pollute the model, while the higher-order quantification is local to the assertion). If an higher-order quantification cannot be solved by Skolemized an error is thrown by the Analyzer.

Encoding test instances

As models evolve, we should always check whether instances that were expected to hold are still valid. Using the enumeration operation New provided by the Analyzer is not feasible for this kind of regression tests that should be executed automatically every time the model changes. This chapter explores how we can write run commands that search for specific instances and that can thus act as unit tests for our models.


Regression tests for models

We’ve already seen that run commands are very useful to encode and explore interesting classes of instances. During validation we often want these commands to be loosely defined in order to allow for unexpected instances that may exhibit issues of the model. However, we can also write commands that are very restrictive and generate a specific instance. These are not as relevant for validation, but allow the encoding of a kind of unit tests, which we call a test instance. When the model suffers any change, we can just hit menu option Execute ‣ Execute All and see if expected test instances are still valid.

Alloy does not have any particular support to specify concrete instances, so they have to be defined using regular relational logic formulas. If we follow a well-defined idiom, test instances can be easily encoded as formulas. Let’s get back to the file system example from chapter Structural modeling, and try to encode a very simple test instance where the root contains one directory and one file, and the directory another file, all with different names. This should obviously be a valid instance in our model.

The first issue we face when encoding an instance is the inability to refer to concrete atoms in Alloy specifications. At first sight, we could feel tempted to declare several multiplicity one signatures to denote distinguished atoms in the instance being encoded. However, this approach has a major disadvantage: such signatures will now exist in all instances of the model, regardless of the executed command. For instance, if we defined a singleton files F1 and F2 for this test instance, then the model will no longer have instances without any file. Moreover, it would break the symmetry between F1, F2 and the other File atoms, as the former would now belong to a distinct signature, so isomorphic instances would be returned. Unless we are dealing with concepts that exist in the domain model (such as the Root), we should not clutter our specifications with additional singleton signatures.

The some/disj pattern

The alternative is to use an idiom based on some/disj patterns, which will allow instances to be encoded as a formula that is local to each command. This pattern works as follows:


	create an existential disjoint quantification for the expected atoms for each signature;


	restrict the value of all signatures to the union of the respective quantified variables;


	restrict the value of all fields to the union of tuples created from the quantified variables;


	define a scope that is sufficient to represent the instance.




For the test instance described above, this would amount to the following command.




run test_root_file_dir {

  some disj d0, d1 : Dir, disj f0, f1 : File, disj e0, e1, e2 : Entry, disj n0, n1, n2 : Name {

    Root = d0

    Dir = d0 + d1

    File = f0 + f1

    Entry = e0 + e1 + e2

    Name = n0 + n1 + n2

    entries = d0->e0 + d0->e1 + d1->e2

    name = e0->n0 + e1->n1 + e2->n2

    object = e0->d1 + e1->f0 + e2->f1

  }

} for 4 Object, 3 Entry, 3 Name






If we now execute this command, we get the instance below. The command fully specifies this instance: if you ask for a different instance with New, you’ll get a message saying there are no more satisfying instances. We could perhaps imagine other instances that encode the same instance by just permuting the atoms, for instance assigning Name1 to File0 and Name0 to File1. However, as we’ve seen, atoms are uninterpreted and the Analyzer’s symmetry breaking algorithm considers this instance to be isomorphic to the one above.

[image: Get the code to generate this instance.]

Forcing the signatures to be exactly the union of the quantified variables guarantees that there are no other atoms in the universe besides the ones quantified. Scope 4 on Object is needed to encode all needed objects (recall the default overall scope is 3). The disj keyword is needed in order to avoid the assignment of the same atom to different variables. For instance, without disj the same file atom could be assigned to variables f0 and f1 or the same entry atom to e0 and e1. For instance, the instance below would also be generated, which although valid in our file system model, is not the test instance we were trying to encode.

[image: Get the code to generate this instance.]

Note that a disj keyword must be applied to each group of quantified variables, and not just at the beginning of the quantification. Always make sure that there are enough atoms in the scope to represent the instance, otherwise the command will be trivially inconsistent.

This idiom is the one used throughout the book to encode the presented example instances.

Skolemization and visualization

When an Alloy run command has outermost existential quantifications, the Analyzer performs a process called Skolemization that solves those variables by creating additional free relations that must also be solved. This improves the efficiency of the analysis procedures, and as a side-effect such relations are now also part of the instance as singleton sets, and appear in the visualization. Such Skolemized variables appear prefixed by a $ and the name of the command, as could be seen in the instances above. Such relations can be treated as any other element of the instance, including being called in the evaluator, or have their visualization customized in the theme. In particular, we can just hide this label by unchecking Show as labels for those subsets. Alternatively, you can check the option Hide skolem sigs/relations within general graph settings, which will hide all such atoms. Note however that this will also hide derived functions from the visualization, which are treated as Skolemized variables. The result is the the following, cleaner visualization. Note that you cannot simply uncheck Show for those subsets: that would actually remove the atoms in the subset from the subset, not only hide the label. If you find it important to know which atom corresponds to each variable, you can still show a shorter and more readable label by changing the label of those sets in the theme.

[image: Get the code to generate this instance.]

Negative test instances

Besides encoding tests that are expected to be instances of our model, we should also make sure that invalid instances are in fact not allowed by our model. In Alloy, these will take the shape of run commands that are not satisfiable, that are not able to generate an instance. We can use exactly the same strategy as above, but imposing instead invalid constraints.

Let us try to generate an instance similar to the previous one, but where the same name is assigned to the file and the directory contained in the root. The following is similar to the command test_root_file_dir_same_name but without name n1.




run test_root_file_dir_bad_name {

  some disj d0, d1 : Dir, disj f0, f1 : File, disj e0, e1, e2 : Entry, disj n0, n2 : Name {

    Root = d0

    Dir = d0 + d1

    File = f0 + f1

    Entry = e0 + e1 + e2

    Name = n0 + n2

    entries = d0->e0 + d0->e1 + d1->e2

    name = e0->n0 + e1->n0 + e2->n2

    object = e0->d1 + e1->f0 + e2->f1

  }

} for 4 Object, 3 Entry, 2 Name






When running this command, the Analyzer will now report that there is no satisfying instance, which is the expected.

If you have many positive and negative test instances, and rely on Execute All, it may become difficult to detect whether each command is supposed to be valid or not. To help manage this, we can annotate the commands the expected outcome, namely stating after the scope definition expect 1 for positive test instances and expect 0 for negative test cases. After running Execute All (assuming that there are no other commands in the model), we would get the following feedback from the Analyzer.

[image: ../../../../_images/log15.png] 

Note only that once you state expect 1, symmetry breaking is turned off for that command, so the argument above that there is a single acceptable instance no longer holds (isomorphic instances will be returned).

Extracting instances from the visualizer

As you might have noticed, writing the constraints that encode a scenario can become quite cumbersome. Luckily, the Analyzer provides a feature that can ease this process. When navigating instances in the visualizer, you can export them to another format through menu option File ‣ Export To. Options include exporting to a DOT file representing the graph view, or to an XML file. But what’s more interesting to the context of this chapter is that they can also be exported as a Predicate (also available through shortcut cmd-p). This will provide the user a formula that exactly encodes the instance being visualized. The formula follows precisely the some/disj pattern defined above, although it will be a bit more cluttered since it will also define the values of some built-in signatures even if they are not relevant for the current model.

So let’s say that when verifying your model a check command, a counter-example was found that was not expected to be an acceptable instance of the model. You’ll fix the model, and then expect that counter-example to no longer be a valid instance. So you can extract the predicate that represents that counter-example and define a negative test command in the Alloy model with it, which will act as a regression test once the model is fixed.

Handling recursion

The transitive closure operator supported by the Alloy language allows the specification of many reachability constraints that otherwise would have to be specified through recursive definitions. Let us get back to the file system model defined in the Structural modeling chapter. Assertion no_partitions required computing all objects indirectly contained in the root, traversing the complete file hierarchy. In a concrete implementation, this would probably be computed with a recursive procedure. In Alloy, we easily collected all objects using the transitive closure on entries.object. While extremely useful, transitive closure cannot be used to specify all constraints that can be specified with recursion. For instance, let us try to compute the (maximum) depth of a file in the file system. We could use the transitive closure of entries.object to retrieve all ancestors of a certain file. However, files can be shared among directories, and the result of the transitive closure would be a flat set of objects without information about their provenance within the file system. Thus, it cannot be used to calculate file depth.


The predefined natural module

To calculate the maximum depth of a file, we will need to calculate the depth of its ancestors, select the maximum depth among them, and increment by 1. Since the depth of the file system is always a positive integer number, we can encode it as a natural number. Alloy provides a predefined library util/natural that provides a codification of natural numbers in plain Alloy, and allows us to refrain from using the built-in type Int. To use this library, we need only to import it at the beginning of the Alloy model, as follows.




open util/natural






This module introduces a signature Natural with two distinguished singleton signatures, Zero and One. You can inspect all functions and predicates provided for Natural by opening util/natural in the menu File ‣ Open Sample Models…. These include functions inc[n : Natural] and dec[n : Natural] to increment and decrement a natural by 1, respectively, and arithmetic operations such as add[n1, n2 : Natural] and sub[n1, n2 : Natural], for addition and subtraction, respectively. A total order is also imposed over Natural using the predefined Alloy module ordering, which introduces function such as max[ns : set Natural] and min[ns : set Natural], and predicates such as gt[n1, n2 : Natural] and lt[n1, n2 : Natural].

Note that by encoding naturals as a signature, they are bounded by the scope specified for signature Natural. For instance, if you increment a natural beyond those allowed by the scope, it will just yield an empty set (without any kind of error or warning). Luckily, in this example it is easy to identify the maximum natural number needed, since we cannot have a file depth larger than maximum number of Object atoms specified in the scope.

Recursive Alloy functions

Let us try to calculate the depth of the file system with the most obvious strategy: a recursive Alloy function. Although not a particularly simple function, it is possible to define it in Alloy. One possibility is to define it as follows.




fun depth [o : Object] : Natural {

  o in Root implies Zero

  else inc[max[{n : Natural | some x : entries.object.o | n = depth[x]}]

}






Given an object, if it is the root then return 0; else, calculate all naturals that correspond to the depth of the directories that contain that object, select the maximum and increment it by 1. The tricky part here is calculating the set of depths of all the ancestors of an object. We’ve defined it by comprehension by collecting all naturals for which there is a parent directory directory with that depth.

We can now use this function to define a run command that generates a file system with a file at a certain depth. For instance, for depth 2, we could execute the following command.




run depth2 {

  some f : File | depth[f] = inc[One]

} for 5 but 3 Name






The scope of 5 applies to both Object and Natural, so the bound on naturals is enough to encode all possible file depths. However, you’ll actually get the following error from the Analyzer: fun this/depth cannot call itself recursively! The fact is, the Analyzer’s procedures, based on SAT solving, cannot handle recursive definitions. Any recursive call to a function would have to be explicitly unrolled, but it is not possible to know how many unrolls would be needed in each case. Nonetheless, Alloy does support recursive function definitions, but in a very restrictive manner since we have to impose a bound on the number of function unrolls. This feature is disabled by default, and must be turned on the options, and is limited to a maximum of 3 unrolls due to performance issues. So, if we follow the menu option Options ‣ Recursion depth and set it to 2 rather than disabled, and then run the command again, we will finally obtain the following instance.

[image: Get the code to generate this instance.]

Now, let us try instead to find a file system with depth 3 with the following command.




run depth3 {

  some f : File | depth[f] = inc[inc[One]]

} for 5 but 3 Name






Perhaps unsurprisingly, there is no such instance. That is because with a recursion depth of 2, it is not possible for depth to ever calculate value 3 (it actually just returns none in those cases). If we set menu option Options ‣ Recursion depth to 3, we will now get the following instance.

[image: Get the code to generate this instance.]

It’s evident that this approach can easily lead to unpredictable results. The outcome of a command is dependent on an Analyzer option, which in general is a bad practice in Alloy where models are expected to be self-contained. When the maximum recursion depth allowed is exceeded, it just “fails silently” by returning an empty relation. Moreover, the maximum recursion depth allowed by the Analyzer is just 3, so we will never be able to calculate a file depth of 4 with this approach. Luckily, we can use a specification pattern that allows us to circumvent these issues altogether. It is very rare that recursive functions are useful in Alloy, so let’s just keep Options ‣ Recursion depth as disabled.

Recursion through memoization

The alternative approach follows a strategy that resembles memoization: we introduce a new field in the signature that is to be recursively traversed, and store in this field the local result of the recursive call. Then, we declaratively specify the value of this field for all atoms using only the the value for its ancestors. There is, of course, a trade-off: now the recursive result will be computed for all atoms of the signature, and not only for a specific atom when called in a function.

In our example, we start by introducing a field to represent the depth of each object, as follows.




abstract sig Object {

  depth : one Natural

}






Next, we have to restrict the value of this field to the correct depth. This can be done declaratively through the following fact.




fact calculate_depth {

  all o : Object |

    o in Root implies o.depth = Zero

    else o.depth = inc[max[(entries.object.o).depth]]]

}






This fact defines the depth of each object o as follows: if o is the root, it has depth 0; else it collects all the depths of the ancestors of o, selects the maximum, and increments it by 1. Notice that we no longer need a relation by comprehension to collect the depths of the contents, since they are already stored in a field.

The run commands above could be executed exactly as they are due to the dual syntax of dot join and box join. However, let us define them using dot join to make it clear that depth is now a field.




run depth2 {

  some f : File | f.depth = inc[One]

} for 5 but 3 Name






After a few theme customizations (showing depth as an attribute rather than an edge, hiding Natural atoms, and removing the namespace from their labels), we obtain instances such as the following.

[image: Get the code to generate this instance.]

We can now ask for file systems with a depth as big as that supported by the scope on naturals. For instance, the following command still generates instances, namely the example shown below.




run depth4 {

  some f : File | f.depth = inc[inc[inc[One]]]

} for 5 but 3 Name






[image: Get the code to generate this instance.]

Beyond depth 4, with the current scope it is not possible to generate instances, since there are obviously not enough objects. But even if we increase the scope on objects and entries, it will not be possible to generate instances since the natural 5 requires a scope of 6 on Natural (natural 0 is also an atom). So be careful to always update the scope of Natural as needed.

Working with integers

Although using integers in Alloy may seem like a harmless decision, they have some particularities that may lead to unpredictable behaviour. Moreover, due to the nature of the procedures behind the Analyzer, using integers actually may have considerable impact in the performance. Integers should only be used if the specification actually requires arithmetic operations. For instance, identifiers may be encoded as integers in the system implementation for convenience, but will only need to be be tested for equality. Thus, during the system design such an identifier can actually be represented by an uninterpreted atom. If we additionally need to, for instance, compare identifiers, this can be achieved by imposing a total order on the atoms of the signature. Nonetheless, there are of course situations where we actually need to perform arithmetic operations over integers. This chapter shows how this can be achieved in Alloy, and which pitfalls to be aware of.

Further reading

The predefined ordering module

Learn how to impose a total order on a signature and avoid using integers unless absolutely necessary.

The predefined ordering module


Models with integers

Integers are actually always enabled in every Alloy specification. For instance, if you execute any run command with a default scope, and use the Analyzer’s evaluator to check the value of expression Int you will get the following set.





	-1

	-2

	-3

	-4

	-5

	-6

	-7

	-8

	0

	1

	2

	3

	4

	5

	6

	7








Int is the built-in signature containing all integer atoms. You can also see that they always integrate the universe of discourse by evaluating univ. You’ll also notice that these integers are finite and that they are the 4-bit signed integers under Two’s-complement binary representation. Being aware of these three points - integers are atoms, bounded, and interpreted in binary - is essential to use integers in Alloy soundly.

Signature Int can be used as any other signature in the model, except that it cannot be extended (like all built-in signatures). Fields can have type Int, and signatures can be declared as subsets of Int. For instance, let us return to the file system example from chapter Structural modeling and try to extend our model with file sizes. In particular, we want to assign to each object an integer size, and also have a distinguished integer atom representing the maximum capacity of the system. This could be simply achieved as follows.




one sig Capacity in Int {}



abstract sig Object {

  size : one Int

}






After running the empty run command example, we could get an instance such as the following, after some theme customizations (by default, unconnected nodes of Int are set to hidden; we’ve turned this off, set all integer atoms to be hidden, but then only subset Capacity to be shown).

[image: Get the code to generate this instance.]

Further reading

The instance evaluator

In this section we mentioned the evaluator. Learn in more detail how to use it to debug specification.

The instance evaluator



Integer operations

Let us the Analyzer’s evaluator to explore how to manipulate integers. Integer constants can occur in relational expressions (including in the model, unlike other atoms). Start by evaluating, for instance, 1+2. While initially surprising, getting the set of atoms {(1),(2)} was the only sensible solution: as everything Alloy, expressions 1 and 2 are actually singleton sets {(1)} and {(2)}, and + denotes the union of relations. For another sanity check, evaluate 1-1. This evaluates to the empty set {}, and not to the integer 0. Again, this is because - is the relation difference operator. Notice that, since these are valid relational expressions, no errors or warnings are thrown.

To perform arithmetic operations over integers, a special set of operators must be used. The table below presents the native integer operators supported by Alloy.





	Operator

	Description

	Operator

	Description




	fun/add

	Addition

	<<

	Left shift




	fun/sub

	Subtraction

	>>

	Right shift w/ zero extension




	fun/mul

	Multiplication

	>>>

	Right shift w/ sign extension




	fun/div

	Division

	>

	Greater than




	fun/rem

	Remainder

	<

	Less than




	fun/min

	Minimum integer

	>=

	Greater than or equal to




	fun/max

	Maximum integer

	<=, =<

	Less than or equal to




	fun/next

	Order relation

	sum, int

	Set to integer conversion








The negation of the comparison formulas can also be written by placing the negation operator next to the comparison operator (R not < S or R !< S for not (R < S), for example). The expressions that we evaluated above should actually be written as 1 fun/add 2 and 1 fun/sub 1. As expected, the result is again a singleton set that contain a single integer atom. By default, Alloy also imports a util/integer utility module that provides friendlier function and predicate versions of these operators. Some of those are listed below, but you can consult the full module through menu option File ‣ Open Sample Models….











	Function

	Description

	Predicate

	Description




	add[n1, n2 : Int]

plus[n1, n2 : Int]

	Addition

	gt[n1, n2 : Int]

	Greater than




	sub[n1, n2 : Int]

minus[n1, n2 : Int]

	Subtraction

	lt[n1, n2 : Int]

	Less than




	mul[ns : set Int]

	Multiplication

	gte[n1, n2 : Int]

	Greater than or equal to




	min[ns : set Int]

	Minimum of a set

	lte[n1, n2 : Int]

	Less than or equal to




	max[ns : set Int]

	Maximum of a set

	eq[n1, n2 : Int]

	Equal




	max

	Maximum integer

	pos[n : Int]

	Positive




	min

	Minimum integer

	neg[n : Int]

	Negative




	next

	Order relation

	nonpos[n : Int]

	Non-positive




	prev

	Reversed order relation

	nonneg[n : Int]

	Non-nositive








Since everything is a relation, integer operations actually apply to any set of atoms, even if it not singleton integer atom. This is something that is not used often, but since this throws no error, it is important to be aware of their semantics (arithmetic over non-unary relations always throws a type-error). Whenever an integer operation is applied to a set, the latter is implicitly cast into a single integer value, and the resulting integer wrapped back into a singleton set. The implicit conversion of set to an integer is done by applying the sum operator. If the relation is a singleton set, this will just result in the value of its atom, but if there are multiple integer values in the set, they will be summed together. So (1+2).plus[3] is actually (the singleton set) 6, and (1+1).plus[3] is still 4. Also, sum works on sets that contain atoms other than integer: they will just be ignored. If the set contains no integer atom (e.g., 3.plus[Root]), a type-error will effectively be thrown. This also highlights a difference between the relational = and the integer eq: while 1 = 1 + Root is false, 1.eq[1 + Root] is actually true.

Let us get back to the example and try to fix some of the issues evident in the instance above. For instance, we expect file sizes to be positive. This can be easily achieved with the following fact.




fact positive_sizes {

  // All file sizes are positive

  all f : File | gt[f.size, 0]

}






Another constraint that we would like to impose is that sum of the size of all files is less than the established capacity. However, using the operators we’ve seen so far, this is not possible to encode. At first sight, sum File.size could perhaps be used to sum the size of all files. However, if there are multiple files with the same size, that integer atom will only occur once in File.size and thus the sum will yield an incorrect value.

This can be addressed with another important integer operator, the sum quantifier (not to be confused with the sum unary operator). The sum quantifier iterates over a set of atoms and adds up the value of an integer expression over the quantified variable. Back to our example, the size of all files could be written as sum f : File | f.size, iterating over all files and summing their size. The following fact would enforce the desired constraint on capacity.




fact below_capactiy {

  // The sum of the size of all files cannot exceed the capacity

  (sum f : File | f.size) <= Capacity

}






One last, but still very useful integer operator, is the cardinality operator #, which calculates the number of atoms in a relation. For instance for a given directory d, expression #(d.entries) returns the number of entries of d. For instance, the following command will search for instances where the root has 3 objects.




run full_root {

  #(Root.entries) = 3

} for 4






Let us run this command and validate our model with the additional constraints. If you’re not aware of Alloy’s integer semantics, you may be surprised to find the following instance, where the sum of the size of the files clearly exceeds the capacity.

[image: Get the code to generate this instance.]

Dealing with integer overflows

Alloy implements a wrap-around semantics for integers, and given the limited number of available integer atoms, and the exhaustive nature of the Alloy analyses procedures, integer overflows are a common issue that must be addressed. With the default scope on integers they range from -8 to 7, so in the instance above 5.plus[1].plus[6] is effectively -4, which is smaller than the capacity 4 (you can test it in the evaluator).

The number of integer atoms available during analysis is defined by the scope on Int on the command declaration, as for other regular signatures. This scope does not set the number of integer atoms in the universe, but rather the size of their bitwise representation. This scope is 4 by default, which results in the 16 integers from -8 to 7. The scope for Int is always exactly defined as the integers available with the specified bitwidth (unlike the other signatures whose scope determines an upper-bound). Also, changing the overall scope of a command does not change the scope on Int: it must be explicitly set.

Nonetheless, our current model will exhibit overflows regardless of the scope for integers, because there are always instances where the size of the files will overflow. Although this may look cumbersome, overflows are a common issue in real systems, Alloy just happens to illustrate it in a smaller scale. So rather that completely forbid overflows, we should instead guarantee that our system model never reaches a state where such overflows occur. For instance, we can limit the size of objects with the following fact, that takes into consideration the maximum available integer and the number of objects in the universe.




fact size_limits {

  // Guarantee file sizes do not overflow

  all f : File | f.size <= div[max, #File]

}






Behind the curtain, the reason why integers behave like this in Alloy is because the Analyzer relies on SAT solvers for the analyses, which support only Boolean variables. Thus, integers are converted into bit strings during analysis, with a Boolean variable representing each bit, while integer operations are converted to their bitwise counter-parts. A side-effect of this is that large integer bitwidth scopes have a considerable toll on performance.

Alloy has the ability to ignore instances where any overflow occurs. This can be turned on in the menu option Options ‣ Prevent overflows. Any run command will no longer present instances with overflows, and these will also be ignored when running check commands. However, bear in mind that this will completely disregard instances where any overflow occurs, which may give a false sense of security. For instance, the obviously false check command below actually finds no counter-example when overflows are forbidden.




check big_files {

  all f : File | f.size > 10

}






This is because the constant 10 cannot be represented with the default bitwidth scope of 4 and overflows.

Further reading

Visualization customization

Throughout the chapter we’ve customized the visualization of instances. Learn in more detail how this can ease instance interpretation.

Visualization customization

 





Signature facts

In chapter Structural modeling we’ve seen that additional constraints can be imposed on a model through the definition of facts, which may contain arbitrary formulas. Any constraint over the model can be written in such a fact. However, often the constraints we wish to impose target a particular signature of the model, and for those cases Alloy offers an alternative syntax to encode constraints associated with a signature declaration.




Declaring signature facts

Signature facts are written in an optional bracket block in a signature declaration after the block of field declarations, and can be attached to top-level, extension or subset signatures. The field declaration block is not optional, so to declare a signature fact for a signature without fields you must leave an empty field block {}.

The main aspect to take into consideration when defining signature facts is that the constraints are implicitly quantified over every atom of the target signature, and that every call to a field of that signature is already projected on that quantified variable.

Consider, for instance, fact unique_names over directories, which we reproduce below.




fact unique_names {

  // Different entries in the same directory must have different names

  all d : Dir, n : Name | lone (d.entries & name.n)

}






Since this fact is restricting the content of directories, it would perhaps be preferable to attach it to the Dir declaration. This could be achieved as follows.




sig Dir extends Object {

  entries : set Entry

} {

  // Different entries in the same directory must have different names

  all n : Name | lone (entries & name.n)

}






The constraint inside the signature fact is quantified for all atoms of Dir, and the occurrence of entries is actually a unary relation resulting from its application to that variable. To make its meaning more clear, that constraint is equivalent to the following.




all this : Dir | all n : Name | lone (this.entries & name.n)

Further reading

A relational logic primer

Learn more about the logical operators provided by Alloy’s relational logic.

Understanding signature facts

The variable implicitly quantified is always called this, and you can call it within signature facts if needed. In fact, this is a protected keyword in Alloy due to this. Occasionally, you may also need to refer to the non-projected version of a field to get its value for an atom other than this. The non-projected version of a field can be accessed by prefixing it with @.

To illustrate this, consider the version of fact no_shared_entries shown below (which was actually superseded by the stronger one_directory_per_entry).




fact no_shared_entries {

  // Entries cannot be shared between directories

  all x, y : Dir | x != y implies no (x.entries & y.entries)

}






This constraint is restricting the content of directories by quantifying over two directories. A signature fact will implicitly quantify this over one directory, but the second one must still be explicit, and to get its entries we must use the non-projected @entries. This would result in the following signature fact.




sig Dir extends Object {

  entries : set Entry

} {

  // Different entries in the same directory must have different names

  all n : Name | lone (entries & name.n)

  // Entries cannot be shared between directories

  all y : Dir | this != y implies no (entries & y.@entries)

}






Although signature facts can improve a model’s readability, they are rather limited. In particular, since the signature’s fields are always projected on the left-hand side, facts such as no_shared_dirs or one_directory_per_entry can’t be elegantly encoded as signature facts.

Behavioral modeling

In this second chapter we will explain the basics of behavioral modeling with Alloy. As running example we will explore the design of a simple file sharing web application, where a user can upload files making them available for others to download, provided that they have access to a unique single-use token that was associated with shared files. Moreover, uploaded files can be deleted, but the user can for a while undo this action: deleted files are moved to a trash bin from where they can be restored. Upon explicit user request or after a certain period of time, the trash bin is automatically emptied, making all files in it no longer available.

More specifically, in this chapter we will show how Alloy can be used in the following design tasks:


	Formally specify, at a very abstract level, the structure and behavior of this web app.


	Validate this specification by simulation, namely using the Alloy Analyzer to check that it allows some of the expected behaviors.


	Verify that this specification entails some of the expected properties of our design.







Specifying transition systems

Transition systems are one of the most standard formalisms to reason about the behavior of a software system. A transition system contains the different states a system may be in while evolving over time, identifying which of these are possible initial states, and clearly depicting how the system can evolve by identifying the transitions that connect each state to every possible succeeding state.

The first step when specifying a transition system is to describe the structure of its states. As we have seen in chapter Structural modeling, in Alloy the structure of a system is described using signatures and fields, all represented by mathematical relations. By default, in Alloy the value of all signatures and fields is immutable. To declare a mutable signature or field it is necessary to add the var keyword before the respective declaration.

The state of our file sharing web app will be described using the following mutable structures: the set of files currently uploaded to the app, the set of items currently trashed, and a binary relation that associates shared files with the respective access tokens. We start by declaring two immutable signatures to denote the universe of atoms available throughout the complete trace: File for the set of available files, and Token for the set of available tokens. The, relation shared is declared as a variable field inside the File signature, associating each file with a set of Token at each moment. The set of uploaded files can be declared as a mutable subset of signature File (the set of all possible files), and trashed as a mutable subset of uploaded.




sig Token {}

sig File {

  var shared : set Token

}

var sig uploaded in File {}

var sig trashed in uploaded {}






Having described the state of our system we can now proceed to specify its intended behavior, namely what are the initial states and the possible transitions. Unlike most state-based formal methods, Alloy has no special syntax to declare the initial states or events that originate transitions. Instead it follows the idea, introduced by Leslie Lamport in the Temporal Logic of Actions [TOPLAS94], of specifying a transition system implicitly by means of a temporal logic formula that dictates which are its valid behaviors. In temporal logic we have operators that can be used to specify how mutable structures evolve over time. Temporal logics differ on how they define what exactly is a behavior of a system. Alloy supports a linear time temporal logic, where a behavior of a system is a trace, an infinite sequence of states fully describing a possible path in the respective transition system. The most well-known operators of linear time temporal logic, also supported by Alloy, are always, that forces the enclosed formula to be valid in all future states, and eventually, that forces the enclosed formula to be valid in some future state.

The temporal logic specification of the behavior of our file sharing app should allow the following traces, all examples of valid behaviors in the underlying transition system.

[image: ../../_images/valid.png] 

On the other hand, the specification should not allow the following traces, because they do not represent valid behaviors. The invalid initial states and transitions are identified in red.

[image: ../../_images/invalid.png] 

In the first trace we have an invalid initial state where there exist already uploaded files, and a transition where simultaneously a file is restored and another file is deleted. In the second trace we have two invalid transitions: in the first we have a simultaneous upload and delete, and in the second we have a file that is no longer uploaded without being first put in the trash bin with a deletion. In the third trace we also have two invalid transitions: in the first we have two files that are simultaneously deleted, and in the second a transition where the trash bin is not fully emptied. Some readers might argue that these two transitions are not problematic and could be allowed. In our specification they will be ruled out, but indeed it is perfectly reasonable to conceive a file sharing app where they are possible. One of the goals of the design phase is precisely to explore such alternative behaviors and choose the one that better fits our goals.

The formula specifying a transition system can typically be divided in two parts: one formula that specifies what are the valid initial states, and another that specifies how the system can evolve from those initial states. In the initial state of our app no files are uploaded (and, consequently, no files are trashed) and no files have access tokens assigned. If a formula inside a fact contains no temporal operators, namely if it is a normal relational logic formula, similar to the ones we have specified in the Structural modeling chapter, then the fact is only required to hold in the initial state of every trace. Formulas without temporal operators can thus be used to specify the valid initial states. In our example, the initial states must obey the following fact. Note that init is just the label assigned to the fact, not a special keyword for facts constraining the initial states.




fact init {

  // Initially there are no files uploaded nor shared

  no uploaded

  no shared

}






To specify the valid transitions, it is easier to specify separately each of the possible actions (or events) in our system. Each action will originate different transitions when executed in different states. In the case of the file sharing app we have six actions: upload a file, delete a file, restore a file, empty the trash, share a file with a token, and download the file associated with a token. Each action will be specified in separate (parametrized) predicate that holds in a particular state of a trace iff that action can occur in that state and the next state of the trace is a valid outcome of the action. As we have already seen in the Structural modeling chapter, a predicate is a named formula that is only required to hold when invoked. For example, in our specification we will have a predicate upload with a file parameter, and the call upload[f] will be will be true in a state iff file f is uploaded in that state.

Assuming we have specified our six actions in the respective predicates (addressed in the next section), we can constrain the valid transitions of the system by imposing a fact that requires one of the action predicates to hold at each possible state during the system evolution. To impose a constraint on all the states of a trace, we can use the temporal operator always followed by the desired formula. With this operator we can easily specify the valid transitions of our system with the following temporal logic formula, where all the action predicates are invoked.




fact transitions {

  // The system must only evolve according to the defined actions

  always (

    (some f : File | upload[f] or delete[f] or restore[f]) or

    (some f : File, t : Token | share[f, t]) or

    (some t : Token | download[t]) or

    empty

  )

}






Note the usage of or to allow any possible action predicate to hold in each state and the usage of the existential quantifier some to non-deterministically choose which file and / or token each action acts on. Also note that the parenthesis after the always are required because this is a unary operator with higher precedence than any binary operator. When a predicate has no parameters, the brackets can be omitted when calling it, as is the case of empty.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-modeling/specifying-transition-systems

Further reading

A temporal logic primer

Read about the full syntax and semantics of the temporal logic supported in Alloy.

tocdepth



Specifying actions

As mentioned above actions are typically specified in predicates that relate pairs of consecutive states. An action predicate checks if the action can occur in a state and if the next state is one of its valid outcomes (or outcome if the action is deterministic). These two conditions are usually called the guard and the effect of the action, respectively. To specify the effect we need to somehow evaluate a formula in the next state or refer to the value of sets and relations in the next state. To evaluate a formula in the next state we precede it with the temporal operator after. To evaluate an expression in the next state we append it the prime operator '.

For example, the parameterless empty action predicate can be specified by the conjunction of three formulas as follows.




pred empty {

  no trashed' // effect on trashed

  uploaded' = uploaded - trashed // effect on uploaded

  shared' = shared // no effect on shared

}






The three formulas specify the effect of the action. There is no guard here, meaning that empty can occur in any state. When specifying an action we should consider what is its effect on all mutable sets and fields that comprise the state. If nothing is specified about a particular mutable relation, then there will be no restriction on how that relation can evolve, meaning that it can change freely when the action occurs. If the intention was for that set or relation to remain unchanged when the action occurs, then an explicit formula stating that the value in the next state is the same as the present value must be added. Such “no effect” formulas are usually called frame conditions. In the case of the empty predicate, the first effect formula states that in the next state the trashed set will be empty (which could alternatively be specified by after no trashed), the second effect states that in the next state the currently trashed files will be removed from uploaded, and the last effect is a frame condition stating that shared should remain unchanged.

The upload action predicate can be specified as follows, parametrized by the file to be uploaded. Its guard states that the file cannot already be uploaded, and the effect is to add the file to the uploaded set.




pred upload [f : File] {

  f not in uploaded // guard

  uploaded' = uploaded + f // effect on uploaded

  trashed' = trashed // no effect on trashed

  shared' = shared // no effect on shared

}






Recall that in Alloy every expression denotes a relation, and in particular a variable denotes a singleton set containing a unary tuple with the respective value. So the f in uploaded + f is a set of files, just like uploaded itself, and it is possible to compute the union of both. This may seem rather strange at first, but it is one of the nice details of Alloy, that further contributes to simplify its semantics and syntax. In particular, the set union operator can also be used for adding an element to a set. Another example is the in operator which tests for set inclusion. Again, since f denotes a singleton set, the expression f not in uploaded is checking whether f is currently not a member of uploaded, without the need for a specific membership test operator.

Action predicates delete and restore can be specified as follows.




pred delete [f : File] {

  f in uploaded - trashed // guard

  trashed' = trashed + f // effect on trashed

  shared' = shared - f->Token // effect on shared

  uploaded' = uploaded // no effect on uploaded

}



pred restore [f : File] {

  f in trashed // guard

  trashed' = trashed - f // effect on trashed

  uploaded' = uploaded // no effect on uploaded

  shared' = shared // no effect on shared

}






The guard of delete states that a file can only be deleted if it is uploaded but not already in the trash. The first effect just states that the file is added to the trash bin. The second effect states that all shared tokens associated with the file should be removed. Recall that shared is a binary relation associating files with the respective tokens. Expression f->Token denotes the cartesian product of the singleton set f with Token, the set of all possible tokens, so it denotes the set of all pairs (f,t) where t is any possible Token. By subtracting this set from shared we will “disconnect” file f from any possible token it is associated with. Alternatively, we could be more specific and subtract from shared only the set of tokens that are associated with the file by using expression f->f.shared instead of f->Token. The last effect on delete is a frame condition stating that uploaded does not change. Action predicate restore is simpler to specify, just removing the parameter file from the trash bin.

The share action predicate will assign to a file a fresh token. The guard will require that the token to be associated with a file has never been used before. This is required, because otherwise users could later try to download unauthorized files using a token that was shared with them before. Although action predicates typically compare only the current state with the succeeding state, they can actually refer to other states of the trace using temporal operators. This is particularly useful when the guard of an event depends on the execution history: while in a concrete implementation this will probably require additional structure to log previously used tokens, in Alloy we can just specify such a guard declaratively. So, to specify the fresh token guard of share we will resort to the temporal operator historically, a past temporal operator that can be used to check if a formula was always true in the past (up to, and including the current state).




pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  shared' = shared + f->t // effect on shared

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






The first guard requires that the file is currently not trashed. The second guard uses historically to check that the token t was never contained in File.shared, the set of tokens associated with any file at each past state. The effect of this action is to add a new association between f and t to relation shared. Expression f->t uses the Cartesian product between two singleton sets to define the singleton binary relation containing the pair (f,t). Using the union operator this pair is then added to shared. The remaining formulas are frame conditions stating that share has no effect on uploaded nor on trashed.

Finally, the download action predicate is specified as follows.




pred download [t : Token] {

  some shared.t // guard

  shared' = shared - File->t // effect on shared

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






The token must be associated with some file by the shared relation, and since we want tokens to be single use, they are removed from the shared relation to prevent further downloads.

Stuttering

The specification of our file sharing app is not entirely fine. For example, the following trace will not be considered valid.

[image: ../../_images/stuttering.png] 

Here a file was uploaded and for a while nothing happened until the file was trashed. In the transitions where nothing happened the user could, for example, have been interacting with other apps and, obviously, those interactions have no effect on the state of the file sharing app. The global state of the world still evolved, but the portion of that global state that corresponds to our app, and that is the focus of our specification, did not change.

It is recommended that the specification of a system allows such stuttering transitions. From a philosophical point of view they capture actions that can happen in the world outside our system, but they also have a practical use. First, allowing them enables our specification to be later composed with the specification of other systems executing concurrently: without stuttering all systems would be forced to execute synchronously, which can be overly restrictive. Second, allowing stuttering is a simple way to make sure all behaviors can be extended to infinite traces, a requirement in Alloy and in most model checkers (adopted to simplify the semantics of temporal logic operators): in the worst case scenario, if a deadlock is reached where no action can occur, the system could still stutter forever. For example, if you start to validate the current specification without stuttering (more on this in the next section), you would soon realize that the only valid traces were those where a restore or an empty necessarily occur, so that at some point the execution returns to a previous state. Otherwise, eventually all tokens would be exhausted and all files will be in the trash, and a deadlock would be reached. Without stuttering these executions could not be extended to an infinite trace.

The specification of a stuttering event is a trivial predicate that consists only of frame conditions.




pred stutter {

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

  shared' = shared // no effect on trashed

}






To allow stuttering in our system we need to change the fact that specifies the valid transitions as follows.




fact transitions {

  // The system either evolves according to the defined actions or stutters

  always (

    (some f : File | upload[f] or delete[f] or restore[f]) or

    (some f : File, t : Token | share[f, t]) or

    (some t : Token | download[t]) or

    empty or

    stutter

  )

}

Validating the design

Now that we have a first specification of the intend behavior of the file sharing app, and before proceeding with the verification of expected properties, it is advisable to perform some validation to get some assurance that indeed it behaves as expected. A typical way to perform such validation is by using some sort of user-guided simulation. The Alloy Analyzer has several mechanisms to allow the user to explore and validate a design, including an interactive exploration mode akin so simulation [FIDE19].

Recall that Alloy has two analysis commands: run commands instruct the Analyzer to check the satisfiability of the formula (and its consistency with the declared facts), yielding a satisfying instance if that is the case; check commands instruct the Analyzer to check the validity of a formula (assuming the declared facts to be true), yielding a counter-example instance if that is not the case. In the case of specifications with mutable relations, an instance is a valid execution trace, an infinite sequence of states, each a valuation of the declared signatures and fields. When our models have mutable structures we will use the terms instance and trace indistinguishably.

As we have seen in the previous chapter, the usual way to start validating a specification is to define an empty run command to ask for any instance that satisfies all the declared facts. To kick-start the validation process we will add such an empty command (named example) to our model.




run example {}






After executing this command we can get the following trace.

[image: Get the code to generate this instance.]

When a specification has mutable relations, the instance is visualized in a slightly different way from what we have seen in the Structural modeling chapter. Below the toolbar, the Alloy visualizer now shows a depiction of the trace, which in this case consists of the initial state repeating itself forever, which is a valid behavior because of stuttering. All traces returned by the Alloy Analyzer will have the same shape: a finite sequence of states followed by a loop back to a previous (or the same) state.

In the lower part of the window the visualizer focuses on a particular transition of the trace, depicting the pre- and post-state using the default Alloy theme: the atoms are named sequentially according to the signature they belong to, and atoms belonging to a subset signature (such as uploaded) will be labelled with that signature name. Mutable sets (and relations) are drawn with dashed borders by default, but this can be changed in the theme. In the instance above, there are no such mutable elements, as expected, since fact init is forcing all mutable signatures and fields to be empty in the first state. The two states being depicted are the ones shown in white in the trace depiction, and will be kept centered in that depiction. When the visualizer window pops up the transition being depicted is always the first one, with the state on the left-hand side being the initial state of the trace.

To navigate in the trace, namely to move forwards and backwards to focus on a different transition, just press the → or ← buttons in the toolbar (or cmd-→ for menu option Instance ‣ Show Previous State and cmd-← for menu option Instance ‣ Show Next State), respectively. For example, by moving forward to focus on the second transition we get the following, which obviously is another stuttering step.

[image: Get the code to generate this instance.]

In the toolbar of the Alloy instance visualizer window we can also find four new buttons, that can be used to ask the Analyzer for alternative instances:

New Config



This button, or shortcut cmd-c for menu option Instance ‣ Show New Configuration, asks for a new trace that differs in the values of immutable sets and relations. Usually, immutable elements constitute the configuration of a system (for example, describing a specific network topology where a protocol is to be executed), and by pressing this button we will get an execution trace with a different configuration. In the case of the file sharing app, the only immutable relations are signatures File and Token, so pressing this button should give us a trace with a different number of files or a different number of tokens.





New Trace



This button, or shortcut cmd-t for menu option Instance ‣ Show New Trace, asks for a new (different) execution trace with the same configuration.





New Init



This button, or shortcut cmd-i for menu option Instance ‣ Show New Initial State, asks for a new trace with a different initial value for mutable sets and relations, allowing us to quickly explore a scenario starting with different initial conditions. In our example, for each configuration there is only one possible initial state, so pressing this button will not return any instance.





New Fork



Finally, this button, or shortcut cmd-f for menu option Instance ‣ Show New Fork, asks for a different trace with the same behavior up to the (left-hand) pre-state we are currently focused, but a different transition at this point. If that is possible, the pre-state will remain the same and we will see a different post-state. The latter could be a different result for the same (non-deterministic) event, or the outcome of a different event.





For example, if at this point we press New Config we could get the following trace, where we have two possible tokens but the system still stutters forever.

[image: Get the code to generate this instance.]

If now we press New Trace we may get the following trace.

[image: Get the code to generate this instance.]

In this trace, the first transition is the upload of the only file in the universe, and then the system stutters forever, as can be seen in the trace depiction. Pressing New Trace again could produce the following trace, where the first transition is again a stuttering step.

[image: Get the code to generate this instance.]

To see the second transition, which is the upload of the file, we can press →.

[image: Get the code to generate this instance.]

Before proceeding with the validation of our specification, let’s change our visualization theme, for example by setting different colors for files not currently uploaded (white), uploaded files (yellow), and trashed files (red), and different shapes for files (circles) and tokens (rectangles), with the latter also colored gray. Finally, hide the subset labels and change the color palette. After customizing the theme the above transition will be displayed as follows.

[image: Get the code to generate this instance.]

While New Trace allows some quick validation of the specification, New Fork is the main tool used in this task, since it allows us to quickly narrow our exploration to the behaviors of interest, instead of just pressing New Trace until they eventually show up. For example, let us suppose we wanted to see if the following sequence of actions is possible: upload a file, share it with two different tokens, download it with one token, delete it, and finally empty the trash. To search for this scenario, we first re-execute our command, and press New Config to get the desired configuration with one file and two tokens.

[image: Get the code to generate this instance.]

Pressing New Fork will necessarily change the stuttering step to a file upload, because that is the only other action that can occur at this point.

[image: Get the code to generate this instance.]

Pressing → to move to the second transition, which is a stuttering step, and pressing New Fork may produce the following trace, where the uploaded file is trashed and then the trash emptied, moving the system back to the initial state. Notice in the trace depiction how in this infinite trace the last state loops back to a state other than itself.

[image: Get the code to generate this instance.]

Since this is not the behavior we want to explore, we can press New Fork again to change this transition to a sharing action (the only other possible action).

[image: Get the code to generate this instance.]

Pressing → and New Fork may show us the second share action.

[image: Get the code to generate this instance.]

By repeatedly pressing these buttons we can produce the remaining steps of our desired scenario.

[image: Get the code to generate this instance.] [image: Get the code to generate this instance.] [image: Get the code to generate this instance.]

We can also use New Fork to check that no unexpected behaviors can happen. For example, at this point the only other possible action should be the following restore action.

[image: Get the code to generate this instance.]

We can confirm this by pressing New Fork and see if the “The are no more satisfying instances” error window appears, which is the case here.

[image: ../../_images/nomore.png] 

Verifying expected properties

After validating the design of our file sharing app we proceed with the specification and verification of some properties that are expected to hold. A nice thing about Alloy is that the same logic is used to both specify the system and its expected properties. In many formal specification languages and verification tools (namely, most model checkers), a different language is used for each. In Alloy we use linear temporal logic, of which we already presented some operators, namely the fundamental always and eventually operators, and also the after operator, that requires a formula to be true in the next state (which always exists because traces are infinite). These are examples of operators that constrain the future behavior in a trace, but in Alloy we also have operators that constrain the past behavior. We already saw one example of the latter, namely the historically operator that forces a formula to always be true in the past (including the current state). Alloy has a few more temporal operators. For example, we have once that requires a formula to be true sometime in the past (or in the current state), and before that requires a formula to be true in the previous state (if evaluated in an initial state it will always be false because there is no previous state). All these are unary operators, but Alloy also has a few binary temporal operators. One of the most useful is releases, that enforces the right-hand side formula to only stop being true after the left-hand side formula becomes true.

As we have already seen, formulas that we want to verify with check commands can be written in assertions. The most frequent (and simple) temporal properties we can specify with temporal logic are invariants, formulas requiring some constraint to be true in all states of all possible behaviors. These can be specified with a single always followed by the invariant property. For example, an invariant that should be valid in our app is that all shared files should still be uploaded and not in the trash. This assertion can be specified and checked as follows.




assert shared_are_accessible {

  always shared.Token in uploaded - trashed

}

check shared_are_accessible






As expected, the check yields no counter-example. Another expected property could be that a restore undoes a delete action, something we can specify as follows.




assert restore_undoes_delete {

  all f : File | always (

    delete[f] and after restore[f] implies

    uploaded'' = uploaded and trashed'' = trashed and shared'' = shared

  )

}

check restore_undoes_delete






Here we used the after operator to check that the restore action occurred after the delete, and a double prime to evaluate the value of the mutable fields two states ahead and check that that value is same as before executing the delete. Checking this assertion will actually yield the following counter-example, where a file has an associated token which is removed when the file is deleted and is not recovered by the restore. We’ve hidden in the visualization the $restore_undoes_delete_f subset identifying the relevant file, as it is evidently File2.

[image: Get the code to generate this instance.] [image: Get the code to generate this instance.]

If we really wanted this property to hold we could change our design in two ways: either keep the associations between files and tokens when deleting them or forbid the deletion of shared files. The converse assertion that delete undoes restore does hold in the current specification.

A key property of our app is that tokens are single use. We can check that indeed that is the case, by checking that after downloading a file with a token that token can no longer be used to download another file.




assert one_download_per_token {

  all t : Token | always (

    download[t] implies

    after always not download[t]

  )

}

check one_download_per_token






Notice how here we use two nested always operators to say that whenever a token is used, from then on it will not be used again. The inner always is coupled with an after because it only applies to the states after the download occurs: otherwise we would be forcing download[t] and not download[t] in the same state.

To make the specification of this assertion more readable we can define a function that returns the set of files that were once downloaded with a given token. In Alloy we can use the set comprehension notation to define a set or a relation. As usual, to define a set by comprehension we use a predicate defined over a quantified variable: any atom that satisfies the predicate will be included in the resulting set. The desired function can be defined as follows.




fun downloaded [t : Token] : set File {

  { f : File | once (download[t] and t in f.shared) }

}






Using this function the previous assertion could alternatively be specified as follows.




assert one_download_per_token {

  all t : Token | always lone downloaded[t]

}






To give an example of releases consider the following assertion (also valid in our system), stating that after deleting a file, it can only be deleted again after being restored or re-uploaded.




assert empty_after_restore {

  all f : File | always (

    delete[f] implies

    after ((restore[f] or upload[f]) releases not delete[f])

  )

}

check empty_after_restore






The formula (restore[f] or upload[f]) releases not delete[f] is true in a state iff not delete[f] only stops being true after restore[f] or upload[f], that is, the file can only be deleted again after being restored or re-uploaded. This formula is used inside an always and only required to hold in every state after a deletion of the file is performed. The after used here is important, because without it we would require (restore[f] or upload[f]) releases not delete[f] to hold in the same state when the deletion of f is performed, and that would require not delete[f] to already be true in that state, which would be a contradiction.

All properties we checked so far are examples of safety properties, which are properties that forbid “bad” behaviors from happening. We can also specify and check liveness properties, that force some “good” behaviors to happen. For example, the following assertion states that every file that is deleted and never again restored will eventually disappear.




assert non_restored_files_will_disappear {

  all f : File | always (

    delete[f] and after always not restore[f] implies

    eventually f not in uploaded

  )

}

check non_restored_files_will_disappear






To satisfy this property the system is forced to make progress in a specific situation to produce the expected behavior, namely to eventually perform an empty when a file remains forever in the trash. Of course that will not be the case in our system because when a file is in the trash actions can still be performed in other files, and even if there is only one file that is deleted and never restored the system can still stutter forever. Allowing stuttering is a good practice, but sometimes we may wish to forbid unrealistic behaviors where the system opts to stutter forever, never making progress even if some action is enabled. The constraints that forbid those kinds of unrealistic behaviors are known as fairness restrictions, because they force the environment to somehow be fair to the system allowing it to make progress once in a while. Fairness can be imposed on the whole system or on specific actions, and they are used many times to impose assumptions about the environment without having to specify in detail how it behaves. For example, when specifying concurrent algorithms it is common to impose restrictions that force the system to be fair to all threads, allowing all of them to execute once in a while. This could alternatively be achieved by specifying in detail how the operating system scheduler works, but when the focus is the verification of the concurrent algorithm that detail is unwelcome.

In our file sharing app, we actually expect the system to periodically empty the trash to free up resources. In the real system, this would probably be encoded with some sort of timer, but at this abstract level we just want to forbid behaviors where this action never occurs without having to detail how that process works. So we can impose a fairness restriction on the empty action predicate, requiring it occur recurrently. That could be specified with the following fact.




fact fairness_on_empty {

  always eventually empty

}






With this fact the above assertion non_restored_files_will_disappear becomes valid, because if a deleted file is never restored then at some point action empty will execute, causing the file to be removed from the uploads.

As already discussed in chapter Structural modeling, it is important to stress that the fact that a check command yields no counter-example instances only means that the assertion is most likely valid. Recall that every command has a, sometimes implicit, scope on top-level signatures. For example, the following command (the first in this section) only checks if the invariant assertion is valid for configurations with up to 3 files and up to 3 tokens.




check shared_are_accessible






In Alloy, commands also have a scope on the size of the finite prefix of traces that precedes the mandatory back loop. By default this scope is 10, meaning that the verification engine only checks for counter-example traces with at most 10 different states (and transitions). This is a verification technique known as bounded model checking. The Alloy Analyzer searches for counter-examples of increasing length, and is guaranteed to return the shortest one, if some exists. To change this bound just assign a different value to the special scope steps. For example, to verify the same assertion for systems with up to 4 files and tokens and traces with at most 20 different states the scope could be set as follows.




check shared_are_accessible for 4 but 20 steps






This command also yields no counter-examples. With such a large scope it is thus very likely that our assertion is indeed valid.

In Alloy the analysis is always bounded in respect to the signatures, but we can perform unbounded model checking (or complete model checking) in respect to the size of the traces, essentially verifying properties for traces composed by an arbitrary number of states. To do so we must first choose a solver in the Options menu that supports unbounded model checking. At the moment only the electrod.nuxmv or electrod.nusmv solvers support that feature. The solver is the low-level verification tool that the Analyzer uses in the backend to perform the actual search for instances and counter-examples. These two solvers are well-known model checkers and must be installed separately from the Alloy Analyzer. For bounded model checking, many different solvers can be used, including the two above but also several SAT solvers that came packaged with the Analyzer. Notice that some solvers may be considerably faster than others in particular examples, so it is always worthwhile to try different options if your analysis commands are very slow. To verify our property for systems with up to 4 items and traces of any length the scope would need to be set as follows.




check shared_are_accessible for 4 but 1.. steps

Behavioral modelling advanced topics

This chapter presents some advanced topics relevant for behavioral modelling. These topics build on the file sharing app example model of the Behavioral modeling chapter.

A temporal logic primer

In chapter Structural modeling, we used relational logic to specify constraints about software structures. As we have seen in the Behavioral modeling chapter, the language also supports temporal logic, to enable the specification of behavioral properties. This topic provides more details about the syntax and semantics of Alloy’s temporal logic.




Everything is a trace

What do we mean by “the behaviors of the system”? In Alloy, we view a system as the set of all its execution traces, and every such trace is a feasible infinite sequence of states of the system. Here, “feasible” means that each trace much follow the constraints of the model. The constraints of the model include the Alloy facts and the constraints that are included in the signature declarations, such as the multiplicity constraints. In each state, a relational value is associated with each declared signature and field. If a signature or field is declared as mutable, that its value can change along the trace. Be aware that if a top-level signature is declared as mutable then relations univ and iden will also be mutable, since univ is the union of all top-level sigs, and iden is the identity relation over univ.

Let us consider for instance the following trace of our file sharing web app.

[image: ../../../../_images/trace.png] 

In this scenario, which we will use as an illustrating example in this topic, there are two files and two tokens. A file is depicted in red if it is shared. Tokens are not represented in the picture.

Let us define this scenario in Alloy terms. The set of atoms (the universe) consists of the two files and the two tokens, which are named after their signature name by Alloy: File0, File1, Token0, Token1. Alloy Analyzer produces the following depiction for this scenario. We use here the same visualization theme as in chapter Behavioral modeling: the files are depicted as circles and the tokens as grey rectangles, the files that are not currently uploaded are in white, the uploaded ones are in yellow, the trashed ones are in red. When inspecting a trace, the visualizer starts by focusing on the first two states of a trace (state 0 and state 1).

[image: Get the code to generate this instance.]

All along the trace, the signatures File and Token have a constant value (because they are static signatures), which is the following.




File = {(File0),(File1)}

Token = {(Token0),(Token1)}






Now, if we look at the content of the first two states, we see that


	in the initial state, the signatures uploaded, trashed and the field shared are empty,


	in the second state, uploaded = {(File1)}, and trashed and shared are still empty.




By pressing pressing → a couple of times we can focus on the 3rd and 4th states (state 2 and state 3) of the trace, corresponding to the transition where one file is shared.

[image: Get the code to generate this instance.]

We can see that in state 2 (left-hand side) shared is empty and that uploaded = {(File0),(File1)}, and that in state 3 (right-hand side) shared = {(File1,Token1)}.

In the following, we will use this scenario to illustrate the semantics of temporal connectives.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/temporal-logic/everything-is-a-trace

Further reading

Mutable top-level signatures

We mentioned that top-level signatures can be mutable. Learn about the implications of having them in a model.

Mutable top-level signatures

Further reading

A relational logic primer

Alloy’s temporal specifications are built top of relational logic. Learn more about this static fragment.

Temporal connectives

The constraints of the model are expressed in Alloy’s logic, which combines relational logic and Linear Temporal Logic (LTL) [FOCS77]. The logic that results from this combination is named Relational Linear Temporal Logic (RLTL). The temporal logic connectives supported by Alloy are the following.





	Future-time connectives

	Past-time connectives




	after

	before




	eventually

	once




	always

	historically




	until

	since




	releases

	triggered








The informal meaning of the future-time connectives is the following.





	Connective

	Informal meaning




	after P

	P is true in the next state




	eventually P

	P is true in a future state




	always P

	P is true in all future states




	P until Q

	Q is true in a future states and P is true until then




	P releases Q

	Q can only stop being true after P is true








To be more precise, a temporal logic formula is interpreted in a given state of a trace. Given a trace τ\tau the interpretation of every connective is given the state of index i≥0i ≥ 0. Given a formula P we write τ,i⊨\tau,i \models P to denote the fact that P is true in the state ii of τ\tau. We consider that a trace τ\tau satisfies a formula P, denoted τ⊨\tau \models P, if P is true in its first state, that is τ,0⊨\tau,0 \models P. And a formula is valid in a model if it is valid in all feasible traces of the model.

The following table shows the formal semantics of the future-time connectives.





	Connective

	Formal meaning




	τ,i⊨\tau,i \models after P

	τ,i+1⊨\tau,i+1 \models P




	τ,i⊨\tau,i \models eventually P

	∃j≥i⋅τ,j⊨\exists j \ge i \cdot \tau,j \models P




	τ,i⊨\tau,i \models always P

	∀j≥i⋅τ,j⊨\forall j \ge i \cdot \tau,j \models P




	τ,i⊨\tau,i \models P until Q

	∃j≥i⋅τ,j⊨\exists j \ge i \cdot \tau,j \models Q ∧\wedge ∀i≤k<j⋅τ,k⊨\forall i \le k < j \cdot \tau,k \models P




	τ,i⊨\tau,i \models P releases Q

	∃j≥i⋅τ,j⊨\exists j \ge i \cdot \tau,j \models P ∧\wedge ∀i≤k≤j⋅τ,k⊨\forall i \le k \le j \cdot \tau,k \models Q ∨\; \vee \; ∀j≥i⋅τ,j⊨\forall j \ge i \cdot \tau,j \models Q








To illustrate the connectives, here are some examples of formulas, which are all valid in the trace that is shown above. Notice that they do not necessarily hold in all the possible traces of the file sharing example.


	after some uploaded


	eventually some trashed


	always (some f : File | upload[f] implies after some uploaded)


	(some f : File | upload[f]) until (some f : File, t : Token| share[f, t])


	(some f : File | delete[f]) releases no trashed




As in relational logic, some connectives can be defined in terms of others. In particular, it is known that after and until are sufficient to define all other future-time connectives. For example, eventually P is the same as (not P) until P, always P is the same as not eventually not P and P releases Q is the same as not ((not P) until not Q) or the same as (Q until (Q and P)) or always Q.

The informal meaning of the past-time connectives is the following, and it’s dual to the future-time connectives.





	Connective

	Informal meaning




	before P

	P is true in the previous state




	once P

	P is true in a past state




	historically P

	P is true in all past states




	P since Q

	Q is true in a past state and P is true since then




	P triggered Q

	Q was at least true since P was true








The formal semantics of the past-time connectives is given in the following table.





	Connective

	Formal meaning




	τ,i⊨\tau,i \models before P

	i>0∧τ,i−1⊨i > 0 \wedge \tau,i-1 \models P




	τ,i⊨\tau,i \models once P

	∃j≤i⋅τ,j⊨\exists j \le i \cdot \tau,j \models P




	τ,i⊨\tau,i \models historically P

	∀j≤i⋅τ,j⊨\forall j \le i \cdot \tau,j \models P




	τ,i⊨\tau,i \models P since Q

	∃j≤i⋅τ,j⊨\exists j \le i \cdot \tau,j \models Q ∧\wedge ∀j<k≤i⋅τ,k⊨\forall j < k \le i \cdot \tau,k \models P




	τ,i⊨\tau,i \models P triggered Q

	∃j≤i⋅τ,j⊨\exists j \le i \cdot \tau,j \models P ∧\wedge ∀j≤k≤i⋅τ,k⊨\forall j \le k \le i \cdot \tau,k \models Q ∨\; \vee \; ∀j≤i⋅τ,j⊨\forall j \le i \cdot \tau,j \models Q








As examples, let us consider the following formulas, which hold in the 4th state of our illustrating scenario. Again, they do not necessarily hold in other states of the trace nor in other traces of the file sharing model.


	some shared and before no shared


	once no uploaded


	some t : token | historically t not in File.shared


	File = uploaded since some f : File | upload[f]


	(some f : File | upload[f]) triggered after some uploaded




As we said above, we consider that a trace satisfies a formula if its initial state satisfies it. A practical consequence is that a formula in Alloy (whether it is a fact or a property in a check or run command) is interpreted in the initial state of a trace. So, past-time connectives only make sense if they appear in the scope of future-time connectives. For instance, consider the following formula, meaning that some token has never been used: some t : Token | historically t not in File.shared. Interpreting this formula in the initial state of a trace makes it the same as some t : Token | t not in File.shared, which means that some token is not used, because there are no other states before the initial one. In other words, the past-time connective is useless. However, if historically is in the scope of a future-time connective, such as always, it can be useful. For instance, the formula all f : File, t : Token | always (share[f, t] implies historically t not in File.shared means that each time a file is shared with a token, this token has never been used before. Also, note that before is always false in the first state of the trace.





Expressiveness of linear temporal logic

Are past-time connectives really useful? A well-known theoretical result for LTL is that past-time connectives do not add any expressiveness to the logic [POPL80]. In other words, after and until are enough to express any property that is expressible in LTL. However, we also know [EATCS03] that past-time connectives allow for exponentially more succinct formulas, which make them very useful in practice.

What do you mean by temporal? In the literature, there are in fact several kinds of temporal logics. Their purpose is to reason over the behavior of a system, but they differ on all sorts of aspects. In the literature, the temporal logic at work in Alloy is referred to as Linear Temporal Logic (LTL) or sometimes Linear Temporal Logic with Past (PLTL). Although this is probably the most commonly used temporal logic, some kinds of temporal reasoning are not possible with LTL. For instance, if one needs to reason about different possible execution traces, a branching-time temporal logic, such as Computation Tree Logic (CTL) [LP81], must be used instead of a linear-time temporal logic. In order to reason about the amount of time that passed between different states, some other kind of temporal logics, which are called timed logics [LICS90], can also be used.

Why does Alloy only consider infinite traces? There exist some frameworks where the length of traces can be finite, but this makes the meaning of temporal connectives tricky. For instance, what is the meaning of after P in the last state of a finite trace? Defining it as either truetrue or falsefalse would be sensible [CAV03]. But in any case, the sames choice applies to after not P, and then not after P is not equivalent to after not P, which is admittedly counter-intuitive. A solution to avoid these issues is to consider infinite traces only. Remark that it is easy to simulate a finite behavior with an infinite trace, by considering a self-loop on the last state. This is in particular possible in case the Alloy model includes a stuttering event (see section Stuttering in the Behavioral modeling chapter).

Why does Alloy only show lasso traces? Remark that some infinite traces cannot be represented by lasso traces: consider, for example, a trace where P is true once in the first state, and then twice in the 3rd and 4th states, and then three times, and so on. This trace never reaches a repeating sequence of states. Therefore it cannot be represented by a lasso trace. However, a theoretical result for LTL called the Small Model Property (SMP) [JACM85] states that if a constraint has a trace that satisfies it, then it has a lasso trace that satisfies it. In other words, if there is no lasso trace satisfying a constraint, then there is no trace at all, which makes it is enough to only search for lasso traces in the analysis.

Is the fact constraining the system behavior required to specify a transition system? As it is presented in chapter Behavioral modeling, it is a good practice to specify an Alloy model as a transition system: a constraint (without any temporal connective) corresponds to the initial states and another constraint imposes that one action (or a stuttering step) occurs in every state. However, you can also add arbitrary temporal formulas as constraints of the model. Then, such formulas constrain the whole execution instead of only constraining the initial state and each transition. This can be useful to abstract away the behavior of some part of the model that we do not want to specify in detail as a transition system. This is typically the case of fairness assumptions, such as the one we specified at the end of chapter Behavioral modeling, to specify the fact that the system should empty the trash periodically.

Further reading

Safety, liveness, and fairness

Learn about the different kinds of formulas you specify in temporal logic.

Mutable top-level signatures

In the specification of our file sharing app in chapter Behavioral modeling: we’ve seen mutable signature as subsets of static signatures. In Alloy it is also possible to declare mutable top-level signatures. Although this sometimes makes for more natural models, there are some nuances of these signatures that must be taken into consideration.


Declaring top-level signatures

In our file sharing model, uploaded files were modelled using a mutable subset of File, the top-level signature that contains the universe of all possible files that can exist in a trace. Instead, we could argue that the universe of files known to the system is exactly the set of uploaded files, and that the value of File itself in each state corresponds to the set of uploaded files. In that case, we could have declared File itself as mutable instead of adding a new mutable subset signature. The signature declarations would then look as follows.




sig Token {}

var sig File {

  var shared : set Token

}

var sig trashed in File {}







	There are some important points to note when top-level signatures are used:

	

	The scope of a mutable top-level signature is the maximum number of different atoms it can contain in the full trace, and not the maximum at each different state. For example, with the default scope of 3, we can have at most 3 different uploaded files in each trace. For example, if at some state File contains 3 uploaded files, no more different files can be uploaded (of course, we can delete a file a re-uploaded it again later).


	In Alloy all top-level and extension signatures are disjoint. The same is true for mutable top-level and extension signatures: they are always disjoint, even at different points in time, meaning that an atom cannot move from one top-level signature to another one in a state transition. For example, if Token was also mutable, an atom contained in File at some state could never be part of Token in a different state.


	When there are mutable top-level signatures the univ is mutable as well, containing, in each state, all atoms contained in all signatures at that state. Similarly, the iden relation also becomes mutable.








Updating the rest of the specification to accommodate this change is not just a matter of replacing uploaded with File. In most formulas that will be the case, but in some formulas the changes are more subtle. As an example of the former case, consider fact init after replacing uploaded with File, that specifies the valid initial states.




fact init {

  // Initially there are no files uploaded nor shared

  no File

  no shared

}






Although this is a correct specification, the second constraint is now redundant. If in the initial state there are no atoms in File it will be impossible for relation shared between files and tokens to have any tuples, so we can can simplify it as follows.




fact init {

  // Initially there are no files uploaded nor shared

  no File

}






Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/mutable-toplevel-signatures/declaring-top-level-signatures



Adding new atoms to the universe

In the file sharing example, for most action predicates we get the intended specification by just replacing uploaded by File. As an example, consider action predicate empty, that specifies the action of emptying the trash bin.




pred empty {

  no trashed' // effect on trashed

  File' = File - trashed // effect on File

  shared' = shared // no effect on shared

}






Here, the effect on uploaded was just replaced by the same effect on File.

However, specifying action predicate upload is a bit more tricky, and cannot be updated by simply replacing uploaded by File. In particular, it no longer makes sense to parametrize it by the file that will be uploaded, since that file will not even exist before the action occurs. Instead, we can have a non-parametrized predicate whose effect is to upload any new file. To enforce that signature File will contain a new uploaded file in the post-state we could, for example, use constraint one File' - File or, alternatively, some f : File' | File' = File + f. The latter version is more convenient if we need to refer to the newly created atom in later effects, but that is not the case of upload. The new specification of upload could thus be as follows.




pred upload {

  one File' - File // effect on File

  trashed' = trashed // no effect on trashed

  shared' = shared // no effect on shared

}






The fact that specifies the valid transitions will then look as follows.




fact transitions {

  // The system must only evolve according to the defined actions

  always (

    upload or

    (some f : File | delete[f] or restore[f]) or

    (some f : File, t : Token | share[f, t]) or

    (some t : Token | download[t]) or

    empty or

    stutter

  )

}






Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/mutable-toplevel-signatures/adding-new-atoms-to-the-universe



Quantifying over mutable signatures

Concerning assertions, again it might not suffice to just replace uploaded by File. In particular, special care is needed with quantifications over mutable signatures. For example, consider assertion restore_undoes_delete.




assert restore_undoes_delete {

  all f : File | always (

    delete[f] and after restore[f] implies

    File'' = File and trashed'' = trashed and shared'' = shared

  )

}

check restore_undoes_delete






This assertion is now trivially true, because the quantification all f : File is outside any temporal operator, and thus only needs to hold in the initial state where File is still empty because no files were yet uploaded, as enforced by fact init. To correctly specify the desired assertion we need to move the quantification inside the always temporal operator, as follows.




assert restore_undoes_delete {

  always all f : File | (

    delete[f] and after restore[f] implies

    File'' = File and trashed'' = trashed and shared'' = shared

  )

}

check restore_undoes_delete






Now, at each state the quantified property must hold for all files that are currently uploaded at that state.

The specification of assertion one_download_per_token used function downloaded shown below, to compute the set of files that were once downloaded with a given token. For similar reasons, its specification no longer makes sense, because the function will now only return the files that are also currently uploaded.




fun downloaded [t : Token] : set File {

  { f : File | once (download[t] and t in f.shared) }

}






As an alternative, for this assertion we can still use the first formulation from the Behavioral modeling chapter that did not use this function.




assert one_download_per_token {

  all t : Token | always (

    download[t] implies

    after always not download[t]

  )

}

check one_download_per_token






Here the quantification all t : Token can still be outside always, because Token is immutable and thus already contains all possible tokens in the initial state. Of course, it could also be moved inside the always because its value is the same in every state.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/mutable-toplevel-signatures/quantifying-over-mutable-signatures

Further reading

A temporal logic primer

Learn in the detail the formal semantics of the temporal logic connectives used in Alloy.

Pointwise effects

When an action modifies the value of a mutable field, one must usually specify how one part of the field is changed by the action, and how another part is left unchanged (as seen in the Behavioral modeling chapter, this part is called a frame condition). For instance, the action share associates a new sharing token t to file f, but other files are left unchanged by this operation.




pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  shared' = shared + f->t // effect on shared

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






In the specification above, the complete effect on relation shared, that is the modification part and the frame condition, is specified all at once by saying how the whole field, viewed as a binary relation, is to be updated. We call this style of effect purely relational or pointfree.

An alternative approach to the specification of effects is to rely on what we call a pointwise update. In this style, rather than specifying how shared evolves all at once, we make a distinction between the change for input file f specifically, and the frame condition for files other than f. This would result in the following alternative specification of share.




pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  f.shared' = f.shared + t // effect on f.shared

  all g : File - f | g.shared' = g.shared // no effect on other shared files

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






The same style can be used for action predicates delete and download. Notice that the latter updates relation shared if token t is in its range. Nonetheless, the pointwise style can be used even if the join is performed on the right column of the relation.




pred delete [f : File] {

  f in uploaded - trashed // guard

  trashed' = trashed + f // effect on trashed

  no f.shared' // effect on f.shared

  all g : File - f | g.shared' = g.shared // no effect on other shared files

  uploaded' = uploaded // no effect on uploaded

}



pred download [t : Token] {

  some shared.t // guard

  no shared'.t // effect on shared.t

  all u : Token - t | shared'.u = shared.u // effect on other shared tokens

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






Both styles are equivalent, so which one should you favor? Some people prefer the pointwise style because the modification of a field for a specific variable is arguably more salient. On the other hand, the relational style is shorter. Some people like this terseness because they can spot the effect of an action on a field in a single stroke. Ultimately, there are good arguments for both styles, so this is mainly a matter of personal taste!

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

Macro system

The Alloy Analyzer comes with a textual macro system that can be handy to define reusable expressions or constraints with less technical restrictions than functions or predicates, but less safeguards too.


Macro definition

A predicate or function provides the ability to define a reusable expression or constraint, possibly with formal parameters. A predicate or function definition must comply with certain technical requirements, which are checked by the Alloy Analyzer:


	The possible formal arguments can only stand for expressions (not predicates);


	The actual arguments must comply with the arity of formal parameters as well as with related type constraints.




Macros are also reusable expressions or constraints. Syntactically, a macro is defined at the top level of a file, using the let keyword, like a pred or fun:




let m [x, y, …] { … }






But the definition, on the other hand, is less constrained:


	The type and arity of formal arguments is not checked;


	The arguments can not only stand for expressions or constraints, but even for partially-applied functions, predicates or macros.




Then, calling a macro and passing it an actual parameter corresponds to substituting textually the bound variable with the said parameter. This process is classically called macro expansion in programming languages. This is very powerful but the consequence is that most typing or arity errors, made when calling a macro, may be cryptic, and the originating error may be difficult to spot.

For this reason, the use of macros is rather discouraged. Nevertheless, their flexibility can be useful to write shorter and clearer specifications, so we illustrate them on two examples:


	The first one shows how the absence of arity checking can be leveraged to simplify the writing of frame conditions;


	The second one shows how one can define constraint schemas thanks to formal parameters standing for constraints.




Like predicates and functions, macros are lexically scoped, which means that if a macro refers to a name that is not part of the list of parameters, then the name will be looked for in the file where the macro was defined (rather than the file where the macro is used).

Furthermore, macros can be partially applied. This means that if a macro with say, n arguments, is called with only k < n arguments, then it yields a new macro where the said k arguments have been applied.



A macro for frame conditions

The effects of an event can be specified with many different styles, for example action share can be specified using two different styles. For instance, in a relational style it could look as follows.




// relational style

pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  shared' = shared + f->t // effect on shared

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






Alternatively, in a pointwise style it could take the following shape.




// pointwise style

pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  f.shared' = f.shared + t // effect on f.shared

  all g : File - f | g.shared' = g.shared // no effect on other shared files

  uploaded' = uploaded // no effect on uploaded

  trashed' = trashed // no effect on trashed

}






In both approaches, specifying frame conditions (constraints stating that some mutable signature or field doesn’t change under the action) is tedious and error-prone. Now suppose we had an unchanged predicate ensuring some argument doesn’t change in the next instant. With such a predicate, our specification of frame conditions would be shorter and safer. The version in the relational style would be adapted as follows.




// relational style

pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  shared' = shared + f->t // effect on shared

  unchanged[uploaded] // no effect on uploaded

  unchanged[trashed] // no effect on trashed

}






The version in the pointwise style would instead be adapted as follows, where the macro is applied to particular projections of relation shared.




// pointwise style

pred share [f : File, t : Token] {

  f in uploaded - trashed // guard

  historically t not in File.shared // guard

  f.shared' = f.shared + t // effect on f.shared

  all g : File - f | unchanged[g.shared] // no effect on other shared files

  unchanged[uploaded] // no effect on uploaded

  unchanged[trashed] // no effect on trashed

}






In the example above, unchanged is applied to sets but, for full generality, it should also be possible to apply it to a relation, such as the binary relation shared in action upload:




// relational style

pred upload [f : File] {

  f not in uploaded // guard

  uploaded' = uploaded + f // effect on uploaded

  unchanged[trashed] // no effect on trashed

  unchanged[shared] // no effect on shared

}






Defining such a generic predicate is however impossible in Alloy. Indeed, in an Alloy predicate (or function) arguments must have a single, fixed arity, while this hypothetical unchanged predicate should accept arguments with any positive arity.

However, it is possible to define unchanged as a macro, since macros do not check the type nor arity of arguments, which is precisely the feature we need. This could be declared as follows.




let unchanged[x] { x = (x)' }






Note that the parentheses in (x)' are absolutely required: when calling unchanged, the actual argument coming in place of x may be an arbitrary complex expression, like in unchanged[g.shared] in action predicate share in the pointwise style. Suppose the expression has the shape r.s.t, with r and t both mutable fields, while s is static. Then our definition of unchanged will ensure that the prime operator is properly applied to every mutable sub-term. Indeed, according to the semantics of the prime operator, (r.s.t)' is equal to r'.s'.t', which is equal to r'.s.t' as s is static. This is different from expression r.s.t' that would results without parenthesis, with is equal to r.s.(t').

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/macros/a-macro-for-frame-conditions

Further reading

Pointwise effects

In the next section we used two different styles to specify the effects of an event. Learn more detail about them.

Pointwise effects



Defining constraint schemas

In Behavioral modeling, checking the non_restored_files_will_disappear assertion (a liveness property) relied on a fairness assumption specified as follows.




fact fairness_on_empty {

  always eventually empty

}






While it was not the case here, often, several events must share a similar fairness assumption in order to ensure a liveness property. The only difference between all these assumptions is the fired event (here empty). We could just repeat them several times but it’s admittedly cumbersome and even error-prone.

A better solution would be to create a parameterized constraint. This is precisely the second usage of the macro system mentioned in the beginning of this chapter. We can thus define a fair macro as follows:




let fair [ev] { always (eventually (ev)) }



fact fairness_on_empty {

  fair[empty]

}






Notice, again, that we write ev between parentheses in case the actual parameter contains logical connectives of lower precedence than always (such as or, if we wanted to impose the constraint on a disjunction of events). Without parentheses, fair[a or b] would expand to always (eventually a or b), which is not equivalent to always (eventually (a or b)), which is what we wanted to enforce.

Alloy model

Further reading

Safety, liveness, and fairness

Here we defined a macro for a specific kind of fairness. Learn about other kinds of fairness constraints, for which macros could also be defined.

Meta-capabilities

Although it is not a very well known feature, Alloy has some basic meta-capabilities that allow to manipulate signatures and fields at the meta-level. This is an advanced feature that can sometimes ease the encoding of certain constraints and even promote maintainability by avoiding updating constraints as the model evolves.


The Alloy meta-model

Let us get back to the file sharing example from the Behavioral modeling chapter, but extend its configuration slightly to better exemplify the Alloy’s meta-capabilities. In particular, let us also add some abstract attributes to files, introduce different types of files as (static) extension sub-signatures of File, and say that links point to other files. This will result in the following static declarations.




sig Token {}



sig Attribute {}



sig File {

  attributes : set Attribute,

  var shared : set Token

}



sig Text, Binary extends File {}



sig Link extends File {

  link : one File

}






A (simplified version of the) Alloy meta-model comprises the signatures and fields declared in a model, along with some of their properties. The Analyzer actually provides an option to inspect this meta-model through menu option Execute ‣ Show Metamodel (or shortcut cmd-m). Below is the result for this version of the file sharing model.

[image: ../../../../_images/metamodel.png] 

Top-level signatures and extension signatures are shown as yellow squares, while subset signatures are shown as blue ellipses. The signature hierarchy is shown with black edges for extension (extends) and subset (in) signatures. Red edges denote the fields, which in this model are all binary. Mutable elements are drawn with dashed lines.

Alloy provides a few meta-signatures that capture these elements of the meta-model. These are all identified by a $ suffix. The two essential ones are sig$ – which contains an atom identifying every signature declared in the model – and field$ – which contains an atom identifying every field declared in the model. By default, these meta-signatures are not created for every Alloy model to avoid cluttering, but only if any meta-signature is referred in the model. So let us activate the meta-capabilities of Alloy by simply writing the following command, which is trivially true in non-empty models:




run some_sig {

  some sig$

} for 2






Meta-signature sig$ contains a meta-atom identifying each signature of the model, so this property is trivially true in our model where there are various signatures declared. Nonetheless, this activates the meta-capabilities and introduces meta-signatures in the instance which we can inspect in the evaluator.

Let us open an instance returned by the Analyzer and open the evaluator by pressing Evaluator. Then let us ask for the value of meta-signature sig$. You’ll get the following set of meta-atoms.





	Attribute$

	Binary$

	File$

	Link$

	Text$

	Token$

	trashed$

	uploaded$








As you can see, there is one meta-atom for each of the signatures declared in the model (also identified by a $ suffix), including extension and subset signatures. The value of meta-signature field$ returns instead the meta-atoms representing the fields for all signatures declared in the model.





	File$attributes

	File$shared

	Link$link








You can refer directly to these meta-atoms in the evaluator, and actually, unlike regular atoms, you can also mention them in directly in the model. (Notice that a signature meta-atom always ends in $, such as File$, while the respective regular atoms end with $ followed by an identifier, such as File$0 and File$1). Additionally, Alloy also provides subsets of meta-atoms to distinguish between the static and mutable elements of the model. Namely, meta-subset static$ returns all static signatures and fields, and meta-subset var$ all mutable signatures and fields.

Each meta-signature has a few meta-fields defined that allow us to navigate over the structure of the model. These are parent, to get the parent signature of a sub-signature, fields, to get all the fields of a signature, and subfields, to get all fields declared by a signature or one of its sub-signatures. Due to the Alloy type system, you won’t be able to call these meta-fields directly on the evaluator since it won’t be able to disambiguate between the instances for each signature. But you can call it for a particular meta-atom, such as File$ <: fields. In this case, as expected, you’ll get the following tuples.





	(File$,File$shared)

	(File$,File$attributes)








Finally, and most importantly, a value meta-field is provided for each meta-atom that retrieves its valuation in a particular instance. The figure below depicts this process for a particular instance resulting from the command presented above, namely the value of the signature File by calling value over the corresponding meta-atom (which is the same as just calling File directly).

[image: Get the code to generate this instance.]

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/behavioral-topics/meta/the-alloy-meta-model

Further reading

The trace evaluator

In this section we used the evaluator. Learn in more detail how to use it to inspect traces.

The trace evaluator



Specifying meta-constraints

Given the available meta-model, let us now explore how it can be used to ease the writing of certain (meta-)constraints. For instance, let’s say that we just want to see scenarios where all signatures of the configuration are not empty. This can be achieved with the following command.




run no_empty_config_sigs {

  all s : sig$ & static$ | some s.value

}






Notice that, for now, we are restricting the signature quantification to those that are static. This command will have the intended behavior regardless of the model and the declared signatures, making it resilient to model evolution.

As another example, we may want to see scenarios where the fields of a particular signature are not empty. As said above, we can refer to specific meta-atoms in the model, so we could just write the following command.




run no_empty_file_fields {

  all f : File$.subfields & static$ | some f.value

}






This will only generate instances where there are necessarily some attributes and links assigned (since we called subfields on meta-atom File$, it also retrieves field link from links).

Perhaps more interesting is using the meta-signatures in the context of behavioral modelling. For instance, it is very often the case that there is a fact in the model restricting all declared mutable signatures and fields to be empty in the first state. That is also the case in the file sharing example. Using meta-signatures, this fact could be trivially written for any model as follows, forcing all mutable elements to be empty in the first state.




fact init {

  // Initially all mutable elements are empty

  all v : var$ | no v.value

}






This strategy is also useful to write stuttering predicates which are common in behavioral models, as is the case in the file sharing example. Using meta-signatures, the stuttering predicate could just be rewritten as follows, stating that the value of all mutable elements remain unchanged between the current and the next state.




pred stutter {

  all v : var$ | v.value = v.value' // no effect on anything

}






A similar strategy could be used to encode frame conditions on event predicates, namely iterating over all mutable fields that are not relevant for the event and force them to remain unchanged. In the file sharing model, we could, for instance, re-encode the upload event as follows.




pred upload [f : File] {

  f not in uploaded // guard

  uploaded' = uploaded + f // effect on uploaded

  all v : var$ - uploaded$ | v.value = v.value' // no effect on anything other than uploaded

}






This feature can also be used to quickly specify rich scenarios. For instance, let us say we want to see the minimal traces where every element of the model is used at some point. We can just write the following command, that will guarantee that every mutable element is eventually populated. For the file sharing example, this is a trace with 5 states, where a file is uploaded, shared, downloaded, and then deleted.




run everything_happens {

  all v : var$ | eventually some v.value

}

An idiom for event depiction

When validating the file sharing example model in chapter Behavioral modeling, the reader has probably realized that the Alloy visualizer does not show the event (or events) occurring in a given transition. This is because, as customary in Alloy, events were modeled as regular predicates restricting two succeeding states, and Alloy has no way of knowing that those particular predicates should be interpreted as events. In this section we will devise an idiom (a modeling pattern) that allows the depiction of events in the visualizer. As an useful side effect, it also eases the specifications of certain classes of constraints.

Let’s consider an instance returned when executing command example, whose transitions are shown below.

[image: Get the code to generate this instance.] [image: Get the code to generate this instance.] [image: Get the code to generate this instance.] [image: Get the code to generate this instance.]

After a short examination, and based upon our knowledge of the specification, we can determine that this trace uploads a file, shares it, deletes it, empties the trash and then stutters forever. However, in the general case, for more complex specifications, the fact that events aren’t displayed makes their interpretation tedious and error-prone.

Further reading

Visualization customization

This topic builds on the standard visualization theme customization features of the Analyzer. Learn in detail how they work.

Visualization customization


Depicting parameterless events

The crux of the idiom presented here is to use derived relations to represent the events happening in a given state. In particular, the value of these relations is calculated for each particular state, so their value may change over the trace. Yet, it may not seem immediately obvious how to use them since derived relations define relations based on existing signatures, while we haven’t got any such signature for events, only predicates. No problem! Let’s introduce a signature (more precisely: an enumeration, since the required atoms are known and we won’t need to add fields) representing event names. Observe how we use the capitalized names of predicates (corresponding to events) as elements of the enumeration, in order to enhance readability.




enum Event {

  // event names

  Empty, Upload, Delete, Restore, Share, Download, Stutter

}






Also, in the theme customization menu, change the shape and color of events, for instance to a blue parallelogram. Then set Hide unconnected nodes to On for Event nodes, as we don’t want to see all event names at all states, but only those corresponding to events occurring in a given state.

Now, let’s introduce a first derived relation. Let us start with the simplest case, the events that take no parameters, empty and stutter.




fun empty_happens : set Event {

  { e : Empty | empty }

}



fun stutter_happens : set Event {

  { e : Stutter | stutter }

}






This definition may seem strange at first but this is indeed what we want. Sets by comprehension retrieve a set of atoms for which a certain formula is true; if this formula is temporal, a different set may be returned in each state. So the empty_happens derived relation yields, in every state, a subset of Event that will be populated (exactly by singleton Empty) if the empty predicate is true, and empty otherwise.

Let us observe the effect of adding this derived relation to the visualization. First, open the theme customization menu and set both Hide unconnected nodes and Show as labels to Off for the subsets $empty_happens and $stutter_happens. This will override the hiding of Event nodes that belong to those subsets.

[image: Get the code to generate this instance.]

Then head to the last states of the trace (where the empty and stutter events occur). You will now be able to observe the event happening, as shown below. You’ll notice that in the last state both the Stutter and Empty atoms are shown. This is because the current version of the empty action has no guard, and thus can be applied even if there is no file in the trash. In those cases, its effect is indistinguishable from stuttering: nothing happens.

[image: Get the code to generate this instance.]

Depicting events with parameters

Now, let’s consider events that have parameters, such as the upload event that takes a file as a parameter. In this case, the derived relation shouldn’t just yield the Upload name as we wouldn’t be able to tell for which file (or files) it is satisfied. We rather return the set of all pairs whose first coordinate is the Upload name and whose second coordinate is a file on which the upload event happens. And likewise for the other events that take a single parameter.




fun upload_happens : Event -> File {

  { e : Upload, f : File | upload[f] }

}



fun delete_happens : Event -> File {

  { e : Delete, f : File | delete[f] }

}



fun restore_happens : Event -> File {

  { e : Restore, f : File | restore[f] }

}



fun download_happens : Event -> Token {

  { e : Share, t : Token | download[t] }

}






Now the first state of the trace is as follows. Since Event nodes related by upload_happens are no longer unconnected, they will show up in the visualization without needing to change the theme as was the case for the events without parameters.

[image: Get the code to generate this instance.]

Finally, we can proceed with the last event, share. Since this event takes two parameters, the derived relation representing it will now be ternary, the first coordinate having the Share name and the other two the file and the token on which the share event occurs.




fun share_happens : Event -> File -> Token {

  { e : Share, f : File, t : Token | share[f, t] }

}






The result is as follows.

[image: Get the code to generate this instance.]

As you start visualizing a trace, you may realize that the depiction of events without further theme customization is deficient when an event takes two parameters or more. A possible alternative visualization is to show event parameters as labels of the event name rather than edges. However, we need to somehow identify which events occur in each state without relying on those edges and the Hide unconnected nodes option. To do so, we can introduce a further derived relation that just returns the set of names of events occurring in a state.




fun events : set Event {

  empty_happens + stutter_happens +

  (upload_happens + delete_happens + restore_happens).File +

  download_happens.Token + share_happens.Token.File

}






Note that, for instance, expression upload_happens.File projects away any parameter of upload events and keeps only the event name. Then the following theme can be configured:


	Uncheck Hide unconnected nodes for the $events set and set Show as labels to Off.


	In the relations part, set all derived relations for events to Show as attribute and change the displayed name for the derived relations to args (shown below for $upload_happens).




[image: Get the code to generate this instance.]

Notice how the arguments of events can be seen clearly (namely File1 for the upload event in state 0, and File1 and Token1 for the share event in state 1).

On a last note, in our file sharing example all events are interleaved, meaning that exactly one event occurs in each state (except for empty actions indistinguishable from stuttering). This is not necessarily the case, and models that allow true concurrency may allow many events to occur simultaneously, which hinders even further the identification of the occurring events without a proper visualization. Luckily, the idiom we just presented will work exactly the same if multiple events occur in a state: the derived relations will just return additional tuples, which will be depicted as well.

Uses of the event idiom beyond visualization

This idiom is also useful to specify certain classes of formulas in a nicer way. First, the idiom allows to greatly simplify the transitions fact.




fact transitions {

  // The system either evolves according to the defined actions or stutters

  always some events

}






You may also check that it is never possible to witness the occurrence of two indistinguishable events in the same state, which is true in this case.




check at_most_one_event {

  always lone events

} for 3






This will return a counter-example since, as we’ve seen above, empty can occur with an empty trash and in that case is indistinguishable from stuttering. However, if we’ve added a guard to the empty action predicate, it would become a valid property.

Now suppose you want to see the example of a trace in which two share events happen in a row (for arbitrary arguments). Until now, you would have had to write this in a rather contrived way, for instance as follows.




run two_shares_in_a_row {

  eventually (

    (some f : File, t : Token | share[f, t]) and

    after (some f : File, t : Token | share[f, t])

  )

} for 3






The derived relations defined above are also useful to specify that an event occurs (for some parameters). It suffices to specify that the corresponding derived relation is non-empty. So, the above run could be specified just as follows.




run two_shares_in_a_row {

  eventually (some share_happens and after some share_happens)

} for 3






Predicates and functions belong to different namespaces in Alloy, and they can always be disambiguated based on the syntactic context. For this reason, it is possible to give to the functions defined above the same name as the respective predicate events. If we did so, to check that event e occurs, we just need to check some e.

As a final remark, notice that this idiom doesn’t entail any performance penalty:


	If derived relations are only used for the depiction of events, they are only computed when visualizing instances.


	If they are also used in formulas, for example to check if an event occurs, they actually use less variables than the version where a predicate is passed arguments quantified existentially.




Thus, the only price to pay is a small but systematic inflation, albeit admittedly tedious, of our models. In the future, an extension to Alloy could easily be proposed to automate this task.

Further reading

Encoding trace scenarios

The event idiom is also helpful when we are trying to encode concrete execution scenarios.

Encoding trace scenarios

 





Encoding trace scenarios

As an Alloy specification increases in size and complexity, its validation through the exploration of arbitrary instances in the visualizer becomes more and more difficult. A technique that can be used is to combine this interactive exploration with the specification of run commands that directly search for interesting scenarios. When models have mutable structures, scenarios now have a temporal facet that must also be restricted, which can get difficult to manage. Also, often we don’t want the command to completely fix the trace since we want to be able to explore the design. In those cases, the scenario may be under-specified and the Analyzer will complete it by solving the specified constraints. This topic presents an idiom to encode such trace scenarios.

Further reading

Encoding test instances

This topic builds on a technique that can be used to encode structural scenarios. We recommend you read about that technique before reading this topic.

Encoding test instances


State-oriented scenario encoding

A trace is comprised of a (immutable) configuration and a (mutable) state. The first step of encoding a scenario is to restrict the configuration, and this can be achieved with the same strategy used for encoding test instances, based on some/disj patterns. For example, let us try to encode the scenario that was being explored in chapter Behavioral modeling: upload a file, share it twice, download it once, delete it, and finally empty the trash. This trace requires exactly one file and two tokens in the configuration (there are no immutable fields in the file sharing example). Such configuration could be specified as follows.




run scenario_two_shared {

   some f : File, disj t0, t1 : Token {

      File = f

      Token = t0 + t1

      // …

   }

} for 1 File, 2 Token






Focusing now on the mutable part of the model, we must extend the above formulas with constraints that encode the different states of the desired execution trace. The main issue here is that with the standard temporal operators we have seen so far, this would result in either nested and/after formulas, or expressions with several appended primes ', neither being a scalable approach. For example, to restrict the first 4 states of the desired scenario we could write the following.




no uploaded and after (uploaded = f and after (uploaded = f and after uploaded = f))

no shared and after (no shared and after (shared = f->t0 and after shared = f->t0 + f->t1))

no trashed and after (no trashed and after (no trashed and after no trashed))






Or, alternatively, the following.




no uploaded and uploaded' = f and uploaded'' = f and uploaded''' = f

no shared and no shared' and shared'' = f->t0 and shared''' = f->t0 + f->t1

no trashed and no trashed' and no trashed'' and no trashed'''






Some of these formulas could of course be simplified (for instance, we could just state always no trash), but they quickly become unmanageable.

The temporal sequence operator

To address this kind of rather common formulas, Alloy has a sequential temporal operator ; that eases their formulation: a formula p;q literally means p and after q. Moreover, this operator has the least precedence of all logic and temporal operators, further simplifying the combination of formulas restricting each individual state. Given this operator, we can now encode our scenario with the following command.




run scenario_two_shared {

  some f : File, disj t0, t1 : Token {

    File = f

    Token = t0 + t1



    no uploaded; uploaded = f; uploaded = f; uploaded = f; uploaded = f; uploaded = f; no uploaded

    no shared; no shared; shared = f->t0; shared = f->t0 + f->t1; shared = f->t0; no shared; no shared

    no trashed; no trashed; no trashed; no trashed; no trashed; trashed = f; no trashed

  }

} for 1 File, 2 Token






If we now run this scenario, we will get exactly the trace we were expecting. Below is the first transition (an upload action), and you can see in the trace overview that it has the expected 7 states.

[image: Get the code to generate this instance.]

Recall that due to the mechanics already explained, the quantified variables are Skolemized and appear in the visualizer identified by a $ prefix and the name of the command, as shown above, but they can be omitted in the theme. This may help identify which atoms in the scenario correspond to the variables in the command, but they also clutter the visualization. Below is the second transition of the same scenario (a sharing action) after disabling Show as labels in the theme for those sets.

[image: Get the code to generate this instance.]

Since we’ve fully restricted the first 7 states of the trace, we might think that the scenario is fully specified and that any instance exploration operation fails to produce another trace. In fact, if you hit New Trace in the visualizer you’ll find that there are many possible traces that respect the specified scenario, namely any valid trace that extends its behavior beyond the first 7 fixed states. Below is one such alternative, which rather than stuttering after emptying the trash, uploads the deleted file again and deletes it again, going back to state 5.

[image: Get the code to generate this instance.]

Exploring the possible continuations of a scenario may or not be something interesting to explore. For instance, you may wish to explore whether it is possible to share the file again (it isn’t because all tokens available in the scenario configuration have been used). In fact, as expected, these formulas can be as under-specified as we wish. For instance, we could leave certain relations unrestricted and just leave them to be solved by the Analyzer. Rather than encoding a single scenario, such commands would encode a “family” of related scenarios.

If we actually wanted the scenario to perform exactly the 6 actions and then stutter forever, we have to enforce what happens after the last state in the command’s constraint. The ; operator can combine arbitrary Alloy temporal formulas, although nesting temporal formulas quickly become difficult to manage. In this case we just want to restrict the behavior after the last step, so we can just specify that the desired last state always happens from that point onwards.




run scenario_two_shared_stutter {

   some f : File, disj t0, t1 : Token {

      File = f

      Token = t0 + t1



      no uploaded; uploaded = f; uploaded = f; uploaded = f; uploaded = f; uploaded = f; always no uploaded

      no shared; no shared; shared = f->t0; shared = f->t0 + f->t1; shared = f->t0; no shared; always no shared

      no trashed; no trashed; no trashed; no trashed; no trashed; trashed = f; always no trashed

   }

} for 1 File, 2 Token






If we run this command and then ask for a New Trace, the Analyzer will report that there is no such instance.

Notice that, since these scenarios are encoded as plain formulas, we can refactor out common formulas into auxiliary predicates. For instance, although configurations are extremely simple in the file sharing example, the two scenarios above share the same configuration, so we can reuse that portion of the command.




pred two_tokens [f : File, t0, t1 : Token] {

  File = f

  Token = t0 + t1

}



run scenario_two_shared {

  some f : File, disj t0, t1 : Token {

    two_tokens[f, t0, t1]



    no uploaded; uploaded = f; uploaded = f; uploaded = f; uploaded = f; uploaded = f; no uploaded

    no shared; no shared; shared = f->t0; shared = f->t0 + f->t1; shared = f->t0; no shared; no shared

    no trashed; no trashed; no trashed; no trashed; no trashed; trashed = f; no trashed

  }

} for 1 File, 2 Token



run scenario_two_shared_stutter {

  some f : File, disj t0, t1 : Token {

    two_tokens[f, t0, t1]



    no uploaded; uploaded = f; uploaded = f; uploaded = f; uploaded = f; uploaded = f; always no uploaded

    no shared; no shared; shared = f->t0; shared = f->t0 + f->t1; shared = f->t0; no shared; always no shared

    no trashed; no trashed; no trashed; no trashed; no trashed; trashed = f; always no trashed

  }

} for 1 File, 2 Token

Event-oriented scenario encoding

The encodings above followed a “relation-wise” definition of the scenario, in the sense that we restricted the evolution of each mutable relation independently. Sometimes it’s easier to reason about scenarios in a “state-wise” manner, particularly for relations closely related. We could easily adapt this idiom for that purpose as follows (again, the ; operator has the lowest precedence).




run scenario_two_shared_stutter {

  some f : File, disj t0, t1 : Token {

    two_tokens[f, t0, t1]



    no uploaded + trashed and no shared;

    uploaded = f and no shared and no trashed;

    uploaded = f and shared = f->t0 and no trashed;

    uploaded = f and shared = f->t0 + f->t1 and no trashed;

    uploaded = f and shared = f->t0 and no trashed;

    uploaded = f and no shared and trashed = f;

    always (no uploaded + trashed and no shared)

  }

} for 1 File, 2 Token






This command represents exactly the same scenario as the previous “relation-wise” version. Notice that we can’t just say no uploaded + trashed + shared because the + operator must combine relations with the same arity.

We can take this approach even further. So far we’ve encoded the expected scenario by directly restricting the value of the states. This allows us to exactly restrict the value of the relations in each state, but the result is verbose. An alternative is to instead just use the action predicates and force their occurrence in each desirable state. This results in simpler encodings, but at the cost of disregarding the concrete value of the relations. In particular, if an event is non-deterministic, the same action event may allow different state transitions to occur.

Let us get back to the scenario above. The same command could be written instead as follows.




run scenario_two_shared_event {

   some f : File, disj t0, t1 : Token {

      two_tokens[f, t0, t1]



      upload[f]; share[f, t0]; share[f, t1]; download[t0]; delete[f]; empty; always stutter

   }

} for 1 File, 2 Token






For the file sharing application, where all events are deterministic, this command represents exactly the same scenario as the previous versions.

This idiom is the one used throughout the book to encode the presented example traces, which you can access by clicking the figures.

Further reading

An idiom for event depiction

Learn how to us an appropriate theme to ease even further the validation of scenarios.

An idiom for event depiction

  





The trace evaluator

The Alloy Analyzer evaluator can be used to evaluate the value of expressions and formulas. It can also be used if a model declares mutable structures, but there are some nuances you should be aware.

Further reading

The instance evaluator

Learn how to use the evaluator to see the value of immutable expressions and formulas before learning the nuances of evaluating mutable ones.

The instance evaluator


Evaluating expressions

As in the static version of the visualizer, the evaluator is still opened by pressing the Evaluator button in the toolbar of the instance visualizer window, and closed with the Close Evaluator button in the toolbar.

The main aspect to take into consideration in the trace version of the evaluator, is that every constraint or expression is evaluated in the state currently focused on the visualizer (the one on the left-hand side). This applies also to temporal constraints: if you evaluate an always constraint, it will only check whether a property holds from the focused state onwards. This is different from the constraints written in the model itself, which are always evaluated from the first state. When you first open the visualizer, the focused state will be the first one, but as you navigate the trace using the → or ← buttons in the toolbar, the focused state may be one further down the trace.

Let us get back to the file sharing example from chapter Behavioral modeling, and, to get some interesting traces, let us define a command that generates traces where a file is shared and then deleted.




run shared_deleted {

  some f : File | eventually (f in shared.Token and after f in trashed)

} for 2






Let us execute the command and then open the evaluator by pressing Evaluator. Notice that the visualizer still shows two states side-by-side, and the trace overview is still shown on top of it. Moreover, the trace navigation buttons → or ← are still available with the evaluator open. Again, recall that the evaluator will act on the state focused on the left-hand side of the visualizer. So if you ask for uploaded, the evaluator will reply with the empty set. You also evaluate temporal expressions. So you can ask for the value of uploaded'. This will evaluate relation uploaded in the state next to the first, which has a single file inside. Temporal expressions are valid even if they go beyond the 2 shown states. For instance, we can see that uploaded becomes empty at the fifth state.

[image: Get the code to generate this instance.]

Now, let us use button → to further explore the trace, and focus on the fourth state. If you now evaluate trashed, you’ll get a set with a single file. This is expected since any temporal expression is now evaluated from this state onward, and there is indeed a file in the trash in the fourth state.

[image: Get the code to generate this instance.]

Evaluating constraints

Besides expressions, the evaluator also supports any temporal constraint, including those with past and future operators. The same rule applies to constraints: they are evaluated from the focused state. For instance, getting back to the example, you can ask if, from that point onwards, there is no shared file, which is true. But you can also ask if at any point in the past there was a shared file, which is also true.

You can also call any function and predicate defined in the model. This has an interesting usage in behavioral modelling, since we’ve already seen in chapter Behavioral modeling that transitions are often defined by enforcing action predicates at each state. A consequence of this is that there is nothing in the visualizer that identifies which event occurred. The evaluator can be used to quickly check which event occurred in a state transition. Since you can refer to concrete atoms in the evaluator, you can also test whether an event has occurred with a particular atom as a parameter. Below we show some of these constraints evaluated over the fourth state of the trace being visualized.

[image: Get the code to generate this instance.]

Further reading

An idiom for event depiction

We’ve mentioned how you can identify occurring events in the evaluator, but you can also have them appear in the visualizer.

An idiom for event depiction

 





Safety, liveness, and fairness

The temporal logic supported by Alloy is rich and allows for the definition of both safety and liveness properties. This section explores the difference between these two classes.




Safety vs liveness

When considering temporal properties, there is an important theoretical distinction between two categories concerning the way one can prove them. These categories were introduced by Lamport [TSE77] and developed by Halpern and Schneider [IPL85]. Roughly speaking, we can distinguish between safety properties, that state that something bad will not happen, and liveness properties, that state that something good will happen.

In order to define these categories in a more formal way, let us recall that we consider that an execution trace of a system consists in an infinite sequence of states. Then, a property is simply a set of infinite sequences of states. Note that when using Alloy, we can specify a property using a logic formula (the property is then the set of infinite sequences of states that satisfy this formula). In the following, if π\pi is a finite sequence of states (also called prefix) and τ\tau is an infinite sequence of states (a continuation of π\pi) then π⋅τ\pi \cdot \tau denotes the concatenation of π\pi and τ\tau.

Now, let us define safety and liveness categories. In the definition of a safety property, the focus is made on the bad thing that the property prohibits:



A property P is a safety property if any trace that violates P includes a bad prefix π\pi, that is, a prefix such that for any possible infinite continuation τ\tau, π⋅τ\pi \cdot \tau does not satisfy P. Intuitively, the only way to violate a safety property is by doing something bad which is unrecoverable.





In the definition of a liveness property, the prescribed good thing does not appear explicitly:



A property P is a liveness property if, for any possible prefix π\pi, there exists some infinite continuation τ\tau such that π⋅τ\pi \cdot \tau satisfies P. In other words, it is always possible to postpone the satisfaction of the good thing.





Given a property (which, in our case, is specified using a logic formula) it is not obvious to determine whether it falls into safety or liveness category (or into none). There exist some syntactic fragments of Linear Temporal Logic that are known to be pure safety or pure liveness, such as the ones studied in [FAC94]. For instance, if P is a formula not including any temporal connective, then always P, which is called an invariant, is a safety property, and eventually P and eventually always P are liveness properties.

Let us consider the following property from the file sharing example:




assert shared_are_accessible {

  always shared.Token in uploaded - trashed

}






This is clearly a safety property, because the formula that is in the scope of always does not include any temporal connective.

Similarly, the following (obviously invalid) property, which states that all files will eventually be in uploaded, is clearly a liveness property.




assert all_files_in_uploaded {

  all f : File | eventually f in uploaded

}






For the following property, the decision wether it is a safety or liveness property is trickier:




assert restore_undoes_delete {

  all f : File | always (

    delete[f] and after restore[f] implies

      uploaded'' = uploaded and trashed'' = trashed and shared'' = shared

  )

}






Indeed, the formula that is in the scope of always includes after and ' (prime) connectives, plus whatever connective is present in the event predicates delete and restore. In order to be convinced that this is a safety or a liveness property, an interesting perspective is to think about the possible violations of this property. Indeed, if it is a safety property, then you simply need to look at a finite prefix of a trace to be convinced that the bad thing happens (meaning that the property is violated). However, if it is a liveness property, you necessarily have to see the whole infinite trace to be convinced that the good thing does not happen. This is the reason why safety properties can be monitored (a system observer, or monitor, can detect a violation) whereas liveness properties cannot.

In the case of restore_undoes_delete, you can convince yourself that a violation consists in a trace where some file is deleted, then restored and such that uploaded, trashed or shared differ between the state which is before the deletion and the state which is after the restoration. So a violation is characterized by a finite prefix (which goes until the restoration), and this prefix is unrecoverable. Thus, restore_undoes_delete is a safety property.

Now, let us consider the property non_restored_files_will_disappear, which states that every file that is deleted and never again restored will eventually disappear.




assert non_restored_files_will_disappear {

  all f : File | always (

    delete[f] and after always not restore[f] implies

      eventually f not in uploaded

  )

}






Let us again consider a possible scenario that violates this property. This would be a trace where a file is deleted, never restored and present in uploaded forever. If you observe such a trace, the only way to be convinced that it violates the property is to inspect the whole infinite trace. Thus, non_restored_files_will_disappear is a liveness property. Note that inspecting infinite traces is feasible because in Alloy they are represented as finite “lasso traces”, where at some point we have a loop back to a previous state.

Notice that some properties are neither safety nor liveness properties. For these properties, some violations are characterized by an unrecoverable prefix, and some other violations are only characterized by a full infinite trace. In other words, they have both safety and liveness aspects. An interesting result, called decomposition theorem [IPL14], states that any property is the conjunction of a safety property and a liveness property.

The distinction between safety and liveness properties has a direct impact on the activity of the Alloy user when it comes to verification. Indeed, as already explained in chapter Behavioral modeling, verifying a safety property can be done directly using the check command whereas verifying a liveness property requires additional assumptions, called fairness assumptions, which are in charge of imposing a kind of progress of the system.

Further reading

Inductive invariants

Fairness properties

Let us look at the verification of non_restored_files_will_disappear. In order to satisfy it, we need to assume that the system periodically empties the trash to free up resources. In the real system, this would probably be implemented using some kind of timer. This assumption is specified with the fact fairness_on_empty in chapter Behavioral modeling.




fact fairness_on_empty {

  always eventually empty

}






A first remark is that this fairness assumption is imposed for all the traces of the system. So even for the verification of safety properties the solver has to take them into account, which can slow down the verification procedure significantly. To overcome this issue, a good practice is to define a fairness assumption in a predicate so that it is only considered for the verification of the liveness property.




pred fairness_on_empty {

  always eventually empty

}

pred non_restored_files_will_disappear {

  all f : File | always (

    delete[f] and after always not restore[f] implies

      eventually f not in uploaded

  )

}






Then, you can check non_restored_files_will_disappear under the fairness assumption.




check non_restored_files_will_disappear_fair {

  fairness_on_empty implies non_restored_files_will_disappear

}






Another remark is that, with a slightly different system, we would need a different fairness assumption. Indeed, let us consider a different version of the action empty, such that it can only occur if some file is in the trash. This corresponds to what is implemented in most software desktops managers, where you cannot empty the trash if it is already empty.




pred empty {

  some trashed // guard

  no trashed' // effect on trashed

  uploaded' = uploaded - trashed // effect on uploaded

  shared' = shared // no effect on shared

}






With this version of empty, the assumption always eventually empty does not make sense anymore. Indeed, this would impose a constraint on the user behavior: the user has to upload and delete a file an infinite number of times. However, we still need a fairness assumption in order to satisfy non_restored_files_will_disappear. A relevant one is to require empty to eventually occur if at some point it becomes continuously enabled. Like the first fairness assumption, this one could be implemented using some kind of timer, which would start when a file is put in the trash. In fact, it corresponds to a common type of fairness called weak fairness, whereas the first fairness assumption that we used corresponds to a so-called unconditional fairness assumption.




pred weak_fairness_on_empty {

  always (

    always some trashed implies

      eventually empty

  )

}






Let us notice that we have specified the fact that empty is enabled by some trashed, which is the guard of event predicate empty. Most of the time, the guard of an action is indeed equivalent to its enabled condition but it is not true in general. Besides, extracting the guard of an action may be more than extracting one conjunct from the body of the action. For instance, if the body of an action is inside a quantifier some x : E | … then the enabled condition should check for the non-emptiness of E, that is, it should include condition some E.

So, you can now check non_restored_files_will_disappear under the weak fairness assumption.




check non_restored_files_will_disappear_fair {

  weak_fairness_on_empty implies non_restored_files_will_disappear

}






There exists another common kind of fairness assumption called strong fairness. In the context of our file sharing app, we could illustrate it as follows. Suppose that we wanted the system to prevent files to be repeatedly put in the trash and restored again, without the trash being emptied. Such an assumption could be abstracted by the following specification.




pred strong_fairness_on_empty {

  (always eventually some trashed)

    implies always eventually empty

}






Of course, non_restored_files_will_disappear, which is true under the weak fairness assumption, is also true under strong and unconditional fairness assumptions, which are both stronger than weak fairness. So our strong fairness assumption is not needed in the process of verifying non_restored_files_will_disappear.

A natural question is then: what is the interest of strong fairness? In fact, although it is not needed to verify this particular liveness property, the strong fairness assumption is can still be useful as a requirement, if for some reason, the specifier of the system wants to prevent any delete-restore loop without an occurrence of empty. Besides, for other systems, it happens that some expected liveness properties do not hold under a weak fairness assumption, and might require stronger fairness.

Assuming that we have an action A and that predicate enabled[A] specifies when A is enabled, the following table summarizes how the three kinds of fairness can be expressed. We recall that most of the time enabled[A] can be expressed by the guard of A.





	Type of fairness

	Corresponding specification




	Unconditional fairness

	always eventually A




	Strong fairness

	(always eventually enabled[A]) implies always eventually A




	Weak fairness

	always ((always enabled[A]) implies always eventually A)








You can find a more detailed discussion about fairness properties in the literature [FAC94], [TCS91], [TOPLAS94].

Inductive invariants

An invariant is a state property (that is, one that only depends on one state) that is true in every state of every trace. In terms of temporal logic, we can assert an invariant by putting the state property under an always connective, as was done for shared_are_accessible in the file sharing model.




assert shared_are_accessible {

  always shared.Token in uploaded - trashed

}






Now suppose we want to check shared_are_accessible for an unbounded number of steps and an overall scope of 10.




check shared_are_accessible for 10 but 1.. steps






On a recent computer, this verification already takes a couple of minutes and this verification time would grow quickly if we increased the scope.

[image: ../../../../_images/log1.png] 

Is there an alternative, more efficient way to verify this invariant?


Verification by induction

Actually we could try to verify this property by induction, that is by showing that:


	initiation: the property holds in the initial state.


	preservation: the property is preserved by all events, that is, given a state satisfying the property, any possible following state also satisfies the property.




These conditions are particularly interesting because one only has to consider a scope of one (resp. two) state for verifying the first (resp. second) condition, rather than considering a whole trace of unbounded length as in the shared_are_accessible assertion shown above.

To be able to check these two conditions, we must first ensure that the initial state and events are not stated as facts, as facts may remove important behaviors. This requires a very small refactoring of the model:


	we change the init fact into a predicate;


	we also change the transitions fact into a predicate;


	we extract into a next predicate the formula inside the outermost always of transitions.







pred init {

  // Initially there are no files uploaded nor shared

  no uploaded

  no shared

}



pred next {

  (some f : File | upload[f] or delete[f] or restore[f]) or

  (some f : File, t : Token | share[f, t]) or

  (some t : Token | download[t]) or

  empty or

  stutter

}



pred traces {

  init

  always next

}






The traces predicate will be of no use for our verification by induction but it must still be used as a premise in normal temporal assertions to restrict the verification to valid traces. For instance, shared_are_accessible should be rewritten as follows.




assert shared_are_accessible {

  traces implies always shared.Token in uploaded - trashed

}






Moreover, fairness constraint fairness_on_empty should also be moved from a fact into a predicate and called when needed in the liveness assertion.

Let us now come back to our verification by induction. First we specify our tentative invariant as a predicate.




pred inv_shared_are_accessible {

  shared.Token in uploaded - trashed

}






Then we assert the conditions for initiation and preservation. In the first case, we say that init implies the invariant; in the second case, invariant preservation means that, in every state that satisfies the invariant, if an event happens, then any following state also satisfies the invariant.




assert init_inv_shared_are_accessible {

  init implies inv_shared_are_accessible

}



assert pres_inv_shared_are_accessible {

  (inv_shared_are_accessible and next) implies

    after inv_shared_are_accessible

}






As explained above, an interesting aspect of this verification technique is that we can focus on traces of length 1 for init_inv_shared_are_accessible and 2 for pres_inv_shared_are_accessible (incidentally, it allows us to rely on a bounded solver, if needed).




check init_inv_shared_are_accessible for 10 but 1 steps

check pres_inv_shared_are_accessible for 10 but 2 steps






Checking both these assertions yields no counterexample, thus establishing that the property is indeed an invariant (up to the given scope of files and tokens, of course). Due to the use of the induction principle, such an invariant is called an inductive invariant.

Verifying this inductive invariant took less than a second on a normal computer, more than 100 times faster than the original check! This gain in speed is interesting as it could allow us to consider larger scopes for signatures, thus increasing our confidence in the correctness of the property.

[image: ../../../../_images/log2.png] 

Non-inductive invariants

At this point you might ask: why not check all (supposed) invariants using this method?

Before addressing this question, let us remark that we had to refactor our model to apply the induction principle. One may argue that the resulting model, if still readable, is a little convoluted with respect to the original version, in particular because every temporal assertion should be preceded by the traces premise. Admittedly, it might be considered a low price to pay considering the apparent added value.

A more important issue, however, is that not all invariants are inductive. Consider, for example, the alternative inv_shared_are_uploaded property that says that all shared files are uploaded.




pred inv_shared_are_uploaded {

  shared.Token in uploaded

}






Obviously, since inv_shared_are_uploaded is a weakened variation of property inv_shared_are_accessible, it is also an invariant of this model, as the command below confirms.




assert shared_are_uploaded {

  traces implies always inv_shared_are_uploaded

}

check shared_are_uploaded for 10 but 1.. steps






But if we proceed to check that inv_shared_are_uploaded is an inductive invariant, then command pres_inv_shared_are_uploaded yields a counterexample.




assert init_inv_shared_are_uploaded {

  init implies inv_shared_are_uploaded

}

check init_inv_shared_are_uploaded for 10 but 1 steps



assert pres_inv_shared_are_uploaded {

  (inv_shared_are_uploaded and next) implies

    after inv_shared_are_uploaded

}

check pres_inv_shared_are_uploaded for 10 but 2 steps






For the sake of readability, we replay the command but with a scope of 1, which also yields a (smaller) counterexample.




check pres_inv_shared_are_uploaded for 1 but 2 steps






[image: Get the code to generate this instance.]

In this counterexample, there is a shared file in the trash in the first states, which is then no longer uploaded after the trash is emptied. The first state satisfies pres_inv_shared_are_uploaded and the second one does not. It might seem contradictory, as we already know that inv_shared_are_uploaded is an invariant. But, after close inspection, it actually appears that these two states are unreachable, that is they do not exist in any possible valid trace: once a file is deleted, it can no longer be shared. This could be confirmed by writing an adequate run command. However, this is in general a bad idea as the command would run for a long time, (because of the absence of a satisfying instance), thus defeating the purpose of using this inductive approach.

What this example illustrates is that this method of verification does not only consider states appearing in all possible traces but also any other state that satisfies the tentative inductive invariant and that has a successor through next. This is why getting a counterexample when checking pres_inv_shared_are_uploaded does not contradict the fact that inv_shared_are_uploaded is an invariant of our model: the former property concerns states related by the next predicate (even unreachable ones), while the latter only concerns reachable states according to traces.

Invariant strengthening

Although inv_shared_are_uploaded is not inductive, it does not mean that we cannot rely on the inductive invariant method and can only resort to checking the temporal constraint shared_are_uploaded. Alternatively, a way to check that an invariant such as inv_shared_are_uploaded holds is to exhibit another invariant that is inductive and that is stronger than the former (that is, it implies it). Indeed, since the stronger invariant is inductive, it holds in every reachable state, and since it implies the original invariant, the latter also necessarily holds in every reachable state.

In our case, we already have an invariant known to be inductive at our disposal: inv_shared_are_accessible. We are therefore only left with confirming that it is stronger than inv_shared_are_uploaded:




assert accessible_is_uploaded {

  inv_shared_are_accessible implies inv_shared_are_uploaded

}

check accessible_is_uploaded for 10 but 1 steps






This obviously succeeds. However, in general, finding inductive invariants is notoriously hard. For this reason, although it might be less efficient, using a temporal constraint such as shared_are_accessible to check an invariant is a relevant approach, at least as a first step.

Sequences

Consider the file sharing example from chapter Behavioral modeling and suppose we wanted restore to recover from the trash bin the last file that was deleted, instead of a specific file selected by the user. To allow this, trashed can no longer be modelled just by a subset of File. At an abstract level trashed should now be a stack operating under the last in first out principle. We could model such a stack in many different ways in Alloy, for example by using a binary relation that, given a file in the trash bin, gives us the next oldest file. Fortunately, Alloy has native support for sequences, so we can also use one of those to model the trash.




Declaring sequences

Sequences can only be used in fields, meaning they must be used as signature attributes. To declare an attribute that is a sequence, the keyword seq must be used, followed by the signature whose atoms can be contained in it. In our example, we want trashed to be of type seq File, the sequence of files in the trash bin, sorted from oldest to newest. Since trashed must be an attribute of some signature, we will declare a singleton signature Trash whose only purposed is to contain trashed. Of course, we want trashed to still be mutable, so our declarations will look as follows.




sig Token {}



sig File {

  var shared : set Token

}

var sig uploaded in File {}



one sig Trash {

  var trashed : seq uploaded

}

The util/sequniv module


	When sequences are declared in a model, the standard module util/sequniv is automatically imported. This module contains many useful functions and predicates to work with sequences, namely:

	

	elems, a function that given a sequence returns the set of elements contained in it.


	isEmpty, a predicate that checks if a sequence is empty.


	first and last, functions that given a sequence return its first and last element, respectively (or none if the sequence is empty).


	rest and butlast, functions that given a sequence return a new sequence without its first or last elements, respectively.


	add, a function that given a sequence and an element, returns a new sequence with that element appended at the end.


	insert and delete, functions that allow insertion or deletion of elements at specific positions in a sequence.


	hasDups, a predicate that checks if a sequence has duplicates.








In this module we can also see that a seq A is implemented using a binary relation of type seq/Int -> A, where seq/Int is a subset of Int containing only a prefix of the non-negative integers (starting at 0). All sequences are guaranteed to range over a prefix of the non-negative integers, for example sequence [x,y,z] is implemented by binary relation {(0,x),(1,y),(2,z)}, and if we apply rest to this sequence we obtain {(0,y),(1,z)}. This means that we can also use the standard relational operators with sequences, for example to check if a sequence S is empty we could use no S, and to obtain the set of its elements we could use seq/Int.S. However, here we will mainly use the util/sequniv functions to manipulate sequences.

It is also important to know that we can control the size of seq/Int by setting a scope for seq in the analysis commands. The default scope for seq is 4, meaning that sequences can have at most 4 elements. In this case, if a sequence already contains 4 elements and we try to add another element, the same sequence will be returned, so we should be careful about setting a scope for seq that is enough for our application (or specify the desired behavior when a sequence is full). In our example, it suffices that the scope of seq is at least as big as the scope of File, because the same file cannot deleted again when it is already in the trash bin. We should also be aware that, since seq/Int is a subset of Int, the scope of the later must be big enough to accommodate the former. For example, if we run the command run {} for 3 but 5 seq, 3 Int we will get an error stating that the scope of Int is not big enough to accommodate the desired scope for seq, because with 3 bits we can only represent integers from -4 to 3, which is not enough to compute the maximum size of sequences, which in this case would be 5.

Further reading

Working with integers

Sequences are defined using relations from integers indexes to values. Learn how to work with integers in Alloy.

Working with integers



Replacing sets with sequences

Most action predicates in our model must be changed to reflect the change in the declaration of trashed. For example, the empty action predicate was previously specified as follows.




pred empty {

  no trashed' // effect on trashed

  uploaded' = uploaded - trashed // effect on uploaded

  shared' = shared // no effect on shared

}






Since now trashed is in fact a ternary relation of type Trash -> seq/Int -> File, the guard and effect condition on trashed using cardinality checks would still work, but we will instead use the util/sequniv function isEmpty applied to Trash.trashed. However, the effect on uploaded would not work, and would raise a type error due to incompatible types. To determine the set of elements in the trash bin we should now use elems[Trash.trashed]. The updated specification of empty would be as follows.




pred empty {

  isEmpty[Trash.trashed'] // effect on trashed

  uploaded' = uploaded - elems[Trash.trashed] // effect on uploaded

  shared' = shared // no effect on shared

}






The most relevant changes are, of course, in the delete and restore action predicates. The former should add the deleted file to the end of the trashed sequence, and the latter no longer is parametrized by the file to be restored and should instead recover the last file of trashed.




pred delete [f : File] {

  f in uploaded - elems[Trash.trashed] // guard

  Trash.trashed' = add[Trash.trashed, f] // effect on trashed

  shared' = shared - f->Token // effect on shared

  uploaded' = uploaded // no effect on uploaded

}



pred restore {

  not isEmpty[Trash.trashed] // guard

  Trash.trashed' = butlast[Trash.trashed] // effect on trashed

  uploaded' = uploaded // no effect on uploaded

  shared' = shared // no effect on shared

}






To see how sequences are visualized by the Analyzer, let us ask for instances where eventually there are two deleted files in the trash. This can be achieved with the following command using the elems function.




run two_deleted {

  eventually some disj f0, f1 : File | f0 + f1 in elems[Trash.trashed]

}






The following is a possibly returned instance where two files are uploaded and then deleted in sequence. Only the transition corresponding to the last deletion is depicted. Notice that, since trashed is a ternary relation of type Trash -> seq/Int -> File, indexes appear as labels in the edges of trashed. Also, notice how the last deleted file is added to the end of the sequence, at index 1.

[image: Get the code to generate this instance.]

The change of trashed to a sequence has no significant impact in the specification of the assertions we checked in the original version, and only some minor and trivial changes are required. For example, to check that all shared files are not in the trash we should use the following assertion, where we just replaced trashed by elems[Trash.trashed].




assert shared_are_accessible {

  always shared.Token in uploaded - elems[Trash.trashed]

}






To see an example where the change might not be so trivial, consider the valid assertion that delete undoes restore, which in the original model could have been specified as follows.




assert delete_undoes_restore {

  all f : File | always (

    restore[f] and after delete[f] implies

      uploaded'' = uploaded and trashed'' = trashed and shared'' = shared

  )

}

check delete_undoes_restore






Since now restore has no parameters, we need to identify the file being restored by explicitly checking that it is the last of trashed, as follows.




assert delete_undoes_restore {

  all f : File | always (

    f = last[Trash.trashed] and restore and after delete[f] implies

      uploaded'' = uploaded and trashed'' = trashed and shared'' = shared

  )

}

check delete_undoes_restore






In this version with sequences we can also add a new assertion that checks that indeed the trash bin never contains duplicate files (which was trivial true in the original model, since trashed was a set).




assert no_duplicates_in_trash {

   always not hasDups[Trash.trashed]

}

check no_duplicates_in_trash

Higher-arity relations

Since sequences are ternary relations, they can be treated as any n-ary relation. Learn more about these higher-arity relations.

Protocol design

In this chapter we will explain how to specify and analyze a distributed protocol using Alloy. We will use a very simple example of a leader election protocol. The aim of a leader election protocol is to designate one node in a network as the organizer or leader of some distributed task. Nodes are initially unaware of which node will play that role, but after running the protocol all nodes should recognize the same node as leader. Many leader election protocols exist: here we will use a well-known version that can be used to elect a leader in a network of nodes organized in a ring, and where nodes also have unique comparable identifiers.

This protocol was proposed by Chang and Roberts [CACM79] and roughly operates as follows: the goal is to elect as leader the node with the highest identifier; each node starts by sending its own identifier to its successor in the ring; upon receiving an identifier, a node only forwards it if it is higher than its own; a node receiving back its own identifier designates itself as leader; finally the leader broadcasts its newly found role to the network. In our specification we will start by omitting this last phase of the protocol and will only be concerned with the fundamental property of a leader election protocol: eventually exactly one node will designate itself as the leader.


Specifying the network configuration

When designing a distributed protocol, we should start by specifying the network configurations in which it is supposed to operate. In this case, the protocol operates in a ring network of nodes with unique identifiers. Notice that many network configurations satisfy this requirement: we could have rings of different size, and for the same size, different assignments of the unique identifiers to the nodes (the relevant fact here is the relative order in which the identifiers appear in the network). The verification of the expected properties of the protocol should take into account all possible different configurations (up to the specified bound on the ring size). The network configuration, although arbitrary, does not change during the execution of the protocol. As such, it will be specified with immutable signatures and fields.

Unlike some formal specification languages, Alloy has no pre-defined notion of process or node. These have to be explicitly specified, by declaring a signature. Since the network of nodes forms a ring, a binary relation that associates each node with its immediate successor in the ring should also be declared.




sig Node {

  succ : one Node

}






Recall that binary relations should be declared as fields inside the domain signature. In the declaration of field succ the multiplicity one is used to ensure that each node has exactly one successor in the ring. As usual in Alloy, we can immediately start validating our specification by inspecting possible instances generated using a run command.




run example {}






By iterating over the returned instances with New we could get the following instance, which is of course not a valid ring.

[image: Get the code to generate this instance.]

In addition to requiring each node to have exactly one successor, a simple way to ensure that a network forms a ring is to require that every node is reachable from any other node. Given a node n, to determine the set of nodes reachable from n via relation succ we can use expression n.^succ. This expression makes use of the composition (.) and transitive closure (^) operators already presented in the Structural modeling chapter. The constraint that succ forms a ring can thus be specified in a fact as follows.




fact ring {

  // succ forms a ring

  all n, m : Node | m in n.^succ

}






An alternative specification of fact ring is to require that the set of all nodes (denoted by Node) is reachable from every node.




fact ring {

  // succ forms a ring

  all n : Node | Node in n.^succ

}






If we now iterate over all instances returned by command example we will get the 3 possible rings with up to 3 nodes and a configuration without any node, which is also allowed by our specification. The limit of 3 is due to the implicit command scope of 3 atoms per top-level signature. As an example we show the ring with 3 nodes.

[image: Get the code to generate this instance.]

To enforce that we have at least one node that can be elected we can add the following fact.




fact some_node {

  // at least one node

  some Node

}






Besides being organized in a ring, nodes must also have unique identifiers. Since we are going to need to compare identifiers, one possibility would be to just use integers to represent them. However, besides being totally ordered, integers carry additional semantics that is not necessary here. In particular, integers support arithmetic operations that will not be required in this example. When developing a formal specification it is good practice to be as abstract as possible and use the simplest structure that fulfills our needs. Also, the analysis of Alloy specifications with integers has some subtleties which makes it better to avoid, unless strictly necessary. As such, we will introduce a signature Id, to denote identifiers, and declare that this signature is totally ordered using a call to module util/ordering at the top of the file. Doing so implicitly extends the model with a binary relation next that given an identifier will yield the next identifier in the total order, two singleton signatures to denote the first and last identifiers of the order, and a binary predicate gt to compare if the first argument is greater than the second. All identifiers but one (the last) have a next.




open util/ordering[Id]



sig Id {}






Having our identifiers totally ordered, we can now declare a field id inside signature Node, to associate each node with its identifier.




sig Node {

  succ : one Node,

  id : one Id

}






To ensure that identifiers are unique it suffices to require id to be injective, which can be done as follows.




fact unique_ids {

  // ids are unique

  all i : Id | lone id.i

}






If we can now create a new example3 command to ask for all configurations with exactly 3 nodes and 3 identifiers, as follows.




run example3 {} for exactly 3 Node, exactly 3 Id






Setting an exact scope over identifiers is actually redundant because util/ordering always imposes an exact scope. If we iterate over all instances with New, we will get the two only (truly) different configurations with this scope: one where the identifiers increase as we move forward in the ring, and another where they decrease. The latter is depicted below (notice the next, prev, first and last elements introduced by util/ordering). This illustrates the power of Alloy’s symmetry breaking, which in this case prevents the return of any other instance (that necessarily would be isomorphic to one of these two).

[image: Get the code to generate this instance.]

Specifying the protocol dynamics

The coordination between the different nodes in this distributed protocol, like in many others, is achieved by means of message passing. Again, likewise for nodes, Alloy has no special support for message passing, so all the relevant concepts have to be specified from scratch. In this phase of the protocol messages are just node identifiers, so there is no need to add a signature to model those, and we can use signature Id directly to represent messages. To capture the incoming and outgoing messages we can declare mutable binary fields inside signature Node, to associate each node with the set of identifiers it has received or that need to be sent, respectively. Using sets for the mailboxes is an abstraction that allows us to verify that the protocol is correct even if messages are transmitted out of order. In this protocol the same message is never sent twice by each node, so we also don’t need to account for multiple copies of the same message. As we have seen in the Behavioral modeling chapter, to declare a mutable field the keyword var should be used.




sig Node {

  succ : one Node,

  id : one Id,

  var inbox : set Id,

  var outbox : set Id

}






We also need to distinguish the nodes that have been elected as leaders. To do so we can declare a mutable signature Elected that is a subset of Node.




var sig Elected in Node {}






Note that, on purpose, we did not impose a multiplicity lone in this declaration, because that constraint, that at most one node is elected leader, is one of the key assertions we will want to verify to be a consequence of the protocol dynamics, and thus should not be imposed as an assumption upfront.

If we now run the example3 command we might get the following instance.

[image: Get the code to generate this instance.]

As we have seen in the Behavioral modeling chapter, the interface of the visualizer is different when we have mutable elements: it now shows two states of a trace side-by-side, there are several new instance exploration buttons in the toolbar, and a depiction of a path just below those. In this case we have a trace where the same state 0 repeats itself indefinitely, something that is possible since so far we added no restrictions that constrain the behavior of the protocol. We recall that in the depiction of the states, by default, immutable sets and fields (the configuration of the protocol) are shown with solid lines, while mutable ones are shown with dashed lines.

To simplify the visualization, we can configure the theme so that node identifiers, the inbox, and the outbox are shown as node attributes, and change the color of elected nodes to green. Since the elected nodes can now be easily distinguished by color we can also hide the respective textual label. As for the totally ordered identifiers, we will just show the next relation. The result of this customization will be the following.

[image: Get the code to generate this instance.]

Something that is clearly wrong in this execution is that in the initial state nodes already have identifiers in their inboxes and outboxes, and some of them are already elected. To restrict the initial value of these mutable fields we can add the following fact.




fact init {

  // initially inbox and outbox are empty

  no inbox and no outbox

  // initially there are no elected nodes

  no Elected

}






Since this fact has no temporal connectives it applies to the initial state of the system. Rerunning the example3 command now yields instances such as the following, where the systems remains indefinitely in a valid initial state.

[image: Get the code to generate this instance.]

We can explore additional instances by using the instance exploration buttons in the toolbar. For example, the New Fork button asks the Analyzer for a different trace with the same behavior up to the left-hand side state, but a different outcome of the current transition (a different right-hand side state). By pressing this button we may get the following.

[image: Get the code to generate this instance.]

This trace displays a behavior that should not be allowed in a correct execution of the protocol: in the second state all of a sudden several identifiers appeared in the inbox and outbox of Node1. Moreover, this node was also randomly designated as leader. So far this is allowed because we added no constraints to our specification that restrict how the system can transition from one state to another. If there are no constraints then any transition is possible.

As already explained in chapter Behavioral modeling, the simplest way to constrain the valid transitions is to consider all the possible events that can occur in the system, and for each event specify when it can occur (its guard) and what is its effect on the mutable relations. In our protocol we can distinguish three possible events:


	a node initiates the execution by sending its own identifier to the next node;


	a node reads and processes an identifier in its inbox, decides whether it should be propagated or discarded and, if it is its own identifier, elects itself as leader;


	the network sends one message in the outbox of a node to the inbox of the next one.




Alloy has no special keywords to declare events. A common approach is to declare a predicate for each event, that specifies its guard and effect, and add a constraint enforcing that at each possible state only one of those predicates can hold. Event predicates can also be parametrized, and in our specification they will be parametrized the node where the event occurs.

Let’s begin by specifying the initiate event. For each event we should always start by specifying what is its guard, a constraint on the current (or pre-) state that determines when can the event occur. To simplify our specification, for the moment, we will assume that a node is free to initiate (or re-initiate) the protocol whenever it wants, so in this case there will be no guard, meaning the event is always possible. Then we should specify the effect of the event on all mutable relations of the specification: note that if nothing is said about a particular mutable relation then its value can change freely when the event occurs. A special effect is forcing the value of a mutable relation to not change at all, something known as a frame condition. For example in this event we will have two frame conditions, since it does not change the value of inbox nor Elected. To specify that a relation does not change with a logic formula we need to refer to its value in the next (or post-) state. In Alloy the value of a relation (or relational expression) in the next state is accessed by appending a prime. So, to state that, for example, the relation inbox does not change we could add the constraint inbox' = inbox. Likewise for Elected. So far, the specification of event initiate looks as follows.




pred initiate_no_effect [n : Node] {

  // node n initiates the protocol



  inbox' = inbox // frame condition on inbox

  Elected' = Elected // frame condition on Elected

}






We now need to specify the effect on relation outbox. We can start by specifying its effect on the outbox of the initiating node. Expression n.outbox denotes the set of identifiers in the outbox of node n in the current state. The effect of this event on this set is to add n’s own identifier, which can be specified by n.outbox' = n.outbox + n.id. Here we used the set union operator + to add the singleton set n.id to n.outbox. Note that requiring n.id to be present in the outbox in the next state, which could be specified by n.id in n.outbox', is not sufficient, as it would allow identifiers other than n.id to be freely removed or added from n.outbox. Having specified the effect on the outbox of n we now need to specify the effect on the outbox of all other nodes. Again, if nothing is said about those, they will be allowed to vary freely. Of course this event should not modify the outboxes of other nodes, something we could specify with constraint all m : Node - n | m.outbox' = m.outbox, that quantifies over all nodes except the initiating one. The final specification of our event looks as follows.




pred initiate_no_guard [n : Node] {

  // node n initiates the protocol



  n.outbox' = n.outbox + n.id // effect on n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes



  inbox' = inbox // frame condition on inbox

  Elected' = Elected // frame condition on Elected

}






To validate our first event we can impose a restriction stating that, for the moment, this is the only event that can occur, and inspect the possible instances to see if the system behaves as expected. To specify such a restriction we need the temporal logic operator always to enforce a formula to be true at all possible states. In particular, to enforce that, at every possible state, one of the nodes initiates the protocol, the following fact can be added to the specification.




fact always_initiate {

  // possible events

  always (some n : Node | initiate_no_guard[n])

}






Running command example3 yields the following trace, where Node2 initiates the protocol and then nothing else happens.

[image: Get the code to generate this instance.]

On first glance, this may seem like an invalid trace, given that we required that at every state one node initiates the protocol. However, if we look closely at our specification of event initiate we can see that it also holds true in a state where a node already has its own identifier in the outbox, which will remain in the outbox. Our specification did not had a guard forbidding this occurrence of the event, and the effect n.outbox' = n.outbox + n.id is also true if n.id is already in n.outbox and in n.outbox'.

To address this issue we could add a guard like n.id not in n.outbox to predicate initiate_no_guard. However, this only forbids a node from initiating the protocol if it’s own identifier is in its outbox at that particular moment. This means that, once we include an event to send messages and this identifier leaves the outbox, a node will be able to re-initiate the protocol. In principle, this does not pose any problem concerning the correctness of this particular protocol, but if we really wanted each node to initiate the protocol only once we would need to strengthen this guard.

One possibility would be to add a field to record at which phase of the protocol execution each node is in, and allow this event only when a node is in an “uninitiated” phase. This would be the common approach in most formal specification languages. However, with Alloy we have a more direct alternative. Since there is no special language to specify events and they are specified by arbitrary logic formulas, we are free to use temporal operators to specify guards or effects. By contrast, in most formal specification languages we can only specify the relation between the pre- and post-state.

In this case we could, for example, use the temporal operator historically, that checks if something was always true in the past up to the current state, to only allow initiate to occur if the node’s identifier was never in its outbox. The specification of our event would look as follows.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically n.id not in n.outbox // guard



  n.outbox' = n.outbox + n.id // effect on n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes



  inbox' = inbox // frame condition on inbox

  Elected' = Elected // frame condition on Elected

}






Unfortunately, after adding this guard our command will return no trace, meaning there are no behaviors that satisfy our constraints. This happens because we are currently not allowing messages to be sent or read, so after all nodes have initiated the protocol nothing else is allowed to happen by our specification, and it is impossible to obtain a valid trace. Recall that traces are infinite sequences of states. A simple way to solve this issue is to add an event allowing the system to stutter, that is to do nothing (keeping the value of all relations unchanged). Stuttering can also be understood as an event specifying something else that is occurring on the environment outside the scope of our specification, and in general it is a good idea to add such stuttering events. In this case, a predicate to specify a stuttering event can be specified as follows.




pred stutter {

  // no node acts



  outbox' = outbox

  inbox' = inbox

  Elected' = Elected

}






To allow this event we need to change the above fact that restricts the possible behaviors.




fact stutter_or_initiate {

  // possible events

  always (stutter or some n : Node | initiate[n])

}






Running command example3 returns a trace where nothing happens in our system, something that is now allowed. If we press New Fork we might get a trace such as the previously depicted, where Node2 initiates the protocol and then nothing else happens. If we move to the next state by pressing →, and fork again with New Fork, we might get the following trace where Node0 initiates the protocol after Node2.

[image: Get the code to generate this instance.]

By exploring a bit more the possible traces we can get some confidence that event initiate is well specified.

Let us now specify the send event. In this event we could have as parameters the node n from where the message will be sent and the message i that will be sent (an identifier). The guard of this event should require i to be in the outbox of n. The effect will be to remove i from the outbox of n, and add it to the inbox of the next node n.succ. All other inboxes and outboxes should keep their value, as well as the Elected set. The specification of this event would be the following.




pred send [n : Node, i : Id] {

  // i is sent from node n to its successor



  i in n.outbox // guard



  n.outbox' = n.outbox - i // effect on n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes



  n.succ.inbox' = n.succ.inbox + i // effect on n.succ.inbox

  all m : Node - n.succ | m.inbox' = m.inbox // effect on the inboxes of other nodes



  Elected' = Elected // frame condition on Elected

}






For event process message, again we will have as parameters the node n and the message i to be read and processed. The guard should require that i is in the inbox of n. The effect on inbox is obvious: i should be removed from the inbox of n and all other inboxes should keep their value. The effect on the outbox of n depends on whether i is greater than n.id: if so, i should be added to the outbox, to be later propagated along the ring; if not, it should not be propagated, meaning the outbox of n will keep its value. To write such conditional outcome we could use the logical operator implies together with an else: C implies A else B is the same as (C and A) or (not C and B), but the former is easier to understand. The event has no effect on the outboxes of other nodes, which should all keep their value. The same conditional outcome applies to Elected: if the received i is equal to the n’s own identifier, then n should be included in Elected; otherwise Elected keeps its value. The full specification of process is as follows.




pred process [n : Node, i : Id] {

  // i is read and processed by node n



  i in n.inbox // guard



  n.inbox' = n.inbox - i // effect on n.inbox

  all m : Node - n | m.inbox' = m.inbox // effect on the inboxes of other nodes



  gt[i, n.id] implies n.outbox' = n.outbox + i // effect on n.outbox

              else n.outbox' = n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes



  i = n.id implies Elected' = Elected + n // effect on Elected

           else Elected' = Elected

}






We should now add these two events to the fact that constraints the valid behaviors of our system. We will also factorize all node events into a separate predicate, to later simplify the specification of fairness conditions.




pred node_acts [n : Node] {

  initiate[n] or

  (some i : Id | send[n, i]) or

  (some i : Id | process[n, i])

}



fact events {

  // possible events

  always (stutter or some n : Node | node_acts[n])

}






Before proceeding to the verification of the expected properties of the protocol, we should play around with the different instance exploration buttons to explore different execution scenarios and validate the specification of our events. An alternative would be to ask for specific scenarios directly in a run command. For example, we could change command example to ask directly for a scenario where some node will be elected. To do so we need to use the temporal operator eventually, which checks if a formula is valid at some point in the future (including the present state). Our command would look as follows.




run eventually_elected {

  eventually some Elected

} for exactly 3 Node, exactly 3 Id






Running this command will return a trace with 8 states where the highest identifier is passed around until the respective node gets elected. This is the shortest trace where a leader can be elected in a ring with 3 nodes, corresponding to one initiate event followed by 3 interleaved send and process message events. With the bounded model-checking engine that is used by default, the Analyzer guarantees that the shortest traces that satisfy (or refute) a property are returned first. The first transition of this trace is the following, where the node with the highest identifier (Id2) initiates the protocol.

[image: Get the code to generate this instance.]

In the last transition, that can be focused by pressing → 6 times or by directly clicking the state numbered 6 in the trace depiction, this node reads back its own identifier that was passed around in the ring and elects himself as leader.

[image: Get the code to generate this instance.]

Verifying the expected properties

The key property of our protocol is that exactly one node will become leader. We can break this property into three simpler ones:


	there will never be more than one leader;


	every leader remains leader;


	eventually there will be at least one leader.




These properties are of very different nature: the first two are a safety properties, forbidding some (undesired) behavior of the system, while the latter is a liveness property, forcing some (desirable) behavior of the system. The analysis of safety properties is usually simpler than the analysis of liveness properties. To find a counter-example for a safety property it suffices to search for a finite sequence of states that leads to a (bad) state (in the case of the first property, one state where there are two or more leaders), and it is irrelevant what happens afterwards, as any continuation of this finite sequence will still be a counter-example. On the other hand, to find a counter-example for a liveness property it is necessary to search for a complete infinite trace where the expected behavior definitely never happened (in the case of the last property, one trace where a leader is never elected). Moreover, it will be necessary to impose additional fairness conditions when verifying liveness properties, in particular to forbid unreasonable counter-examples where at some point the system stutters forever and the nodes never execute an enabled event.

Let us start by verifying the first (safety) property. Recall that properties that are expected to hold can be written in named assertions (declared with keyword assert) and then verified with check commands. This safety property is a very simple example of an invariant, a property that requires something to be be true in all states of all possible traces. In Alloy, invariants can be specified using the temporal operator always. In each state, to check that there is at most one leader in set Elected we could use the keyword lone. This invariant could thus be specified as follows.




assert at_most_one_leader {

  always (lone Elected)

}






To check this assertion we could define the following command.




check at_most_one_leader






This protocol is known to be correct, so, as expected, running this command returns no counter-example. Recall that the default scope on top-level signatures is 3, so this command actually verifies that the property holds for all rings with up to three nodes. This Alloy ability of model checking a property at once for all possible configurations of a system is not possible in some competing model checkers, where we are forced to specify the specific configuration on which we want to verify a protocol. That is rather cumbersome, since with a reasonable scope there can be many different configurations and its difficult to even enumerate them manually. Also, we could easily miss a bug in a specific configuration.

As mentioned in chapter Behavioral modeling, by default, verification of temporal properties in Alloy is done with a technique known as bounded model checking, meaning that the search for counter-examples will only consider a given maximum number of different transitions before the system starts exhibiting a repeated behavior. By default this maximum number is 10. To increase our confidence in the result of the analysis we could, for example, check this property for all rings with up to 4 nodes and consider up to 20 different transitions (or steps). To do so we could change the scope of the command as follows.




check at_most_one_leader for 4 but 20 steps






This commands sets the default scope on signatures to 4 but also changes the scope on transitions to 20 using keyword steps. Again, as expected, no counter-example is returned, but the analysis now takes considerably longer, as there are many more network configurations and states to explore.

It is also possible to check a temporal property with complete model checking if a compatible solver is selected. This will consider an arbitrary number of transitions, but still with the signatures bounded by a maximum scope. To do so, a special scope on steps is needed to trigger unbounded temporal analysis.




check at_most_one_leader for 4 but 1.. steps






The second expected property is another example of a safety property, this time requiring a nested always operator to be specified.




assert leader_stays_leader {

  always (all n : Elected | always n in Elected)

}

check leader_stays_leader






Again this assertion is true, as expected. Note that the universal quantification on Elected could not be moved outside the first always, because Elected is a mutable subset signature, and if used outside any temporal connective it will be evaluated in the initial state, where it is empty. Of course, that is not what we want. Here we check that Elected never decreases in content, that is, at every state any node that it contains will remain in Elected for ever. Combined with at_most_one_leader this ensures that there can never exist two different leaders.

The third expected property is a very simple example of a liveness requirement, namely one that requires something to hold at least in one state of every trace. In this case we want to make sure that at least one node will be elected. Simple liveness properties such as this one can many times be specified directly with the temporal connective eventually. Inside this temporal connective, again a very simple cardinality check on Elected suffices, this time with keyword some.




assert at_least_one_leader {

  eventually (some Elected)

}






The following command can be used to check this property with bounded model checking and the default scopes.




check at_least_one_leader






We recommend that you start by verifying specifications with bounded model checking, because for small scopes on steps it is usually much faster than the unbounded counterpart, and most counter-examples tend to require only a handful of transitions. Once you have a design where no counter-example is returned with bounded model checking, you can increase your confidence on the analysis by using unbounded model checking. As hinted above, running this command immediately returns a counter-example where the system stutters forever, and obviously no leader is elected. This counter-example can be replicated in trivial configurations, for example the following with a single node.

[image: Get the code to generate this instance.]

This behavior is currently allowed because we added a stutter event that captures events external to our system. At the moment this event can occur indefinitely, which is a bit unrealistic or unfair to the system under analysis: in particular, if at some point one node is continuously ready to execute one of its events (the node is continuously enabled), then it should eventually do something. For example, in our protocol, a trace where at some point a message is in the inbox of a node but is never processed is unfair to that node.

To specify fairness properties that exclude such unreasonable executions, we first need to understand two well-known combinations of the always and eventually temporal operators:


	eventually always P holds in a system if all traces reach a state where P becomes valid indefinitely.


	always eventually P holds in a system if in every state of every trace P is later valid, which means that P is true infinitely often.




To specify that a node is at some point continuously enabled we can use the first combination. Most of the times the enabled condition for a node is exactly the same as the disjunction of the guards of its events. In our case a node n is enabled if it has never initiated or has some message in the inbox or in the outbox. To specify that a continuously enabled event eventually occurs (after the point it becomes enabled) the second combination of operators presented above can be used. Note that a continuously enabled event would still be (continuously) enabled after the required occurrence of the event, which means that the event should occur again and again, or infinitely often. So, the desired fairness condition can be specified as follows.




pred initiate_enabled [n : Node] {

  historically n.id not in n.outbox

}

pred process_enabled [n : Node, i : Id] {

  some n.inbox

}

pred send_enabled [n : Node, i : Id] {

  some n.outbox

}

pred node_enabled [n : Node] {

  initiate_enabled[n] or

  (some i : Id | process_enabled[n, i]) or

  (some i : Id | send_enabled[n, i])

}



pred fairness {

  all n : Node {

    eventually always node_enabled[n]

    implies

    always eventually node_acts[n]

  }

}






Here we specified separately the enabled conditions for each of the events. Technically, this fairness condition is known as weak fairness, as a node is only required to act if is continuously enabled. Often this suffices to verify most liveness properties. However, sometimes we may need strong fairness constraints, requiring that some event occurs when it becomes recurrently enabled (infinitely often, but not necessarily continuously).

If we change the at_least_one_leader assertion to assume the above fairness condition, no counter-example will be returned even with increased scopes, as expected.




assert at_least_one_leader_fair {

  fairness implies eventually (some Elected)

}

check at_least_one_leader_fair

Making the specification more abstract

There are several ways in which we can make our specification of this protocol more abstract, and potentially speed up its analysis. For example, we actually do not need to model the identifiers explicitly: we can use each node atom name as its own identifier. To model this, we could impose the total order on Node itself, and get rid of signature Id and field id. Also, messages are now the node atoms, and the declaration of inbox and outbox should change accordingly. However, imposing a total order with util/ordering will make the scope on Node exact, which means that for a given scope we would only verify all configurations with that exact number of nodes. This is undesirable, because we could easily miss bugs for smaller configurations. As such, instead of using util/ordering we will directly impose a total order on the nodes, by explicitly adding a next relation, the first and last nodes, and the corresponding fact.




sig Node {

  next : lone Node,

  succ : one Node,

  var inbox : set Node,

  var outbox : set Node

}

one sig first, last in Node {}



fact ordering {

  no next.first and no last.next

  Node-first in first.^next

}






Actually, in our first model with a separate Id signature and using util/ordering we were verifying some redundant configurations that were symmetric for this protocol. For example, with the default scope of 3, the scope of Id was exactly 3, meaning that even if we had less than 3 nodes, there would still exist 3 identifiers. This means that, for example, for a network of 2 nodes we were analyzing three configurations: one where the identifiers were consecutive starting in the first identifier, one where the identifiers were consecutive starting in the second identifier, and one where the identifiers differed in two units. For this protocol, where we just need to check which identifier is greater, all these configurations are equivalent, and thus it would be unnecessary to check them all. In this new version without explicit identifiers, we no longer have this issue, and for a scope of 3 only 4 truly different configurations will be analyzed: one network with one node, one with two nodes, and two networks with three nodes, one where next is in the same order of succ and one where it is in reverse order.

Of course, after removing Id we have to slightly change the specification of our event predicates and the assertions. For example, event process can now be specified as follows.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in n.inbox // guard



  n.inbox' = n.inbox - i // effect on n.inbox

  all m : Node - n | m.inbox' = m.inbox // effect on the inboxes of other nodes



  i in n.^next implies n.outbox' = n.outbox + i // effect on n.outbox

               else n.outbox' = n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes



  i = n implies Elected' = Elected + n // effect on Elected

        else Elected' = Elected

}






Note that since we now don’t have the gt predicate available we directly compared nodes using the next relation.

The eventually_elected command now only needs to specify a scope for Node.




run eventually_elected {

  eventually some Elected

} for exactly 3 Node






Running this command yields the following instance (with the theme already customized), and it is now more clear if the ring follows the increasing order of the identifiers (as happens here), or the other way around. Notice that without using util/ordering, the node identifiers are no longer representative of the total order (in the trace below, Node2 is the first element of the total order, and Node1 the last).

[image: Get the code to generate this instance.]

Another signature we can remove is Elected, since actually we can infer which node has been elected by looking at what happened in the past: if at some point in the past a node had its identifier in the inbox and processed it, then it necessarily became a leader. Instead of declaring a subset signature we can define Elected as a derived set of nodes using a function without parameters.




fun Elected : set Node {

  { n : Node | once (before n in n.inbox and n not in n.inbox) }

}






Here, the set of elected nodes at each state is defined by comprehension. Note the usage of the once and before past operators to check if the desired transition happened in the past. We can now simplify the specification of all three events, removing the effects on Elected. For example, event process can now be specified as follows.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in n.inbox // guard



  n.inbox' = n.inbox - i // effect on n.inbox

  all m : Node - n | m.inbox' = m.inbox // effect on the inboxes of other nodes



  i in n.^next implies n.outbox' = n.outbox + i // effect on n.outbox

               else n.outbox' = n.outbox

  all m : Node - n | m.outbox' = m.outbox // effect on the outboxes of other nodes

}






Another abstraction could be to remove the outbox and incorporate the sending of a message in the initiate and process events. This is a reasonable simplification in this protocol, since each node only communicates with the successor node, and out of order message delivery is already being modeled by having the inboxes contain sets of messages. The declaration of signature Node becomes the following.




sig Node {

  next : lone Node,

  succ : one Node,

  var inbox : set Node

}






The specification of event initiate should be changed to directly add the node identifier to the inbox of the successor node.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically n not in n.succ.inbox // guard



  n.succ.inbox' = n.succ.inbox + n // effect on n.succ.inbox

  all m : Node - n.succ | m.inbox' = m.inbox // effect on the outboxes of other nodes

}






Finally, the specification of process should also be changed accordingly.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in n.inbox // guard



  n.inbox' = n.inbox - i // effect on n.inbox

  i in n.^next implies n.succ.inbox' = n.succ.inbox + i // effect on n.succ.inbox

               else n.succ.inbox' = n.succ.inbox

  all m : Node - n - n.succ | m.inbox' = m.inbox // effect on the inboxes of other nodes

}






After removing event send from predicate node_acts, we can run the eventually_elected command and see that it is now possible to elect a leader in a ring with three nodes with almost half the transitions.

[image: Get the code to generate this instance.]

With the same scope on the steps we can now check much longer behaviors with roughly the same efficiency. If we check our three assertions they are all still valid, as expected.

However, this specification is actually not correct! If we run the following command to get an example of electing a leader in a ring with one node, we will get no instances.




run eventually_elected_1node {

  eventually some Elected

} for exactly 1 Node






The problem is in the specification of the effect of process on n.succ.inbox. If the ring has a single node, both n and n.succ are the same node, and the two conditions specifying the effect on n.succ.inbox and on n.inbox contradict themselves, so the process event cannot actually occur (is not truly enabled) even if its guard is true in a state. This was the reason why checking the at_least_one_leader_fair assertion did not produce a counter-example, because the fairness condition now has the wrong enabledeness condition for this event. It is very easy to make such subtle mistakes while specifying, and introduce inconsistencies in our model, and to avoid them we should always exhaustively validate our specification before checking our assertions. This is specially true for liveness properties. Ideally, we should have different run commands to check the consistency of different scenarios, for instance asking for examples where leaders are elected in rings of different sizes. To fix the specification of process we could require the frame condition on n.succ.inbox to only apply when n.succ is not n itself.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in n.inbox // guard



  n.inbox' = n.inbox - i // effect on n.inbox

  i in n.^next implies n.succ.inbox' = n.succ.inbox + i // effect on n.succ.inbox

               else n.succ != n implies n.succ.inbox' = n.succ.inbox

  all m : Node - n - n.succ | m.inbox' = m.inbox // effect on the inboxes of other nodes

}






If we ask for a trace where a leader is elected in a ring with one node, we now get the expected outcome after two events.

[image: Get the code to generate this instance.] [image: Get the code to generate this instance.]

So far we have specified the effects of events in a point-wise style, stating the effect on different projections of the inbox separately. Using a point-free style, where we specify the effect on all inboxes at once, can many times considerably simplify the specification. Consider for example the point-free version of the initiate event.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically n not in n.succ.inbox // guard



  inbox' = inbox + n.succ->n // effect on inbox

}






Now we just specify in a single constraint that the binary relation inbox should have a new tuple in the next state, namely one where n was added to the inbox of n.succ.

For process specifying the effect on the all inbox in a single constraint is a bit more challenging, but could be done as follows.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in n.inbox // guard



  inbox' = inbox - n->i + n.succ->(i & n.^next) // effect on inbox

}






In the next state, binary relation inbox should have one less tuple, corresponding to deleting i from the inbox of n, and, if i in n.^next one more tuple, corresponding to adding i to the inbox of n.succ. This last conditional addition was specified by always adding tuple n.succ->(i & n.^next) to inbox: note that expression i & n.^next is equal to i if i in n.^next or none otherwise, hence in the latter case no tuple will be added since the Cartesian product with an empty set is also an empty binary relation.

Explicit messages as signatures

Up until now, we only specified the first phase of the leader election protocol. In a second phase, once a node identifies itself as the leader, it should propagate that information to all the other nodes to make sure that every node is aware of the elected leader. This second phase can begin while there are still messages from the first phase being exchanged. A message informing about the newly elected leader contains the payload exchanged in the first phase: a node identifier, in this case of the elected leader instead of candidate. Thus, we can no longer abstract messages by just exchanging identifiers between nodes, and must introduce a richer message type into our model to distinguish between the messages exchanged in the two phases of the protocol. In a programming language we would probably encode messages using a record, or struct type. In Alloy such records can to be encoded with signatures, but that causes some issues that will be discussed in this section.

We can easily extend our model to support different types of messages by introducing an abstract static signature to represent them, and then extend it by the more specific message types. Signature fields would represent the payload or data fields of the messages. In our leader election protocol, we have two message types that happen to contain the same payload – a node identifier – so we can define that field at the top-level signature, which will be inherited by the specific CandidateMsg and ElectedMsg. The payload is mandatory, so it is assigned multiplicity one.




abstract sig Message {

  payload : one Node

}

sig CandidateMsg, ElectedMsg extends Message {}






Then we need to adapt the inbox declaration to contain the new messages instead of just node identifiers.




sig Node {

  next : lone Node,

  succ : one Node,

  var inbox : set Message

}






Next, we must adapt the event predicates to consider the new message types. Some of these events (such as when a node initiates, or elects itself the leader) are expected to ‘create’ new messages. This will expose a main difference between having true record-like data structures and Alloy static signatures: with the latter, messages will in fact never really be created, since all possible messages that can be sent in an execution already belong to signature Message in the initial state. The ‘creation’ of a new message will be specified by an existential quantification that searches for an atom inside Message with the required type and content. Predicate initiate, for instance, could be adapted in the following way.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically no CandidateMsg & payload.n & n.succ.inbox // guard



  some m : CandidateMsg & payload.n | inbox' = inbox + n.succ->m // effect on inbox

}






The first difference to our previous specification is in the guard: rather than testing whether its own identifier has ever been in the inbox of its successor, a node can now only initiate if a candidate message with its identifier was never in that inbox. Note that for a node identifier n, payload.n retrieves all messages with that identifier, which intersected with CandidateMsg gives all candidate messages for node n (in the current model, there may be multiple CandidateMsg atoms with the same payload). The second difference, as we already mentioned, is the use of an existential quantification in the effect to pick a message of the appropriate type and content to be added it to the successor’s inbox.

Rather than having an identifier as a parameter, the process event should now consider a message. To ease the specification, we split the process event into two different events specified in different predicates: processing a CandidateMsg message or processing an ElectedMsg message. Predicate processCandidate becomes slightly more complicated, since there are now three possible effects on the successor’s inbox: as previously, a node receiving a candidate message may discard it (if the identifier in the message is smaller than its own), or propagate it (if the identifier in the message is larger than its own). But now, when a node identifies itself as the leader (the identifier in the message is the same as its own), it must also send a new elected message informing other nodes that it become the leader. One possibility to specify this event is as follows.




pred processCandidate [n : Node, m : CandidateMsg] {

  // candidate message m is read and processed by node n



  m in n.inbox // guard



  m.payload in n.^next implies inbox' = inbox - n->m + n.succ->m // effect on inbox

  else m.payload in ^next.n implies inbox' = inbox - n->m

  else some e : ElectedMsg & payload.n | inbox' = inbox - n->m + n.succ->e

}






Due to the need to send a different type of message in the last case, it is now more difficult to specify the effect in a single case, so we keep the three cases separate.

Predicate processElected is quite simple, just propagating the elected messages unless it’s the elected leader receiving the message again, in which case it is discarded.




pred processElected [n : Node, m : ElectedMsg] {

  // elected message m is read and processed by node n



  m in n.inbox // guard



  m.payload != n implies inbox' = inbox - n->m + n.succ->m // effect on inbox

                 else inbox' = inbox - n->m

}






Concerning Elected, we would now to consider a more interesting version, where we register for each node which other node it considers the leader, if any. As such, we will change Elected to return not the set of elected nodes, but a binary relation that for each node returns the leader it currently knows. A node gets to know who is the leader when it processes an elected message, so the set of leaders for each node is the payload of all previously processed messages of this type. We can define this relation by comprehension, using a let-expression to denote the set of elected messages in a node inbox.




fun Elected : Node -> Node {

  { n, i : Node |

    let inbox_elected = payload.i & ElectedMsg & n.inbox |

      once (before some inbox_elected and no inbox_elected) }

}






Lastly, we just have to update the fact that specifies what are the valid executions of the protocol.




pred node_acts [n : Node] {

  initiate[n] or

  (some m : CandidateMsg | processCandidate[n, m]) or

  (some m : ElectedMsg | processElected[n, m])

}



fact events {

  // possible events

  always (stutter or some n : Node | node_acts[n])

}






Let us validate the new version of our protocol using the functionalities provided by the Analyzer. Let us run our empty run command example just to explore some possible traces. The first trace returned is one where there is a single node and the system stutters forever (recall that bounded model checking guarantees minimal trace prefix length). By hitting New Fork we should be able to observe a different event, namely an initiate event. However, depending on the selected solver, we may get the following message.

[image: Get the code to generate this instance.]

Let’s try to use the evaluator to debug the trace. Recall that the evaluator for traces supports any formula and expression, and that this evaluation is always performed on the focused state (the one at the left-hand side). We can start by confirming that the system is simply stuttering by calling stutter at the current state (in this case, this is still the initial one since we did not navigate in the trace). We can also ask if stutter is happening after or even always. For all theses cases the evaluator will answer true as expected. We can then ask the evaluator whether there is some node for which the guard of the initiate predicate holds (a formula with the past operator historically), or use comprehension to get all nodes for which that guard holds. The evaluator will show us that it holds for the existing node. So this must be a case where the guard is not necessarily the same as the enabled condition of the event. The problem is in the existential quantifier searching for the new candidate message: this cannot be satisfied because there is no available CandidateMsg message in the configuration of this trace that can be added to the successor’s inbox.

[image: Get the code to generate this instance.]

This issue is actually evident if we inspect the available messages in the visualizer, as there are only ElectedMsg messages in the configuration. So we can hit New Config until a CandidateMsg is available (after closing the evaluator). This should happen after a few iterations. Then, we can ask again for New Fork, and this time a node will effectively initiate.

[image: Get the code to generate this instance.]

This means that to simulate a specific scenario we must first think about which messages will be necessary and hit New Config until those messages are in scope at the initial state. Of course, this does not scale to more complex scenarios.

Another problem occurs when we want to inspect a different network configuration (recall that with up to 3 nodes, there are only 4 distinct configurations). This should be easy to achieve by using New Config. Unfortunately, you’ll notice that the network configuration most likely stays the same, and only the set of available messages keeps changing. This is due to the fact that, as we’ve seen, the available messages are also part of the configuration because Message is an immutable signature. With one of the available solvers we actually needed to hit New Config 10 times before seeing a different ring network, and dozens of times to inspect the 4 alternatives, as the Analyzer will just iterate over different sets of possible messages.

[image: ../../_images/validation3.png]  [image: ../../_images/validation4.png]  [image: ../../_images/validation5.png] 

One possible solution to circumvent these issues if we have explicit messages is to enforce a so-called generator axiom. These are constraints that force every possible combination of field values of a signature to exist in every instance. In our leader election model, we would want to force the existence of messages with all possible types and values, which could be specified as follows.




pred generator {

  all n : Node {

    some m : CandidateMsg | m.payload = n

    some m : ElectedMsg | m.payload = n

  }

}






In order for models with the generator axiom to be consistent, we must set the scope to allow every possible message. In our model, we can have one message of each type for each available node, so the Message scope should be twice that of Node. Notice that we define the generator axiom as a predicate, rather than a fact: enforcing all possible messages to exist is helpful when exploring scenarios, but might slow down too much the verification properties, where enforcing a large scope for messages might possibly encumber the solving process. This is less of a problem for run commands that are expected to be satisfiable, which usually finish quickly. So, for the moment, we call this predicate only in run commands used for validation, such as the one below for ring networks with exactly 3 nodes.




run example3_generator {

  generator

} for exactly 3 Node, 6 Message






This command now guarantees the existence of all possible messages, and simulation using New Fork can easily be done as before. And since we have a tight scope of Message there is a unique configuration of messages available, and hitting New Config will effectively generate a new network configuration. Unfortunately, this will only work if we know the smallest scope needed for messages, which is not always easy to identify. Otherwise, different messages with the same payload will be allowed to appear in the configuration. That will be the case if we no longer ask for exactly 3 nodes in the command above: for ring networks with 2 nodes, 6 messages result in repetitions of the network configurations, changing only the available messages. To address this, we can also additionally enforce messages to be unique with the following predicate.




pred unique {

  all m1, m2 : CandidateMsg | m1.payload = m2.payload implies m1 = m2

  all m1, m2 : ElectedMsg | m1.payload = m2.payload implies m1 = m2

}






Given this, even if we assign a scope to messages larger than the one needed, a unique message configuration is guaranteed to be generated, and New Config will necessarily return a different network configuration (a different ring or a different order of node identifiers).




run example_unique_generator {

  generator

  unique

} for 3 Node, 10 Message






However, by forcing messages to be unique, we are actually restricting the set of possible behaviors of our protocol, and we must consider the implications of that decision. The main consequence is that, since inboxes are modeled as sets, it is now impossible to have two messages with the same content in an inbox (elements are unique in sets). But this was already the case in the version of the model without messages - a node identifier could only appear once in an inbox - so supporting duplicated messages was actually a deviation from the original model. Regardless, this is not an issue in this protocol, since each node sends at most one candidate message and one elected message with its own identifier.

Regardless of the issues with trace iteration, we should always reason carefully about message scopes. For instance, we could try to ask for a scenario where all nodes initialize, and eventually all nodes know who is the leader, with the following invalid command.




run bad_all_initiate {

  all n : Node | eventually initiate[n]

  eventually Node = Elected.Node

} for 3 but exactly 3 Node






The Analyzer will reply that there is no such trace. That’s because the default scope for signatures is 3, and 3 messages are not sufficient to represent this trace (at least 4 are needed). This can also lead to a false sense of safety from check commands, since a limited set of messages may reduce the valid traces explored by the Analyzer. To actually see a trace with 3 nodes where eventually a node is elected, we should use the following command, which returns a trace such as the one below. Notice how Elected is now a binary relation. To improve the visualization, we could introduce an auxiliary function for Node.Elected to highlight the nodes considered the leader by any node.




run all_initiate {

  all n : Node | eventually initiate[n]

  eventually Node = Elected.Node

} for exactly 3 Node, exactly 6 Message






[image: Get the code to generate this instance.]

So, before re-running the 3 check commands defined previously for our leader election protocol, we should extend the scope of available messages. However, we must first adapt the specification of the properties to the new Elected relation.




assert at_most_one_leader {

  always lone Node.Elected

}

check at_most_one_leader for 3 but 6 Message



assert leader_stays_leader {

  always (all n : Node.Elected | always n in Node.Elected)

}

check leader_stays_leader for 3 but 6 Message



assert at_least_one_leader_fair {

  fairness implies eventually (Node = Elected.Node)

}

check at_least_one_leader_fair for 3 but 6 Message






Note that Node.Elected is now the set of leaders known to any of the nodes, so the two safety properties are the same as before, but with the previous Elected set replaced by Node.Elected. The liveness property specifies that all nodes will eventually know who is the leader, by requiring that eventually the domain of relation Elected contains all nodes. The two safety properties are satisfied as before. Here is the result of the analysis for the first.

[image: ../../_images/log11.png] 

To verify the liveness property at_least_one_leader, we should first update the fairness condition to consider the new event and the new guards.




pred initiate_enabled [n : Node] {

  historically no CandidateMsg & payload.n & n.succ.inbox

}

pred processCandidate_enabled [n : Node, m : Message] {

  m in n.inbox

}

pred processElected_enabled [n : Node, m : Message] {

  m in n.inbox

}



pred node_enabled [n : Node] {

  initiate_enabled[n] or

  (some m : CandidateMsg | processCandidate_enabled[n, m]) or

  (some m : ElectedMsg | processElected_enabled[n, m])

}



pred fairness {

  all n : Node {

    eventually always node_enabled[n]

    implies

    always eventually node_acts[n]

  }

}






With this fairness condition property at_least_one_leader_fair holds. Note that in the above enabled conditions we did not explicitly checked if it was possible to create a message of the appropriate type to send. For example in initiate_enabled we did not include the condition some CandidateMsg & payload.n. The behaviors where that condition is false will be excluded from the analysis by the fairness property, which is precisely the intended. Also, since our scope for Message is big enough, the configuration where all possible messages exist will also be analyzed, and in that configuration those constraints would be trivially true, and so all the interesting behaviors will still be verified. Actually, when using explicit messages it might be a good idea to just change the generator and unique predicates to facts, because analysis commands will only have to explore a single message configuration and this might lead to efficiency gains (besides all the advantages in validation). Of course, then we must be very careful to always choose a big enough scope for messages. The only reason to keep them as predicates is if the scope needed to have all possible messages becomes too big: in that case the analysis might be too inefficient, and without the generator axiom we might still be able to check the property for a smaller number of messages. Of course, then we will have no guarantees that all possible executions for a given number of nodes are explored, but we might still be able to find bugs and have some confidence in the results.

The reader might wonder if instead of having a static Message signature we could declare it as mutable, and then really create new messages when they are needed. That can be done in Alloy, but, unfortunately, from our experience, that option makes specification more difficult and analyses less efficient, when compared to the static version with the generator and unique assumptions, so we will not discuss it here. And concerning efficiency, there is a much better alternative that we will discuss next, that is to not have explicit messages as signatures.

Messages as tuples

In the previous section we used signatures to encode records, which led to some issues with validation. However, we can also explore Alloy’s flexible relational logic to implement a more abstract version that instead of using signatures implements messages directly as tuples. This has the advantage of avoiding the validation issues, and, by removing message atoms, it will also speed up analysis. The trade off is that it does not scale very well when we have very complex message types.

Recall that fields in Alloy can be of arbitrary arity, so one can simply declare the inboxes to return a relation with a set of tuples, each containing all the information of a message: if a message has 2 fields of type A and B, then the inbox will contain a subset of pairs contained in A -> B. However, we will also need to identify the type of the message in the inbox. So, if we have different message types, the inbox should actually contain triples belonging to Type -> A -> B, where Type will be an enumerated signature discriminating the different types of messages. Since each inbox is associated to a node, this would result in a quaternary inbox relation with type Node -> Type -> A -> B. This strategy works if all message types contain exactly the same payload, otherwise we would need to somehow normalize this tuple set (more on this later).

In our current example, we have two kinds of messages that happen to have the same payload, so this strategy can simply be encoded by changing the declaration of inbox to a mutable ternary relation.




abstract sig Type {}

one sig Candidate, Elect extends Type {}



sig Node {

  succ : one Node,

  next : lone Node,

  var inbox : Type -> Node

}






Notice that this idiom again disallows repeated messages in the inboxes, since a tuple belonging to Type -> Node can only appear once in the inbox.

Specifying the event predicates is actually simpler than the version with explicit messages, since we can always create a new tuple with the needed message payload. So, in the initiate event, the guard just has to check whether the tuple Candidate->n has ever been in the inbox of the successor, and if not that ‘message’ is added to the successor’s inbox.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically Candidate->n not in n.succ.inbox // guard



  inbox' = inbox + n.succ->Candidate->n // effect on inbox

}






The process events are also simpler, and with messages as tuples it is even simpler to specify effects in a point-free style. The processElected event can be specified as follows. Note that now it is again parametrized by the node identifier expected to be contained in the message to be processed.




pred processElected [n : Node, i : Node] {

  // elected message m is read and processed by node n



  Elect->i in n.inbox // guard



  inbox' = inbox - n->Elect->i + n.succ->Elect->(i - n) // effect on inbox

}






The guard states that a message with content Elect->i should exist in the inbox of n. In the effect, this message is removed from the inbox of n and only added to the inbox of n.succ if the i != n. This conditional addition is achieved by adding message Elect->(i - n) to the inbox of n.succ. Note that i - n is empty iff i != n, hence no message will be added in that case.

The specification of processCandidate can also be done with a couple of one-liners.




pred processCandidate [n : Node, i : Node] {

  // candidate msg m is read and processed by node n



  Candidate->i in n.inbox // guard



  inbox' = inbox - n->Candidate->i + n.succ->Candidate->(i & n.^next) + n.succ->Elect->(n & i) // effect on inbox

}






Here we expect a Candidate->i message in the inbox of n, which is then removed in the effect. The conditional addition of that message to the inbox of n.succ when i in n.^next is achieved by adding tuple Candidate->(i & n.^next), and the conditional addition of an elected message when the received identifier is equal to n is achieved by adding tuple Elect->(n & i), which will be empty iff n != i.

The Elected function is also simpler.




fun Elected : Node -> Node {

  { n, i : Node | once (before Elect->i in n.inbox and Elect->i not in n.inbox) }

}






Finally, you must update fact events and the enabledness predicates for the fairness constraint for this new version of the model. The specification of all properties remains the same, only the commands need to be adapted by removing the scope on Message. The specification of the enabledness predicates is the following.




pred initiate_enabled [n : Node] {

  historically Candidate->n not in n.succ.inbox

}

pred processCandidate_enabled [n : Node, i : Node] {

  Candidate->i in n.inbox

}

pred processElected_enabled [n : Node, i : Node] {

  Elect->i in n.inbox

}



pred node_enabled [n : Node] {

  initiate_enabled[n] or

  (some i : Node | processCandidate_enabled[n, i]) or

  (some i : Node | processElected_enabled[n, i])

}






In this new model all commands return the expected result. Below is a transition for the eventually_elected command.

[image: Get the code to generate this instance.]

Notice that, without messages as signatures, messages are now represented as edges in the visualizer. In this case, the inbox is a ternary relation Node -> Type -> Node, so the type appears as an annotation of the edge. This may be arguably more difficult to interpret than the previous version.

It is also worth noting that the analysis of this version of the model is much more efficient than the one with explicit messages. Running the at_most_one_leader command, whose log was already shown for the other version, is now one order of magnitude faster than the version with an explicit Message signature.




check at_most_one_leader for 3






[image: ../../_images/log21.png] 

The payload of the messages in this protocol is very simple, with just two message types that happen to contain the same single, mandatory field. Let us imagine we needed an additional, optional field r with type X, in elected messages. With messages as signatures this would be easy to encode: just add a new lone field to the respective message type.




sig ElectedMsg extends Message {

  r : lone X

}






Adapting the events is mostly straightforward, just determining the correct value of r. However, issues with scope are now exacerbated: the number of messages must now increase to consider the possibility of an empty r (and the generator axiom must also be adapted to force those cases).

In the messages as tuples idiom, we must now adapt the declaration of inbox so that it always contain tuples with the same arity. Elected messages with an r are quaternary tuples of type Node -> Type -> Node -> X, while all other messages are of type Node -> Type -> Node. To make all tuples of the same arity, we could introduce an Empty singleton signature to pad the tuples of the messages with less content. In particular, it will always be the forth element of candidate messages of elected messages without the r field. The declaration of the inbox would look as follows.




abstract sig Type {}

one sig Candidate, Elect extends Type {}



one sig Empty {}



sig Node {

  succ : one Node,

  next : lone Node,

  var inbox : Type -> Id -> X + Empty

}






Using tuples to direct represent messages has many advantages as we have seen. Unfortunately, if messages have a lot of different fields it will not scale up, due to the wat the analysis of Alloy models is performed. Fields of arity nn might require 2n22^{n^2} boolean variables in the backend analysis engine, and this value becomes too large for larger values of nn.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/protocol-design/messages-as-tuples

Further reading

Model finding

Learn how the analysis engine of Alloy works, to understand why analysis becomes unfeasible with fields of large arity.

Model finding

Further reading

Higher-arity relations

In this section we used higher-arity fields to model inboxes. Learn how to use them.

Higher-arity relations



Refining the network model

So far we’ve considered node inboxes to be sets, meaning that received messages are unordered and thus not necessarily processed in the delivery order. This allows us to show that our protocol is correct in a network model where there are no guarantees or ordered delivery. However, we might want to verify the correctness of our protocol in a more refined network model, closer to a possible implementation. For example, some middlewares ensure ordered delivery, but only support inboxes with a maximum size, meaning that if a message is received while the inbox is still full it will be silently discarded. If we wanted to check the correctness of our protocol with this network model, we would need to model inboxes using bounded queues, which can be done by resorting to Alloy sequences. To simplify the presentation, we will illustrate this by building on one of the simpler models of our protocol, where only the first phase was specified using a point-wise style, and where messages where just node identifiers.

Sequences in Alloy are introduced with the keyword seq, and are essentially partial functions from integer indices to elements of the specified type. The scope of indices is bounded, meaning that sequences cannot grow indefinitely. Changing our inboxes to (mutable) sequences results in the following signature declaration.




sig Node {

  next : lone Node,

  succ : one Node,

  var inbox : seq Node

}






To adapt the events, we can make use of the auxiliary functions provided by utility module sequniv (which is imported automatically whenever sequences are used). But first, the Analyzer will throw an ambiguity error in our ordering do to a call to our first signature that clashes with a function defined in sequniv. To disambiguate, just replace it with this/first.

Writing the events in the point-free style is complicated when sequence operations are involved, so let us adapt the point-wise version previously presented. To test whether a message is already in the inbox of the successor in the guard of the initiate event, one can use elems to get all elements in a sequence. To add a new message to an inbox, one can use function add to add an element to the end of a sequence. If the sequence is already full, add discards the new element and returns the sequence unchanged.




pred initiate [n : Node] {

  // node n initiates the protocol



  historically n not in elems[n.succ.inbox] // guard



  n.succ.inbox' = add[n.succ.inbox, n] // effect on n.succ.inbox

  all m : Node - n.succ | m.inbox' = m.inbox // effect on the outboxes of other nodes

}






The process event can be adapted in a similar manner. Rather than selecting an arbitrary message from the inbox, it now must select the first element in the sequence, and then update the inbox by keeping only the rest of the sequence. When propagating the message, is it also added to the successor’s inbox with add.




pred process [n : Node, i : Node] {

  // i is read and processed by node n



  i in first[n.inbox] // guard



  n.inbox' = rest[n.inbox] // effect on n.inbox

  i in n.^next implies n.succ.inbox' = add[n.succ.inbox, i] // effect on n.succ.inbox

               else n.succ != n implies n.succ.inbox' = n.succ.inbox

  all m : Node - n - n.succ | m.inbox' = m.inbox // effect on the inboxes of other nodes

}






Finally, we must adapt the notion of elected node. We’ll just say that a node is considered to be elected when its own identifier was at the head of its inbox and processed in the next state.




fun Elected : set Node {

  { n : Node | once (before n in first[n.inbox] and n not in first[n.inbox]) }

}






At this point our leader election model with queues can be validated, and the previously defined safety and liveness properties will still be valid for a default scope of 3. However, this version of the protocol will actually not work if the capacity of the inboxes is less than the number of nodes. In particular it is no longer guaranteed that a leader will be elected. This can be checked with the following command.




check at_least_one_leader_fair for 3 but 2 seq






This will now return a counter-example, for which a relevant transition is shown below.

[image: Get the code to generate this instance.]

The issue is that the inbox of Node2, the potential leader, is already at full capacity. Node0 is attempting to send the Node2 identifier to Node2, but since the queue is already full, the message is discarded. So to ensure liveness in this version of the protocol - and in an eventual implementation with such a communication middleware - one must make sure that the inboxes are large enough to contain all possible messages. Although this counter-example uses very small queues sizes, the problem still might exist in realistic implementations at larger scales.

Alloy model

Full model for the section

Download and explore the files relevant for the model at this point of the book.

https://github.com/practicalalloy/models/tree/2024-02-28/protocol-design/refining-the-network-model

Further reading

Sequences

Sequences in Alloy have some particularities, learn how to use them correctly.

Sequences

